Formül İçermeyenleri Sil

[CenTay]

Arkadaşlar selamlar B22 aralığında bir tablom var, C2 de ürün adı var diğer satırlarda formüllü ve elle girilenler var Ben C2 ürün adını silince formül içermeyenlerin de silinmesini istiyorum yada C3 yada C4 silince...kısaca satırdaki formülsğüz hücrelerdeki veriler de silinsin.Şimdiden teşekkürler arkadaşlar.

 

[Necdet]

Merhaba.
Paylaşım sitelerinden birine örnek dosyanızı ekleyin, çözüme daha hızlı ulaşırsınız.

 

[Seyit Tiken]

Bu şekilde çalışmanıza uyarlayınız.

Sub formulolmayansil()
On Error Resume Next
[b2:p2].SpecialCells(2) = ""
[c3] = ""
End Sub

 

[CenTay]

Seyit Tiken hocam merhabalar teşekkürler ediyorum ilginiz için, olursa eğer , ben hücreyi elle silince işlem gerçekleşmeli.Çok çok teşekkürler yeniden hocam.

 

[Korhan Ayhan]

Sayfanızın kod bölümüne uygulayıp deneyiniz.

Option Explicit

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim Veri As Range, Alan As Range
    
    On Error GoTo 10
    
    If Intersect(Target, Range("C2:C" & Rows.Count)) Is Nothing Then Exit Sub
    
    Application.EnableEvents = False
    
    For Each Veri In Intersect(Target, Range("C2:C" & Rows.Count))
        If Veri.Value = "" Then
            On Error Resume Next
            Set Alan = Nothing
            Set Alan = Veri.Offset(, -1).Resize(, 15).SpecialCells(xlCellTypeConstants, 23)
            On Error GoTo 0
            If Not Alan Is Nothing Then Alan.ClearContents
        End If
    Next
    
10  Application.EnableEvents = True
End Sub

 

[Seyit Tiken]

Private Sub Worksheet_Change(ByVal Target As Range)
On Error Resume Next
If Intersect(Target, [c3]) Is Nothing Then Exit Sub
If Target = "" Then
[b2:p2].SpecialCells(2) = ""
End If
End Sub

Bu şekilde deneyiniz.(Alternatif)

 

[CenTay]

Değerli hocalarım Korhan Ayhan, Seyit Tiken sizlere çok ama çok teşekkür ediyorum , iyiki varsınız, ömrünüzün uzun ve iyi olsun.