hücreye veriyi çift tıklama ile başka sayfadan alma nasıl olur

[yusufymr]

herkese selam sorum veri girişi yaptığım hücreye çift tıkladığımda o hücreye ait bilgilerin olduğu sayfa açılsın ve o sayfadaki herhangi bir veriye çift tıkladığımda ilk giriş yaptığım hücreye o veri gelsin
bu işlemi nasıl yaparız yardım lütfen .teşekkürler

 

[asdfwqrx]

hocam ekli dosya olmadığı için pek yardımcı olunabileceğini sanmıyorum, anlattğınız kadarıyla köprü işleviyle yapılabilir gibi ama ekli dosya olmadan bişey diyemiyorum..

 

[yusufymr]

Dosya eklemeyi bilmiyorum örnek hazırladım

 

[yusufymr]

Dosyayı nasıl eklicem mesaja

 

[yusufymr]

Hocam dosya ekledim bakarmısınız

 

[Korhan Ayhan]

Selamlar,

Ekteki örnek dosyayı incelermisiniz.

Uygulanan kodlar;

Boş bir modüle;

Option Explicit
Public Eski_Hücre_A As String
Public Eski_Hücre_B As String

Sayfa1 in kod bölümüne;

Option Explicit
 
Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
    If Intersect(Target, Range("A2:B65536")) Is Nothing Then Exit Sub
    Cancel = True
    If Target.Column = 1 Then
        Eski_Hücre_A = Target.Address
        Sheets("İSİMLER").Select
    ElseIf Target.Column = 2 Then
        Eski_Hücre_B = Target.Address
        Sheets("ÜRÜNLER").Select
    End If
End Sub

İSİMLER sayfasının kod bölümüne;

Option Explicit
 
Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
    If Intersect(Target, Range("A2:A65536")) Is Nothing Then Exit Sub
    Cancel = True
    Sheets("Sayfa1").Range(Eski_Hücre_A) = Target.Value
    Sheets("Sayfa1").Select
End Sub

ÜRÜNLER sayfasının kod bölümüne;

Option Explicit
 
Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
    If Intersect(Target, Range("A2:A65536")) Is Nothing Then Exit Sub
    Cancel = True
    Sheets("Sayfa1").Range(Eski_Hücre_B) = Target.Value
    Sheets("Sayfa1").Select
End Sub

 

[yusufymr]

Hocam allah razı olsun tam istediğim gibi çok teşekkür ederim çok işime yarayacak