Soru Formül ile kümülatif toplam

[Ergün ÇUBUK]

Herkese kolay gelsin. Elimde seçilan ay verilerini getiren bir formül var. Bu formül Seçilen aya kadar olan verileri toplayıp getirsin olarak düzenlemek gerekmekte. Yardımcı olacağınızı ümit ederek formülü veriyorum. İlgilenenlere şimdiden teşekkür ederim.FORMÜL:
=ÇOKETOPLA(
KAYDIR('YAPILACAK İŞLEMLER'!$EL$1;;KAÇINCI($H$2;'YAPILACAK İŞLEMLER'!$EL$2:$EW$2;0)-1;1048576);
'YAPILACAK İŞLEMLER'!$EI:$EI; $A6;
'YAPILACAK İŞLEMLER'!$EJ:$EJ; $B6;
'YAPILACAK İŞLEMLER'!$EK:$EK; $C6
)

 

[KuTuKa]

1.Yol Seçilen aya kadar olan tüm ay sütunlarını oluşturup, her sütun için ÇOKETOPLA sonucunu dizi olarak alıp TOPLA ile birleştiriyoruz.

=LET(
n; KAÇINCI($H$2; 'YAPILACAK İŞLEMLER'!$EL$2:$EW$2; 0);
ofs; SÜTUN('YAPILACAK İŞLEMLER'!$EL$1:İNDİS('YAPILACAK İŞLEMLER'!$EL$1:$EW$1; 1; n)) - SÜTUN('YAPILACAK İŞLEMLER'!$EL$1);
TOPLA(
ÇOKETOPLA(
KAYDIR('YAPILACAK İŞLEMLER'!$EL$1;; ofs; 1048576);
'YAPILACAK İŞLEMLER'!$EI:$EI; $A6;
'YAPILACAK İŞLEMLER'!$EJ:$EJ; $B6;
'YAPILACAK İŞLEMLER'!$EK:$EK; $C6
)
)
)

2.Yol Dilerseniz her ay için mevcut formülünüzü çoğaltıp ilk aydan seçilen aya kadar toplayabilirsiniz. Örneğin:

=TOPLA(
ÇOKETOPLA(KAYDIR('YAPILACAK İŞLEMLER'!$EL$1;;0;1048576);
'YAPILACAK İŞLEMLER'!$EI:$EI;$A6;
'YAPILACAK İŞLEMLER'!$EJ:$EJ;$B6;
'YAPILACAK İŞLEMLER'!$EK:$EK;$C6)
:
ÇOKETOPLA(KAYDIR('YAPILACAK İŞLEMLER'!$EL$1;;
KAÇINCI($H$2;'YAPILACAK İŞLEMLER'!$EL$2:$EW$2;0)-1;
1048576);
'YAPILACAK İŞLEMLER'!$EI:$EI;$A6;
'YAPILACAK İŞLEMLER'!$EJ:$EJ;$B6;
'YAPILACAK İŞLEMLER'!$EK:$EK;$C6)
)

 

[Ergün ÇUBUK]

Sn. Hocam. Uyguladım formülü hata verdi. Dosya linkini paylaşıyorum side dosya üzerinde denerseniz hatayı daha net görürsünüz. eşleşmeleri renklendirdim. LİNK: https://lifeboxtransfer.com/s/b6cdac58-ae04-4b46-8c51-28516cea57d7

 

[KuTuKa]

Formülü doğrudan dosyana uygulamam için gerekli hücre/sekme bilgisini verirmisin

 

[Ergün ÇUBUK]

Sn. Hocam, "Demir Cevheri Mukayeseli (2)" sayfası "M6" hüresinden aşağıya doğru uygulanacak. E6 hüresinde yalnızca H2 deki ay verisini getiren örnek formül var. Aynı formül aynı tablodan H2 deki aya kadar Ocaktan itibaren toplamını getirecek

 

[KuTuKa]

Ergun Bey selamlar

M6 ya uygulayacağınız formül

=LET(
n; KAÇINCI($H$2; 'YAPILACAK İŞLEMLER'!$EL$2:$EW$2; 0);
ofs; SÜTUN('YAPILACAK İŞLEMLER'!$EL$1:İNDİS('YAPILACAK İŞLEMLER'!$EL$1:$EW$1; 1; n)) - SÜTUN('YAPILACAK İŞLEMLER'!$EL$1);
TOPLA(
ÇOKETOPLA(
KAYDIR('YAPILACAK İŞLEMLER'!$EL$1;; ofs; 1048576);
'YAPILACAK İŞLEMLER'!$EI:$EI; $A6;
'YAPILACAK İŞLEMLER'!$EJ:$EJ; $B6;
'YAPILACAK İŞLEMLER'!$EK:$EK; $C6
)
)
)


bu formül iş görüyor olması lazım. gönderidğiniz tablo da bağlantılı dosyalar olduğu için ve bu dğerleri göremediğim için bu kadar biir çalışma yapabildim . iyi çalışmalar

 

[Ergün ÇUBUK]

HOCAM FORMÜL BENDE ÇALIŞMADI, uygulama yaptığınız dosyayı bana yollayabilirmisin erguncubuk@gmail.com adresine

 

[Korhan Ayhan]

Excel sürümleri farklı olabilir.

 

[Ergün ÇUBUK]

Uygulama yaptığınız dosyayı erguncubuk@gmail.com adresine yolamanızı rica etmiştim. Gönderirmisiniz.(Ben Exsel 2016 kullanıyorum).

 

[Korhan Ayhan]

Sizin kullandığınız sürüme göre aşağıdaki formülü deneyebilirsiniz.

=TOPLA.ÇARPIM(KAYDIR('YAPILACAK İŞLEMLER'!$FP$4:$FP$58;;;;KAÇINCI($H$2;'YAPILACAK İŞLEMLER'!$FP$2:$GA$2;0))*('YAPILACAK İŞLEMLER'!$EI$4:$EI$58=$A6)*('YAPILACAK İŞLEMLER'!$EJ$4:$EJ$58=$B6)*('YAPILACAK İŞLEMLER'!$EK$4:$EK$58=$C6))

 

[Ergün ÇUBUK]

Sn. Hocam. Formülünüz çalıştı, öncelikle elinize emeğinize sağlık. Bu formülü Tek şartla da çalıştırmak gerekti. Bunada bir bakabilirmisiniz.
=TOPLA.ÇARPIM(KAYDIR('YAPILACAK İŞLEMLER'!$FP$4:$FP$58;;;;KAÇINCI($H$2;'YAPILACAK İŞLEMLER'!$FP$2:$GA$2;0))*('YAPILACAK İŞLEMLER'!$EI$4:$EI$58=$A6)*('YAPILACAK İŞLEMLER'!$EJ$4:$EJ$58=$B6)). ani 'YAPILACAK İŞLEMLER'!$EJ$4:$EJ$58=$B6) tek eşleşmeli kümülatif toplayacak olması gerekiyor.