Istenilen sayfa varsa makrosu

[kadir78]

İyi günler. Aşağıdaki kodlar ile yeni bir sayfa oluşturuyorum fakat if komutu ile sayfa yoksa "üretim raporu" sayfasını oluştur varsa oluşturma kodlarını yapamadım. Yardımcı olurmusunuz.

Set s7 = Sheets("Taslak")

s7.copy After:=Activesheet
Activesheet.Name = "Üretim Raporu"

 

[muygun]

Merhaba;

Boş bir modüle;

Sub sayfa_oluştur()
Dim Sayfa As String
Sayfa = "Üretim Raporu"
If Not SayfaVarMi(Sayfa) Then
Set s7 = Sheets("Taslak")
s7.Copy After:=ActiveSheet
ActiveSheet.Name = "Üretim Raporu"
End If
End Sub

Function SayfaVarMi(SayfaAdi As String) As Boolean
On Error Resume Next
SayfaVarMi = CBool(Len(Worksheets(SayfaAdi).Name) > 0)
End Function

Ekleyerek sayfa oluştur makrosunu deneyin.

İyi çalışmalar.

 

[Korhan Ayhan]

Alternatif;

Option Explicit

Sub Test()
    Dim S7 As Worksheet, S1 As Worksheet
    
    Set S7 = Sheets("Taslak")
    
    On Error Resume Next
    Set S1 = Nothing
    Set S1 = Sheets("Üretim Raporu")
    On Error GoTo 0
    
    If S1 Is Nothing Then
        S7.Copy After:=ActiveSheet
        ActiveSheet.Name = "Üretim Raporu"
    Else
        MsgBox "Eklemek istediğiniz sayfa zaten var!", vbCritical
    End If
End Sub

 

[kadir78]

Sayın Muygun. Kodlar için teşekkür ederim çok sağolun.

 

[kadir78]

Alternatif;

Option Explicit

Sub Test()
    Dim S7 As Worksheet, S1 As Worksheet
   
    Set S7 = Sheets("Taslak")
   
    On Error Resume Next
    Set S1 = Nothing
    Set S1 = Sheets("Üretim Raporu")
    On Error GoTo 0
   
    If S1 Is Nothing Then
        S7.Copy After:=ActiveSheet
        ActiveSheet.Name = "Üretim Raporu"
    Else
        MsgBox "Eklemek istediğiniz sayfa zaten var!", vbCritical
    End If
End Sub

Korhan hocam sağolun. Elinize emeğinize sağlık. Teşekkür ederim.