Iç içe eğer formülü ve değer hatası

[enginyıldırım]

arkadaşlar excel listesinde sayfa sayfa ay listesi var. en son sayfa ise ay filitresi yaptım. hangi ay seçilirse o ayın içinden bilgi almasını istiyorum rakamları alıyor ama yazıda değer hatası verdi yardımcı olursanız sevinirim. formül atta ancak dosyayı nasıl yükleneceğini bilemediğim için ekleyemedim.

=EĞER($A$1="OCAK AYI";DÜŞEYARA($A$2;'OCAK LİSTE'!$A$3:$AC$124;29;0))+
EĞER($A$1="ŞUBAT AYI";DÜŞEYARA($A$2;'ŞUBAT LİSTE'!$A$3:$AE$124;29;0))+
EĞER($A$1="MART AYI";DÜŞEYARA($A$2;'MART LİSTE'!$A$3:$AC$124;29;0))+
EĞER($A$1="NİSAN AYI";DÜŞEYARA($A$2;'NİSAN LİSTE'!$A$3:$AC$105;29;0))+
EĞER($A$1="MAYIS AYI";DÜŞEYARA($A$2;'MAYIS LİSTE'!$A$3:$AC$113;29;0))+
EĞER($A$1="HAZİRAN AYI";DÜŞEYARA($A$2;'HAZİRAN LİSTE'!$A$3:$AC$120;29;0))+
EĞER($A$1="TEMMUZ AYI";DÜŞEYARA($A$2;'TEMMUZ LİSTE'!$A$3:$AE$118;29;0))+
EĞER($A$1="AĞUSTOS AYI";DÜŞEYARA($A$2;'AĞUSTOS LİSTE'!$A$3:$AC$119;29;0))+
EĞER($A$1="EYLÜL AYI";DÜŞEYARA($A$2;'EYLÜL LİSTE'!$A$3:$AC$117;29;0))+
EĞER($A$1="EKİM AYI";DÜŞEYARA($A$2;'EKİM LİSTE'!$A$3:$AC$115;29;0))+
EĞER($A$1="KASIM AYI";DÜŞEYARA($A$2;'KASIM LİSTE'!$A$3:$AC$110;29;0))+
EĞER($A$1="ARALIK AYI";DÜŞEYARA($A$2;'ARALIK LİSTE'!$A$3:$AC$110;29;0))

 

[S.Yiğit]

Merhaba,

Herhangi bir upload sitesinde yükleyebilirsiniz.

 

[Merhum İdris SERDAR]

.

Bu kadar uzun formüle gerek yok. Bunu deneyin.

=EĞER(EHATALIYSA(DÜŞEYARA($A$2;DOLAYLI("'"&A1&" LİSTE'!$A$3:$AC$124");19;0));"";DÜŞEYARA($A$2;DOLAYLI("'"&A1&" LİSTE'!$A$3:$AC$124");19;0))

.

 

[enginyıldırım]

inşallah yüklemeyi başarmışımdır. bu ana listemin ilk çalışması küçük parçası

http://dosya.altervista.org/download.php?file=9c4bd4a68d5d2e7aad9aa6508f5865a5

 

[Merhum İdris SERDAR]

inşallah yüklemeyi başarmışımdır. bu ana listemin ilk çalışması küçük parçası

http://dosya.altervista.org/download.php?file=9c4bd4a68d5d2e7aad9aa6508f5865a5

.

H Sütunundaki ayların listesini OCAK, ŞUBAT, MART... gibi ve boşluksuz yaptıktan sonra yukarıda yazdığım formülü kullanın.

.

 

[enginyıldırım]

Teşekkür ederim üstadım ayları yazınca verdi yalnız "'"&a1&" bunun anlamı ne oluyor

 

[Merhum İdris SERDAR]

Teşekkür ederim üstadım ayları yazınca verdi yalnız "'"&a1&" bunun anlamı ne oluyor

Şimdi şöyle bir deneme yapalım:

Bir hücreye = yazıp, OCAK LİSTE sayfasında A3 hücresinde ENTER'e basalım. Aşağıdaki gibi bir formül elde edilir.

='OCAK LİSTE'!A3

Sayfa adlarında boşluk olduğu için OCAK'ın başına ve LİSTE'nin sonuna birer kesme işareti gelmiş. Bu metin olduğu için çift tırnak arasına almamız gerekir. Ay adı da A1 hücresinden alacak. O zaman & (birleştirme) işaretleri ile formülü devam ettiriyoruz.

"'"&A1&...


.

 

[enginyıldırım]

çok teşekkür ederim hayırlı akşamlar