Fazla mesai hesaplama formu

[s.savas]

İyi geceler arkadaşlar.
Ekteki fazla mesai hesaplama formu ile ilgili eksiklerim için bilgi ve tecrübelerinize ihtiyacım var.
Fazla mesai sayfası için;

Tutulan her nöbet 24 saat olarak hesaplanıyor ve 160 saatten fazla çalışılan günler için fazla mesainin hesaplanması gerekiyor.

6 Nöbet 144 saat, 7 Nöbet ise 168 saat tutuyor.

Ocak ayında nöbet tutan bir personelin 7.Nöbeti hangi güne denk geliyorsa o gün için 8 saat, 7 den sonraki nöbetleri için 24 saat yazacak.

Örnekte: Personel Süleyman Savaş 7.nöbetini 13 Ocakta tutmuş, 8.nöbetini ise 15 ocakta tutmuştur.

İcap Mesai sayfası için ise;
Ocak ayında icap nöbeti yazılan personelin, icap nöbeti yazılan günlerine karşılık gelen günleri için 24 yazmalı.

İlgilenecek herkese teşekkür ederim.

 

[Muhammet Okumuş]

=EĞER(TOPLA.ÇARPIM(--(OCAK!$C$4:$I$34='FAZLA MESAİ'!$A4)*(OCAK!$C$3:$I$3="nöbet")*(OCAK!$A$4:$A$34='FAZLA MESAİ'!C$3))=0;"";EĞER(MOD(TOPLA.ÇARPIM(--(OCAK!$C$4:$I$34='FAZLA MESAİ'!$A4)*(OCAK!$C$3:$I$3="nöbet")*(OCAK!$A$4:$A$34<='FAZLA MESAİ'!C$3));7)=0;24;8))

bu formülü denermisiniz.

 

[s.savas]

muokumus arkadaşım teşekkür ederim ilgine.
Yazdığınız formülün hangi sayfa için yazıldığını belirtmemişsiniz, formülü Fazla Mesai sayfasının C4:AG4 aralığına uyguladım fakat sonuç vermedi.
Biraz daha detay bilgi verirsen sevinirim.

 

[Muhammet Okumuş]

Dosyayı incelermisiniz?

 

[s.savas]

Tekrar teşekkür ederim.
İcap Mesai sayfası için söylenecek söz, harika olmuş.
Fazla mesai sayfası için ise, ilk altı nöbet için bişey yazmayacak, 7.nöbet için 8 ve varsa 7.nöbetten sonraki tutulan nöbetler için 24 yazabilirmi.

 

[Muhammet Okumuş]

=EĞER($A4="";"";EĞER(TOPLA.ÇARPIM(--(OCAK!$C$4:$I$34=$A4)*(OCAK!$C$3:$I$3="nöbet")*(OCAK!$A$4:$A$34=C$3))=0;"";EĞER(TOPLA.ÇARPIM(--(OCAK!$C$4:$I$34=$A4)*(OCAK!$C$3:$I$3="nöbet")*(OCAK!$A$4:$A$34<=C$3))=7;8;EĞER(TOPLA.ÇARPIM(--(OCAK!$C$4:$I$34=$A4)*(OCAK!$C$3:$I$3="nöbet")*(OCAK!$A$4:$A$34<=C$3))>7;24;""))))

FAZLA MESAİ C4 hücresine kopyalayınız.

 

[s.savas]

FAZLA MESAİ C4 hücresine kopyalayınız.

Harika oldu, çok teşekkür ederim.

 

[Muhammet Okumuş]

Rica ederim. İyi çalışmalar.

 

[s.savas]

Merhaba arkadaşlar.
Sağolsun muokumus arkadaşın yardımıyla projeyi tamamladım, yalnız şöylen bir sorunum var.
Projede 12 sayfada, 720 hücrede aşağıdaki,

=EĞER($A4="";"";EĞER(TOPLA.ÇARPIM(--(OCAK!$C$4:$I$34=$A4)*(OCAK!$C$3:$I$3="nöbet")*(OCAK!$A$4:$A$34=C$3))=0;"";EĞER(TOPLA.ÇARPIM(--(OCAK!$C$4:$I$34=$A4)*(OCAK!$C$3:$I$3="nöbet")*(OCAK!$A$4:$A$34<=C$3))=7;8;EĞER(TOPLA.ÇARPIM(--(OCAK!$C$4:$I$34=$A4)*(OCAK!$C$3:$I$3="nöbet")*(OCAK!$A$4:$A$34<=C$3))>7;24;""))))

ve aynı şekilde 12 sayfada, 720 hücrede de aşağıdaki formül var.

=EĞER($A4="";"";EĞER(TOPLA.ÇARPIM(--(OCAK!$C$4:$I$34=$A4)*(OCAK!$C$3:$I$3="icap")*(OCAK!$A$4:$A$34=C$3))=0;"";24))

Bu formüllerle dosyanın boyutu 3,67 mb oldu, buda projenin normal konfigurasyondaki makinaların kasılmasına sebebiyet verecektir.
Bu formülleri makroya terfi etmek istiyorum.
Yardımcı olacak arkdaşlara teşekkür ederim.