Iki Kritere Bagli Siralama Islemi

[mustafaine1]

Merhaba Arkadaslar,

Ekteki calismada sefer numaralarina gore isim bazinda siralama yapmak istiyorum, baska bir deyisle isim ve sefer numarasi ayni ise sira ayni olucak ve her isim icin 1'den baslayacak bir siralama yapmak istiyorum, yardimci olursaniz sevinirim,

iyi calismalar.

 

[Ömer]

Merhaba Mustafa bey,

Siz formül ile C sütununu oluşturmayı mı hedefliyorsunuz.

.

 

[mustafaine1]

Merhaba Omer Bey,

Evet C sutununda formul olusturmam gerekiyor, anlattigim adimi yardimci sutunlar kullanmadan gecemedim malesef.

 

[Ömer]

C2:

=EĞER(D2="";"";BAĞ_DEĞ_SAY(1/SIKLIK(EĞER($A$2:A2=A2;EĞER($D$2:D2<>""
 ;KAÇINCI($D$2:D2;$D$2:D2;0)));SATIR($D$2:D2)-SATIR($D$2)+1)))

Dizi formülüdür.

.

 

[mustafaine1]

Omer Bey elinize saglik, tek kelimeyle mukemmelsiniz, benzer bir sekli ile dun aksam 2 saatten fazla ugrasip beceremedim, yapiyi kesinlikle ezberleyecegim sagolun.

 

[Ömer]

Rica ederim Mustafa Bey. Sizde sağolun.

 

[mustafaine1]

Omer Bey, D14 hucresini de 118 olarak degistirirsem onun sefer numarasi da 3 olarak degisebilir mi; suan ki haliyle 4 nolu sefermis gibi gosteriyor, dolayisiyla raporlama yanlisligi yaratacak.

 

[Ömer]

Mustafa bey,

Bahsettiğiniz olasılığı dikkate almamıştım.
Bu durumda yapıyı değiştirmek gerekecek. Peki A sütunundaki isimler sıralı mı yoksa onlar da karışık gelebilir mi?

.

 

[mustafaine1]

Aslinda bir muhasebe muavini uzerinden gidiyorum, ayni sekilde A sutunuda sabit olmuyor, masraflar karisik giriliyor ve farkli seferlere ait olabiliyorlar.

Ben suan muavini sefer numaralarina gore listeleyerek formulunuzun calismasini sagladim, seferler sirali olunca harkulade sekilde siralam yapiyor.

Sizin formulunuzun uzerinede baya bi vakit harcadim siralama yapmamak icin ama Bi taraftan guzelde bir etut oldu.

Uzerinde kafa yormak isterseniz benim icin ihtiyacin disinda egitim olur; vakit buldukca uzerinde calisacagim, farkli bir yol bulursam ayrica paylasirim, tekrar tesekkur ederim, tekrar elinize saglik.

 

[Ömer]

Veriler karışıksa şartlar artacağından dolayı çok eğerli bir fonksiyon olur.

=EĞER(D2="";"";EĞER(EĞERSAY($A$2:A2;A2)=1;1
 ;EĞER(TOPLA(($A$1:A1=A2)*($D$1:D1=D2))>0
  ;İNDİS($C$1:C1;KAÇINCI(A2&D2;$A$1:A1&$D$1:D1;0))
   ;1+MAK(EĞER($A$1:A1=A2;$C$1:C1)))))

Dizi formülüdür.

Biraz uzun oldu, daha sakin bir zaman da üzerinde düşünüp kısaltmaya çalışırım.

.

 

[mustafaine1]

Gercekten cok saygi duydum Omer Bey;

Bu arada bu sefer cok basit cozume ulasmissiniz, ben mantik olarak bir turlu oturtamamistim bu calismayi, hep 1'e bolerek cozume gitmeye calistim ne yaziik ki tekrar tekrar elinize saglik, borclu sayarim kendimi size karsi, saygilar..