Kapalı Dosyadan Veri Alma

[valentino06]

Sayın Çok kıymetli Excel Hocalarım kapılı Excel Kitap'ından veri çekmek istiyorum. lütfen yardımcı olabilir misiniz. Yapmak istediğim Üretim Kitap'ında bulunan Açılış tarihleri ile sevk tarihlerini çekmek istiyorum. kriter ise Rapor kitabında "C" sütunun daki kodların karşılığı olan tarihleri getirmek istiyorum. lütfen ortak alanda duracak şekilde kodları düzenleyebilir misiniz. çok teşekkür ederim. Allah Kat Kat Razı Olsun. İnşallah

 

[valentino06]

Arkadaşlar lütfen yardımcı olabilir misiniz. Çok teşekkür ederim.

 

[BAZGİRET]

Merhaba;
özet sayfasında yazılı olan kodlar ile üretim dosyasındaki kodlar baştan mı yazılı olacak? Yoksa Karışık olabilir mi?
Eki inceleyin değişik durum olursa bakılır.
Not: İki dosyanın da aynı klasörde olmasına dikkat edilmesi gerekir.

 

[valentino06]

Sayın Bazgired Hocam ben bir kaç deneme yaptım çekemedim verileri önemli olan kritere göre veri çekmek nasıl uygun görürseniz olur. yeter ki veriler gelsin. çok teşekkür ederim.

 

[Korhan Ayhan]

Deneyiniz.

Option Explicit

Sub Tarihleri_Aktar()
    Dim Dosya1 As String, Dosya2 As String, Zaman As Double
    Dim Baglanti As Object, Kayit_Seti As Object, Sorgu As String
   
    Zaman = Timer
   
    Set Baglanti = CreateObject("AdoDb.Connection")
   
    Dosya1 = ThisWorkbook.FullName
    Dosya2 = ThisWorkbook.Path & "\üretim.xlsx"
           
    Baglanti.Open "Provider=Microsoft.Ace.OleDb.12.0;User ID=Admin;Data Source=" & _
    Dosya1 & ";Extended Properties=""Excel 12.0;Hdr=Yes"""
   
    Sorgu = "Select Tablo2.[AÇILIŞ TARİH],Tablo2.[SEVK TARİHİ] From [" & Dosya1 & "].[Özet$C9:G31] As Tablo1 " & _
            "Left Join [" & Dosya2 & "].[Üretim$B7:AA25] As Tablo2 On Tablo1.[KOD] = Tablo2.[KOD]"

    Set Kayit_Seti = Baglanti.Execute(Sorgu)

    Range("D10").CopyFromRecordset Kayit_Seti
    Range("D10:E" & Cells(Rows.Count, 3).End(3).Row).NumberFormat = "dd.mm.yyyy"

    If Baglanti.State <> 0 Then Baglanti.Close

    Set Kayit_Seti = Nothing
    Set Baglanti = Nothing

    MsgBox "Veri aktarımı tamamlanmıştır." & vbLf & vbLf & _
           "İşlem süresi ; " & Format(Timer - Zaman, "0.00") & " Saniye"
End Sub

 

[valentino06]

Sayın Bazgired Hocam; Sayın Korhan Ayhan Hocam ne kadar teşekkür etsem az olur. Allah kat kat razı olsun. İnşallah sağolun varolun. Allah yolunuzu açık etsin. İnşallah Kod Çok güzel çalışıyor. tekrar çok teşekkür ederim.

Saygılarımla,

Hayırlı Günler Dilerim.