Hücre İçindeki Veriyi Alarak Atama Yapmak

[bichet]

Merhabalar,

Çalışma kitabının 1. sayfasında aşağıdaki gibi bir veri setim var. 2.sayfada ise firmaların sıralandığı bir bölüm var ve o bölüme kopyalama yapmam gerekiyor.

A-------------B-------------C----------------D
Ürün-------Miktar--------Fiyat----------Firma Sırası
x-------------30-----------300-------------1
x1-----------770----------500-------------5
x2----------1230---------600-------------89
x3----------140-----------700-------------34
Xn-----------~-------------~---------------~

D sütunundaki sayı değerine göre miktarları 2. sayfaya kopyalama yapmak istiyorum. Örneğin; x1 miktarının 2. sayfada 5. satıra, x3 miktarının 2. sayfada 34. satıra kopyalanması gerekiyor.

Yazmaya çalıştığım kod;

satir_sayisi = Worksheets("sayfa1").Cells(Rows.Count, "A").End(xlUp).Row

For i = 2 to satir_sayisi
Worksheets("sayfa1").activate
'burada c sütunundaki değeri çekmem lazım. Buradan gelen değer y olsun.
Range( cells(i,2),cells(i,3) ).Select
Selection.copy
Worksheets("sayfa2").activate
Range( cells(y,2),cells(y,3) ).select
Activesheet.paste
Next i

D sütunundaki sayı değerini nasıl çekebilirim ve formülün içine dahil edebilirim?

Not: Başka işlemlerden dolayı diğer sayfada düşeyara kullanmak işime yaramıyor.

 

[mancubus]

Sub xlTR_197123()

    Dim SonSat As Long, i As Long, SiraNo As Long
    
    With Worksheets("Sayfa1")
        SonSat = .Range("A" & .Rows.Count).End(xlUp).Row
        For i = 2 To SonSat
            SiraNo = .Range("D" & i).Value
            Worksheets("Sayfa2").Range("B" & SiraNo & ":C" & SiraNo).Value = .Range("B" & i & ":C" & i).Value
        Next i
    End With

End Sub