hücre atlatma

[YSFYSF0707]

a1 hücresine masraf yazdığımız zaman masraf için yazacağım değeri c1 e yazacagım ancak a1 e masraf yazdıgım zaman hücre otomatik olarak c1 e atlayacak yani b1 i ıska geçecek

 

[Korhan Ayhan]

Selamlar,

Aşağıdaki kodu bu işlemi yapacağınız sayfanın kod bölümüne uygulayıp denermisiniz.

A sütununa değer girdiğinizde C sütununa geçer.
C sütununa değer girdiğinizde ise bir alt satırın A sütunundaki hücreye geçer.

Option Explicit
 
Private Sub Worksheet_Change(ByVal Target As Range)
    If Intersect(Target, Range("A:A,C:C")) Is Nothing Then Exit Sub
    Select Case Target.Column
        Case Is = 1
        Target.Next.Next.Select
        Case Is = 3
        Target.Offset(1, -2).Select
    End Select
End Sub

 

[YSFYSF0707]

çok güzel olmuş ama ben sadece a dan c ye atlasın istiyorum c den a ya atlamasın.

 

[Korhan Ayhan]

Selamlar,

Bu durumda kodu aşağıdaki şekilde değiştirip kullanabilirsiniz.

Option Explicit
 
Private Sub Worksheet_Change(ByVal Target As Range)
    On Error GoTo Son
    If Intersect(Target, Range("A:A")) Is Nothing Then Exit Sub
    Application.EnableEvents = False
    If Target <> "" Then
        Target.Next.Next.Select
    End If
Son: Application.EnableEvents = True
End Sub

 

[YSFYSF0707]

korhan bey ilk girişte uygulama güzel çalışıyor ancak excelden cıkıp tekrar sayfaya girdimmi makro uyarısı veriyor ve çalışmıyor tekrar yazmam gerekiyor.bunun bi çaresi varmı

 

[YSFYSF0707]

birde ben sadece masraf yada ne bileyim harcama yazdım mı atlamasını istiyorum çünkü a1 sütunu harcama türleri,b1 sütunu gelir, c1 sütunu gider olarak kayıtlı...a1 e masraf yazdım mı direk c1 e yada alış yazdım mı b1 e geçecek bu şekilde verileri girerken hata yapma oranım azalacak...1 haftadır uğrasşıyorum olmuyor.sizin gonderdıgınız formullerıde denedım ama sadece bi anlık çalıştırıyor.

 

[Korhan Ayhan]

Selamlar,

Peki sadece "MASRAF" yazdığınızdamı sütun atlamasını istiyor sunuz? Başka bir kriter var mı?

 

[YSFYSF0707]

Masraf, nakliye bunun gibi bir çok şey.siz bu 2 si için yapabilirseniz yapın ben yine aynı şekilde eklerim diğerlerini
hatta yaklaşık 10 tane farklı gider ve bi o kadarda gelir var

 

[Korhan Ayhan]

Selamlar,

Aşağıdaki kodu kullanabilirsiniz. Kırmızı renkli bölüme dilediğiniz kadar seçeneği (büyük harfle yazarak) ekleyebilirsiniz.

Option Explicit
 
Private Sub Worksheet_Change(ByVal Target As Range)
    Dim Kriter() As Variant, X As Byte
    
    On Error GoTo Son
    If Intersect(Target, Range("A:A")) Is Nothing Then Exit Sub
    
    [COLOR=red]Kriter = Array("MASRAF", "NAKLİYE")
[/COLOR]    
    Application.EnableEvents = False
        
    For X = 0 To UBound(Kriter)
        If UCase(Replace(Replace(Target, "ı", "I"), "i", "İ")) = Kriter(X) Then
            Target.Next.Next.Select
            GoTo Son
        End If
    Next

Son: Application.EnableEvents = True
End Sub

 

[kahramang1]

Option Explicit

Private Sub Worksheet_Change(ByVal Target As Range)
If Intersect(Target, Range("A:A,C:C")) Is Nothing Then Exit Sub
Select Case Target.Column
Case Is = 1
Target.Next.Next.Select
Case Is = 3
Target.Offset(1, -2).Select
End Select
End Sub

Korhan bey ben bu kodu eklediğimde a dan c sütununa atlıyor. Ben D ve E sütununa da değer yazdıktan sonra Bir alt satırdaki a sütununa gitmesini istiyorum. Bunun için ne yapabiliriz. Bu drumda C sütununa değer yazınca bir alt satıra dönüyor. Teşekkürler.