Hedef Satır aralığı arttırmak

[5353]

Ekteki dosyada İNDİS bir formül var.
=EĞER($M$1=Veri!$A$5;EĞER(SATIRSAY(B$1:B1)<=TOPLA.ÇARPIM(--(Veri!$J$12:$J$65<>"")*--(Veri!$J$12:$J$65>0));İNDİS(Veri!$B$12:$B$65;KÜÇÜK(EĞER(((Veri!$J$12:$J$65<>"")*(Veri!$J$12:$J$65>0));SATIR($B$1:$B$54));SATIRSAY(B$1:B1)));"");"")

Buradaki 65 ten fazla satırı baz almasını istiyorum bir türlü olmuyor. #YOK hatası geliyor.
Çözüm bulacak arkadaş var mı?
Birde SİL yeni bir excel dosyası açıyor bu buton kendi içinde makrosu çalışmaz mı ?

 

[ÖmerFaruk]

Buradaki 65 ten fazla satırı baz almasını istiyorum bir türlü olmuyor. #YOK hatası geliyor.
Çözüm bulacak arkadaş var mı?

Formülünüz DİZİ formülüdür.
Formül içine girince dizi formülü kaybolur ( { } parantezlerinden bahsediyorum)
Formülde değişiklik yaptıktan sonra formül içindeyken Ctrl+Shift+Enter tuş kombinasyonuna basmayı unutmayınız.
Alt satırlarda da değişiklik yapacaksanız yukarıdaki işlemden sonra sürükleyerek yapıştırmanız yeterli olacaktır.

 

[5353]

Formülünüz DİZİ formülüdür.
Formül içine girince dizi formülü kaybolur ( { } parantezlerinden bahsediyorum)
Formülde değişiklik yaptıktan sonra formül içindeyken Ctrl+Shift+Enter tuş kombinasyonuna basmayı unutmayınız.
Alt satırlarda da değişiklik yapacaksanız yukarıdaki işlemden sonra sürükleyerek yapıştırmanız yeterli olacaktır.

Evet o şekil geçiyorum. Formül 65. satırdan sonrayı görmüyor. Formül mantığında hassas bir durum var. 74 oluyor sonrası 116 mesela en son hedef olmuyor...???

 

[Ömer]

Merhaba,

Formül içinde kullanılan, SATIR($B$1:$B$54) bu tür artırımlar için doğru yazım şekli değildir, çünkü 65 değerini değiştirdiğinizde yada diğer sayfaya satır ekleyip sildiğiniz de bu değerdeki satır aralığını da hesaplayıp 54 değerini değişmeniz gerekir. Bunun yerine aşağıdaki gibi bir yazım ile aralık değişirken size kolaylık sağlar.
Örneğin 65 değerini 100 yaptığınız da 100-12+1 =89 SATIR($B$1:$B$89) yazmanız gerekir. Bunun yerine aşağıdaki yapıyı kullanırsanız sadece aralık değiştirirsiniz hesaplama yapmazsınız.

SATIR($B$1:$B$54) yerine SATIR(Veri!$B$12:$B$65)-SATIR(Veri!$B$12)+1 gibi.

Formülün tamamı:
=EĞER($M$1=Veri!$A$5;EĞER(SATIRSAY(B$1:B1)<=TOPLA.ÇARPIM(--(Veri!$J$12:$J$65<>"")*--(Veri!$J$12:$J$65>0));İNDİS(Veri!$B$12:$B$65;KÜÇÜK(EĞER(((Veri!$J$12:$J$65<>"")*(Veri!$J$12:$J$65>0));SATIR(Veri!$B$12:$B$65)-SATIR(Veri!$B$12)+1);SATIRSAY(B$1:B1)));"");"")

Bu şekilde yazarak tüm 65 değerlerini değiştirerek aralığı artırırsınız.

 

[5353]

Merhaba,

Formül içinde kullanılan, SATIR($B$1:$B$54) bu tür artırımlar için doğru yazım şekli değildir, çünkü 65 değerini değiştirdiğinizde yada diğer sayfaya satır ekleyip sildiğiniz de bu değerdeki satır aralığını da hesaplayıp 54 değerini değişmeniz gerekir. Bunun yerine aşağıdaki gibi bir yazım ile aralık değişirken size kolaylık sağlar.
Örneğin 65 değerini 100 yaptığınız da 100-12+1 =89 SATIR($B$1:$B$89) yazmanız gerekir. Bunun yerine aşağıdaki yapıyı kullanırsanız sadece aralık değiştirirsiniz hesaplama yapmazsınız.

SATIR($B$1:$B$54) yerine SATIR(Veri!$B$12:$B$65)-SATIR(Veri!$B$12)+1 gibi.

Formülün tamamı:
=EĞER($M$1=Veri!$A$5;EĞER(SATIRSAY(B$1:B1)<=TOPLA.ÇARPIM(--(Veri!$J$12:$J$65<>"")*--(Veri!$J$12:$J$65>0));İNDİS(Veri!$B$12:$B$65;KÜÇÜK(EĞER(((Veri!$J$12:$J$65<>"")*(Veri!$J$12:$J$65>0));SATIR(Veri!$B$12:$B$65)-SATIR(Veri!$B$12)+1);SATIRSAY(B$1:B1)));"");"")

Bu şekilde yazarak tüm 65 değerlerini değiştirerek aralığı artırırsınız.

Ustadım TEŞEKKÜRLER harika öğretici anlattınız. 65 rakamını 165 yaptım aşağıya doğru değerleri getirdi. Bazı hücrelerde "0" değerini getiriyor(ekteki resimde olduğu gibi) bu değeri pas geçebilir mi? Yani "0" ları baz almasın.

 

[Ömer]

R sütununa hangi şartlarda listelemek istediğiniz nedir? Konuyu detaylı açıklar mısınız.

 

[5353]

B sütününda sicil numaraları yazılı, bu numaraları, J sütününda rakam varsa "0,3" "0,8" eğer rakam varsa getirecek. Sadece J de rakam varsa onu getirmesi sağlanacak.

 

[5353]

0 olanları-yazı olanları getirmesin sadece rakam olanlar gelse.

 

[Ömer]

Dizi formülüdür.

=EĞERHATA(EĞER($M$1=Veri!$A$5;İNDİS(Veri!$B$11:$B$165;KÜÇÜK(EĞER(Veri!$J$11:$J$165>0
 ;EĞER(ESAYIYSA(Veri!$J$11:$J$165);SATIR(Veri!$B$11:$B$165)-SATIR(Veri!$B$11)+1));SATIRSAY(R$3:R3)));"");"")

 

[5353]

Dizi formülüdür.

=EĞERHATA(EĞER($M$1=Veri!$A$5;İNDİS(Veri!$B$11:$B$165;KÜÇÜK(EĞER(Veri!$J$11:$J$165>0
;EĞER(ESAYIYSA(Veri!$J$11:$J$165);SATIR(Veri!$B$11:$B$165)-SATIR(Veri!$B$11)+1));SATIRSAY(R$3:R3)));"");"")

Ustad teşekkürler. iyi ki varsınız.