Farklı satış faturalarını toplatıp aynı isimdeki carinin karşısına tek kalemde yazmak

[EMREKAYA]

Arkadaşlar Merhaba,

Elimde bir cari-satış faturaları dosyası var. İlk Sutünda Cariler ve İkinci Sutünda Satış Faturaları yer alıyor. Bana iste Tek kalemde satış faturaları lazım. Çünkü 6000-8000 satır lık bir döküman.

Yani;

Cariler Satış FATURALARI
A firması 500000
A firması 550000
A firması 150000
B firması 250000
C firması 350000
C firması 450000

Olması gereken;

Cariler Satış FATURALARI
A firması 1200000
B firması 250000
C firması 800000

gibi tek kalemde yazması lazım. Acaba böyle bir makro yazılabilir mi?

 

[Ömer]

Merhaba,

Özet tablo kullanmanızı tavsiye ederim..

ÖZET TABLOLAR (PİVOT TABLE)

Bunun dışında linkeride inceleyebilirsiniz. Ayrıca Mükerrer konusu forumda en fazla sorulan konulardan olduğu için arama yaparak istediğiniz sonuçlara ulaşabilirsiniz..

Mükerrer (Çift) Kayıt Engelleme,Sayma Örnekleri

Tekrarsız Liste

.

 

[Orion1]

Dosyanız ektedir.

Sub cari_toplami_59()
Dim z As Object, i As Long, sat As Long, a()
Sheets("Sayfa1").Select
Range("D2:E65536").ClearContents
Application.ScreenUpdating = False
sat = Cells(65536, "A").End(xlUp).Row
If sat < 2 Then Exit Sub
a = Range("A2:B" & sat).Value
Set z = CreateObject("Scripting.Dictionary")
For i = LBound(a, 1) To UBound(a, 1)
    If Not z.exists(a(i, 1)) Then
        z.Add a(i, 1), a(i, 2)
        Else
        z.Item(a(i, 1)) = z.Item(a(i, 1)) + a(i, 2)
    End If
Next
Range("D2").Resize(z.Count, 2) = Application.Transpose(Array(z.keys, z.items))
Application.ScreenUpdating = True
MsgBox "Cari toplamlar çıkarılmıştır." & vbLf & _
"evrengizlen@hotmail.com", vbOKOnly + vbInformation, "E V R E N"
End Sub

 

[EMREKAYA]

Sayın Evren Gizlen,

Tam istediğim kod
İşime çok yaradı...
Sonsuz teşekkürler. İyi Çalışmalar dilerim.

 

[Orion1]

Sayın Evren Gizlen,

Tam istediğim kod
İşime çok yaradı...
Sonsuz teşekkürler. İyi Çalışmalar dilerim.

Rica ederim.
İyi çalışmalar.