Kapalı dosyadan, puantaja sadece 4 sütün aktarmak istiyorum

[Filose]

Herkese merhaba,
Ekte örnek dosyada görüleceği gibi kapalı dosyadan açık olan puantaj dosyama sadece 4 sütun çekmek istiyorum. (Yada daha fazla sütün çekmek)

Kendi becerimle dosyaları aktarabildim ancak istediğim sütünü istediğim sütuna aktarma yapamadım. Çünkü yazacağım sütun kodlarını belirleyemedim.

Yardımcı olabilecek arkadaşlara şimdiden çok teşekkür ediyorum. Kadir geceniz mübarek olsun.

İyi çalışmalar.

 

[Orion1]

Her 2 dosyada ayni klasörün içinde olmalı.
Dosyanız ektedir.

Sub aktar59()
Dim conn As Object, rs As Object, sat As Long
Range("B5:D65536,F5:F65536").ClearContents
Set conn = CreateObject("adodb.Connection")
Set rs = CreateObject("adodb.Recordset")
conn.Open "Provider=microsoft.jet.oledb.4.0;data source=" & ThisWorkbook.Path & _
        "\sicilliste.xls;extended properties=""excel 8.0;hdr=No"""
rs.Open "select F1,F16,F17,F22 from [Sayfa1$B5:W65536];", conn, 1, 1
sat = 5
rs.movefirst
Do While Not rs.EOF
    Cells(sat, "B").Value = rs(0).Value
    If IsDate(rs(1).Value) Then Cells(sat, "C").Value = CDate(rs(1).Value)
    If IsDate(rs(2).Value) Then Cells(sat, "D").Value = CDate(rs(2).Value)
    Cells(sat, "F").Value = rs(3).Value
    sat = sat + 1
    rs.movenext
Loop
rs.Close: conn.Close
Set rs = Nothing: Set conn = Nothing
MsgBox "işlem tamam." & vbLf & "evrengizlen@hotmail.com"
End Sub

 

[Filose]

Sayın Orion,

Çok teşekkür ederim ellerinize sağlık. Şimdi deneyeceğim.
Saygı ve sevgiyle kalın.

 

[Orion1]

Sayın Orion,

Çok teşekkür ederim ellerinize sağlık. Şimdi deneyeceğim.
Saygı ve sevgiyle kalın.

Rica ederim.
İyi çalışmalar.

 

[Filose]

Merhaba Orion1,
Tekrar teşekkür eder ellerinize sağlık. Kodlar hatasız çalışıyor. Diğer çeşitli dosya aktarmalar için de kullanacağım. Yazdığınız bu kod için kısa açıklama yapabilir misiniz.

"\sicilliste.xls;extended properties=""excel 8.0;hdr=No"""
rs.Open "select F1,F16,F17,F22 from [Sayfa1$B5:W65536];", conn, 1, 1
sat = 5

Buradaki F1,F16,F17,F22 ne için olduğunu anlayamadım.
Teşekkür eder saygılar sunarım.

 

[alicimri]

Sayın Orion1 Çevrimiçi olmadığından ben izah etmeye çalışayım.

[Sayfa1$B5:W65536]

Sayfa1'in 5 satırdan başlayarak B sütunundan W sütununa kadar olan sütunlarını alıyor.

F1,F16,F17,F22

F1=B sütununu , F16=Q sütununu, F17=R sütununu, F22= W sütununu temsil ediyor ve aradaki sütunları atlıyor.
bir kere rs (Kayıt seti/Recordset) oluşturduktan sonra bu sütunlara indeks numaraları ile sıfırdan başlayarak ulaşabilirsiniz. Bu kodların alt tarafındaki rs(0), rs(1), rs(2), rs(3) gösterimleri, belirlenen sütunları indeks numaralarını kullanarak aktarıyor. Bu referansları rs("F1"), rs("F16"), rs("F17"), rs("F22") şeklinde de verebilirsiniz.

 

[Filose]

Alicimri Bey Merhaba,

İlginiz için çok teşekkür ederim. Çok makbule geçti.
Ayrıca Orion1'e de tekrar teşekkür eder, Saygı ve sevgiyle kalın.

İyi çalışmalar