Gizli Sayfaları Barındıran Dosyada Sıralama Sorunu

[cicosz]

Merhaba,

Elimde gizli sayfaların da olduğu bir çalışma kitabı mevcut. Sayfaların tümü görünür vaziyetteyken sıralamada sorun olmuyor fakat sayfalardan bazılarını gizlediğim zaman hata alıyorum. Bu sorunu nasıl çözebilirim.

Teşekkürler.

 

[muygun]

Merhaba;
makro adından sonra;

On Error Resume Next

satırı ekleyerek deneyin.
İyi çalışmalar.

 

[cicosz]

Teşekkürler,
Peki hataları atla demeden yapmaya kalksak alternatif çözüm ne olur?

 

[Korhan Ayhan]

Deneyiniz.

Option Explicit

Sub Sayfalari_Sirala()
    Dim XL_APP As Object, K1 As Workbook, K2 As Workbook, S1 As Worksheet
    Dim Sayfa As Worksheet, Veri As Variant, X As Integer, Satir As Integer
    
    Application.ScreenUpdating = False
    
    Set K1 = ThisWorkbook
    Set XL_APP = CreateObject("Excel.Application")
    XL_APP.Visible = False
    Set K2 = XL_APP.Workbooks.Add(1)
    Set S1 = K2.Sheets(1)
    S1.Range("A1") = "Sayfalar"
    Satir = 2
    
    For Each Sayfa In ThisWorkbook.Worksheets
        S1.Cells(Satir, 1) = Sayfa.Name
        Satir = Satir + 1
    Next
    
    S1.Range("A2:A" & Satir - 1).Sort S1.Range("A2"), xlAscending
    
    Veri = S1.Range("A2:A" & Satir - 1).Value
    
    For X = LBound(Veri) To UBound(Veri)
        If K1.Sheets(CStr(Veri(X, 1))).Visible = -1 Then
            K1.Sheets(CStr(Veri(X, 1))).Move After:=K1.Sheets(K1.Sheets.Count)
        End If
    Next

    K2.Close 0
    XL_APP.Quit
    
    Set K1 = Nothing
    Set XL_APP = Nothing
    Set K2 = Nothing
    Set S1 = Nothing

    Application.ScreenUpdating = True

    MsgBox "Sayfa sıralama işlemi tamamlanmıştır.", vbInformation
End Sub

 

[cicosz]

Merhaba,

Vakit ayırdığınız için teşekkürler.