İki sütunlu düşey ara

[hayalmeyal]

Hayırlı günler.
İki sütunlu düşey ara yapılması gerekiyor.
A, E Sütununa, B, F sütununa eşit olduğunda, E-F yanındaki G sütununu getir şeklinde formul C sütununa yazılmaktadır.

=EĞERHATA(İNDİS($E$2:$G$40;KAÇINCI(A2:A40&B2:B40;E2:E40&F2:F40;0);3);"0")
Dizi formülüdür.

Sıkıntım bu formül dizi formülü olmadan çalışmıyor.

Çalışmada satırlar silinebiliyor-sütun eklenebiliyor. Bu nedenle bu kodu dizi ve makro olmadan yazma şansım var mıdır?

ÖRNEK DOSYA

 

[Ömer BARAN]

Örnek dosyanızı bir dosya paylaşım sitesine (örneğin burası) yükleyip, oradan alacağınız belge link'ini burada paylaşırsanız çok kısa sürede cevap alacağınızı sanıyorum.

Not: Dizi formülü kullanmak istemiyorsanız yardımcı sütun kullanmanız gerekebilir.

 

[hayalmeyal]

Ömer bey teşekkür ederim.
Formülü belirttiğim için dosya eklememiştim. Örnek dosya ekledim.
Yardımcı sütun olmadan formüle edilebilirse çok sevinirim.

 

[Ömer BARAN]

Dizi formülü olmayacaksa, ek sütunsuz mümkün değil bence.
Link'teki belgeye bakınız.

BELGE

 

[Ömer BARAN]

Gönderdiğim belgedeki I sütununu kullanmadan C2'deki formülü aşağıdaki gibi değiştirip, tek ilave sütun ile de işlem yapılabilir.

=EĞERHATA(İNDİS($G$2:$G$11;KAÇINCI(A2&B2;$J$2:$J$11;0);1);"")

 

[hayalmeyal]

Ömer bey ilginize çok teşekkür ederim.
Dediğiniz gibi en azından tek ek sütun eklemek gerekiyor gibi.

Farklı çözüm önerileri gelirse memnun olurum. Yoksa tek yardımcı sütun ile yapılacaktır.

 

[Ömer BARAN]

Ömer bey ilginize çok teşekkür ederim.
Dediğiniz gibi en azından tek ek sütun eklemek gerekiyor gibi.

Farklı çözüm önerileri gelirse memnun olurum. Yoksa tek yardımcı sütun ile yapılacaktır.

Estağfurullah.
Dizi formüllerinin sıkıntısı, formül sayısı arttığında ve diziler büyüdüğünde hız sorunu yaşanmasıdır.
Bunu aşmak için söylediğim yöntem tek çıkar yol gibi görünüyor. (VBA Kod ile bulunacak çözümü bilemiyorum tabi.)

Kolay gelsin. İyi günler dilerim.

 

[bzace]

Merhabalar,
Değerlerinizin sayı olduğunu düşünürsek;

=TOPLA.ÇARPIM((E$2:E$11=A2)*(F$2:F$11=B2)*G$2:G$11)

uygulanan formül ile sonuç alınabilir.

 

[Erdem Akdemir]

Merhaba,

Sayın bzace'ye alternatif olsun.Getireceğiniz sonucun metin yada sayı olmasından etkilenmez.

Dizi formülü olmadan sonuç almak istiyorsanız. excel 2010 altı versiyonlarda çalışmaz.

=İNDİS($G$2:$G$11;TOPLAMA(15;6;KAÇINCI(A2&B2;$E$2:$E$11&$F$2:$F$11;0);1))

 

[hayalmeyal]

Merhaba,
.

Merhabalar,
.

Elinize sağlık.
Sayın bzace, verdiğiniz formul sayı olduğundan işe yaradı. topla.çarpım aklıma gelmemişti
Sayın kuvari, verdiğiniz formülü 2007 office de denediğimden #ad hatası aldım.

bzace beyin formülünü kullanacağım. Hepinizin emeğine sağlık. Vesselam

 

[bzace]

Metinsel değerleri döndürmesini istiyorsanız formülü bu şekilde kullanın.

=İNDİS(G$2:G$11;
      TOPLA.ÇARPIM((E$2:E$11=A2)*(F$2:F$11=B2)*SATIR(E$2:E$11))-1)

Daxe Syán

 

[hayalmeyal]

Metinsel değerleri döndürmesini istiyorsanız formülü bu şekilde kullanın.

=İNDİS(G$2:G$11;TOPLA.ÇARPIM((E$2:E$11=A2)*(F$2:F$11=B2)*SATIR(E$2:E$11))-1)

Bu formül tamamdır. Çok teşekkür ederim.
Elinize,emeğinize sağlık. Vaktinizi aldığım için hakkınızı helal edin.
Vesselam.