Çözüldü Hücre İçindeki Harf Geçiyorsa

[gicimi]

Merhaba;

1E123
112E3
1112E
1A123
11A23
111A4 A1 ile A6 hücrelerinde örnekteki gibi değerler yer almaktadır. Hücre içerisinde "E" harfi mevcut ise hücrelerin yanına "Evet", "A" harfi içeriyor ise hücrelerin yanına "Aynı" yazmasını istiyorum.
"A" ve "E" harfleri aynı anda hücre de yer almamaktadır.

Konu hakkında yardımlarınızı rica ederim.

 

[ÖmerBey]

Merhaba,
B1 için deneyiniz.

=EĞER(EĞERHATA(BUL("E";A1);0)>0;"EVET";EĞER(EĞERHATA(BUL("A";A1);0)>0;"AYNI";""))

Alternatif:

=EĞER(UZUNLUK(A1)>UZUNLUK(YERİNEKOY(A1;"E";""));"EVET";EĞER(UZUNLUK(A1)>UZUNLUK(YERİNEKOY(A1;"A";""));"AYNI";""))

Alternatif:

=EĞER(ESAYIYSA(-YERİNEKOY(A1;"E";1));"EVET";EĞER(ESAYIYSA(-YERİNEKOY(A1;"A";1));"AYNI";""))

 

[gicimi]

@ÖmerBey Hocam çözümler için çok teşekkür ederim.

 

[ÖmerBey]

Rica ederim, iyi çalışmalar...

 

[gicimi]

@ÖmerBey Hocam bu işlemi ARA fonksiyonu ile yapmak mümkün olabilir mi_?

 

[ÖmerBey]

ARA bir dizi içerisinde arama yapar.

 

[gicimi]

Cevabınız için teşekkür ederim. İyi Çalışmalar. @ÖmerBey

 

[Ömer BARAN]

Merhaba.
ARA işleviyle alternatif olsun.
Aslında bu işlem için ARA işlevi çok anlamlı gelmiyor ama aşağıdaki formülü dizi formülüne dönüştürerek (CTRL+SHIFT+ENTER) sonuç alabilirsiniz.

=EĞERHATA(ARA(PARÇAAL($A1;EĞERHATA(BUL("A";$A1);BUL("E";$A1));1);{"A";"E"};{"Aynı";"Evet"});"YOK")

 

[gicimi]

@Ömer BARAN Hocam teşekkür ederim.