Iki değişkene göre say

[haso_excel]

Merhaba arkadaşlar,

Elimde a kolonunda firma listesi var, b kolonunda da ürün bilgileri var.
Amacım a kolunun da ki her bir firmaya kaç tane ürün vermişiz.(her üründen kaç adet aldığına bakılmaksızın bir sayılacak)
Ben dosyamda D2 ve D3 hücrelerine elimle cevapları yazdım.

 

[Orion1]

Özet tablo işinizi görür.
Dosyanız ektedir.

 

[bzace]

Merhaba,
Dosyanızı göremem, ama açıklamalarınızdan anladığım kadarıyla deneyiniz.

=TOPLA.ÇARPIM(EHATA(MBUL("Jane";A1:A38))*(B1:B38<>""))

Firma isminiz Jane olsun.

 

[haso_excel]

ilginiz için çok teşekkür ederim arkadaşlar,
Öncelikle pivot ile yapmak istemiyorum. Bzace arkadaşım türkçe yazdığın formülü ingilizce ye çevirdiğimde =SUMPRODUCT(ISERR(SEARCH(C2;A2:A13))*(A2:A13<>"")) ki böyleyse sonuç dosyamda da göreceğiniz üzere 2 olması gerekirken ordaki ürün adetlerini topluyor aslında a müşterisi 1 ve 2 nolu üründen aldığı için 2 olması gerekiyor sonucun

 

[YUSUF44]

Çözümü yardımcı sütun kullanarak şöyle hallettim.
C sütununa bir sütun ekledim
C2 hücresine aşağıdaki formülü yazıp aşağıya doğru kopyaladım:

=EĞER(ÇOKEĞERSAY($A$1:A2;A2;$B$1:B2;B2)>1;0;ÇOKEĞERSAY($A$1:A2;A2;$B$1:B2;B2))

yeni durumda sizin özetiniz bir sütun kaydığından firmalar D sütununa, adetler de E sütununa geldi.
E2 hücresine aşağıdaki formülü yazıp aşağıda doğru kopyaladım:

=ETOPLA(A:A;D2;C:C)

 

[haso_excel]

=SUMPRODUCT(ISERR(SEARCH(C2;A2:A13))*(B2:B13<>"")) yaptım ama olmadı. Aslında amaç, A kolonunda birden fazla müşteri ismini, ( benzer yada farklı olablir)
c2 hücresindeki müşteri ismini kontrol ettirerek. B kolonunda kaçtane unig değer var onu bulmak.

 

[YUSUF44]

=SUMPRODUCT(ISERR(SEARCH(C2;A2:A13))*(B2:B13<>"")) yaptım ama olmadı. Aslında amaç, A kolonunda birden fazla müşteri ismini, ( benzer yada farklı olablir)
c2 hücresindeki müşteri ismini kontrol ettirerek. B kolonunda kaçtane unig değer var onu bulmak.

Benim çözümümü uygulamadınız mı?

 

[randzafer]

Yusuf44 Üstad formül için teşekkürler.

 

[bzace]

Alternatif;

=BAĞ_DEĞ_SAY(1/
    EĞER(A$2:A$13=D2;SIKLIK(B$2:B$13*(A$2:A$13=D2);
B$2:B$13*(A$2:A$13=D2))))
[COLOR="Blue"]Formül dizi formülüdür.CTRL + SHIFT + ENTER ile tamamlayınız.[/COLOR]

Daxe Syán

 

[bzace]

Alternatif;

=TOPLA(EĞER(A$2:A$13=D2;
     ÇOKEĞERSAY(A$2:A$13;D2;B$2:B$13;B$2:B$13)^
(2*((A$2:A$13=0)+(B$2:B$13=0))-1)))
[COLOR="Blue"]Formül dizi formülüdür.CTRL + SHIFT + ENTER ile tamamlayınız.[/COLOR]

 

[Erdem Akdemir]

Merhaba,

D2 hücresine yapıştırın.Dizi formülüdür.

=TOPLA(--(EĞERHATA(KAÇINCI(SATIR($1:$100);EĞERHATA(KAÇINCI(EĞER($A$1:$A$100=C2;C2&$B$1:$B$100);$A$1:$A$100&$B$1:$B$100;0);0);0);0)>0))

Alternatif

=TOPLA.ÇARPIM(--ESAYIYSA(KAÇINCI(SATIR($1:$100);KAÇINCI($A$2:$A$100&$B$2:$B$100;EĞER($A$2:$A$100=C2;C2&$B$2:$B$100);0);0)))

 

[bzace]

Sayın Kuvari'nin önerdiği Topla,Kaçıncı,Eğer fonksiyon kombinasyonuna alternatif;

=TOPLA(--(KAÇINCI(EĞER(A$2:A$13=D2;B$2:B$13);
    EĞER(A$1:A$13=D2;B$1:B$13);)=
SATIR(A$2:A$13)))
[COLOR="Blue"]Formül dizi formülüdür.CTRL + SHIFT + ENTER ile tamamlayınız.[/COLOR]

Formüllerin İngilizce karşılıkları;
Topla -- Sum
Kaçıncı -- Match
Eğer -- If
Satır -- Row

 

[haso_excel]

Herkezin emeğine sağlık arkadaşlar, teşekkür ederim