Hücre atlama

[sward175]

İyi Geceler adına, herkese Merhabalar,

Şöyle bir soru sormak istiyorum.
Excel' de Maus ile bir hücreye tıkladım. Yön tuşlarından sağ, sol, üst yada alt birine bastım.
İsteğim hangi yöne basarsam bir hücre atlasın. Örnek maus ile D5 hücresine geldim yön tuşlarından alt yöne bastım imlecin D7 hücresine gelmesi için yardımlarınızı rica ederim.
Saygılarımla,
sward175

 

[Haluk]

Aşağıdakileri bir modüle yapıştırdıktan sonra, Auto-Open makrosunu çalıştırın, daha sonra bahsettiğiniz ok tuşlarıyla deneme yapabilirsiniz.

Söz konusu ok tuşlarına verilen görevleri iptal etmek için bu kez, Auto_Close makrosunu çalıştırın.

Sub Auto_Open()
    Application.OnKey "{LEFT}", "mySub_Left"
    Application.OnKey "{RIGHT}", "mySub_Right"
    Application.OnKey "{UP}", "mySub_Up"
    Application.OnKey "{DOWN}", "mySub_Down"
End Sub
'
Sub mySub_Left()
    On Error Resume Next
    Range(ActiveCell.Offset(0, -2).Address).Activate
End Sub
'
Sub mySub_Right()
    On Error Resume Next
    Range(ActiveCell.Offset(0, 2).Address).Activate
End Sub
'
Sub mySub_Down()
    On Error Resume Next
    Range(ActiveCell.Offset(2, 0).Address).Activate
End Sub
'
Sub mySub_Up()
    On Error Resume Next
    Range(ActiveCell.Offset(-2, 0).Address).Activate
End Sub
'
Sub Auto_Close()
    Application.OnKey "{LEFT}"
    Application.OnKey "{RIGHT}"
    Application.OnKey "{UP}"
    Application.OnKey "{DOWN}"
End Sub

.

 

[sward175]

Haluk Bey, Günaydın,
Ellerinize sağlık gayet güzel çalışıyor,
Sizlerin sayesinde hem bilgimiz, hem ufkumuz genişliyor.
İyi ki varsınız.
Saygılarımla,
sward175

 

[Haluk]

Size de günaydın, kolay gelsin .....

.

 

[sward175]

Haluk Bey, Merhaba,

Hafta başı bu konu üzerinde yardımınızı esirgememiştiniz ve dosya çalışıyordu.
Bu gün açtığımda ise çalışmıyor ve macro devre dışı diye uyarı veriyor.
Yapmak istediğim Maus ile bir hücreye tıkladım. Yön tuşlarından sağ, sol, üst yada alt birine bastım.
İsteğim hangi yöne basarsam bir hücre atlasın.
Bu konuda yardımınızı rica ederim.
Saygılarımla,
sward175

 

[Haluk]

O kod sadece geçen hafta çalışmak üzere tasarlanmamıştı.

Başka yeni bir dosyada deneyin ... makroları da etkinleştirin.

.

 

[sward175]

Merhabalar,

Bu sefer oldu , Dosyanın altından yeteri kadar silme usulü ile yükledim.
Maus ile bir hücreye tıkladım. Yön tuşlarından sağ, sol, üst yada alt birine bastım.
Hangi yöne basarsam bir hücre atlasın.
Yardımınızı rica ederim.
Saygılarımla,
sward175

 

[Haluk]

Makroları yanlış yere yapıştırmışınız .....

Sayfa modülünden o makroları silin, dosyaya yeni bir modül ilave edin ve oraya yapıştırın.

Dosyayı kaydedip, kapatın .... sonra tekrar açtığınızda her şey çalışıyor olacak.

.

 

[sward175]

Haluk Bey,
Teşekkür ederim.
Sonunda başardım.
İyi günler diliyorum.
sward175

 

[sward175]

Haluk Bey, Merhaba,
Dosya gayet güzel çalışıyor, Yalnız açık olan tüm excel dosyalarında hücreler birer atlayarak gidiyor.
Bu anlamda yardımınızı rica ederim.
Saygılarımla,
sward175

 

[Haluk]

Dosyanızdaki Auto-Open ve Auto_Close makrolarını silin, diğerleri kalsın.

Daha sonra, dosyanızın ThisWorkbook modülüne aşağıdakileri yapıştırın;

Private Sub Workbook_Activate()
    Application.OnKey "{LEFT}", "mySub_Left"
    Application.OnKey "{RIGHT}", "mySub_Right"
    Application.OnKey "{UP}", "mySub_Up"
    Application.OnKey "{DOWN}", "mySub_Down"
End Sub
'
Private Sub Workbook_Deactivate()
    Application.OnKey "{LEFT}"
    Application.OnKey "{RIGHT}"
    Application.OnKey "{UP}"
    Application.OnKey "{DOWN}"
End Sub

Böylece, kodlar sadece bu çalışma kitabında geçerli olacaktır.

Örnek dosya ektedir...

.

 

[sward175]

Haluk Bey, Merhaba,
Teşekkür eder, Nice güzel günler dilerim.
Saygılarımla,
sward175