kaçıncı karakter

[sinembagci]

a1 hüresinde bir metin var.kelimeler arasıda değişen sayıda boşluk var.mesela
a1=ocak şubat mart nisan mayıs
ocak ile şubat arasında 5, şubat ile mart arasında 12 mart ile nisan arasında 8 boşluk var.
her kelimenin baş ve son karakteri bu metinin kaçıncı karekteri olduğunu bulabilirmiyiz.
k,ş,t,m,t,n,n,m,s bu metnin kaçıncı karakterleridir?

 

[Necdet]

Merhaba,

Böyle bir şey nerede gerek duyulur pek yorum yapamadım ama aşağıdaki kodları deneyiniz.

Sub Sozcukler()
    Dim Deger, _
        i       As Integer, _
        j       As Integer, _
        k       As Integer, _
        Metin   As String
    
    Application.ScreenUpdating = False
        
    For i = 1 To Cells(Rows.Count, "A").End(3).Row
        Deger = Split(Application.WorksheetFunction.Trim(Cells(i, "A")), " ")
        Cells(i, "B").ClearContents
        For j = 0 To UBound(Deger)
            k = Application.WorksheetFunction.Search(Deger(j), Cells(i, "A"))
            Metin = Deger(j) & " : " & Left(Deger(j), 1) & "-" & k & " " & _
                    Right(Deger(j), 1) & "-" & k + Len(Deger(j)) - 1
            If Cells(i, "B") = "" Then
                Cells(i, "B") = Metin
            Else
                Cells(i, "B") = Cells(i, "B") & "," & Chr(10) & Metin
            End If
        Next j
    Next i
    
    Application.ScreenUpdating = True
    
    MsgBox "İşlem Tamam...", vbInformation, "N. YEŞERTENER - [URL="http://www.excel.web.tr/"]www.excel.web.tr[/URL]"
    
End Sub

 

[sinembagci]

teşekkür

bir text dosyasında uygulamam gerekli olduğundan sordum. cevebınız için çok teşekkürler.

 

[Necdet]

bir text dosyasında uygulamam gerekli olduğundan sordum. cevebınız için çok teşekkürler.

Umarım işinize yaramıştır.