Excel - Mdb ilişki kurma hakkında

[Kemal Demir]

Arkadaslar iyi hafta sonları,

Access ile çalışmam gerekti ve bu konuda bilgi sahibi değilm.Eğer vakit ayırırsanız bir çalışma hazırlamama yardımcı olurmusunuz.

"\\WordPro\Cyber\Nos\Kg\PRg\340.mdb"

Yukarıdaki *.mdb dosya için hazırlamayı düşündüğüm 2 çalışma yapmak istiyorum.(arayüz olarak *.xls dosyası kullanmak istiyorum )

Planlanan 1. çalışma :Rastgele ( Table adı REHBER ) 100 veya 200 ( sayısını kendımızın belirleyebilceği ) veri çekmek istiyorum.*.mdb dosyasından bu veriler çekilirken ( E kolonumu demem lazım tam bilemiyorum yada 5 kolon mu ) çektiği verilerin 5 kolondaki satılarına *.mdb dosyasının içerisine "alındı" yazdırmak istiyorum.Daha sonra yapacagım calismalarda tekrar rastgele veri almak istedğimde "alındı" lar harıcınde veri çekmek istiyorum.

Mümkümmüdür mümkün ise bir örnek çalışma paylaşabilirmisiniz.

Planlanan 2. çalışma : C kolonu (mu demen gerekir yada 3 kolon mu bilemiyorum) içinde Rkb , Rtb ,Acd geçen ( Kendımızın Tanımlayabilceği dongu kurulabilcek bir mantıkta listbox'a eklendikten sonra aratılacak ürün kodlarını )

Excele aktarmak istiyorum

Bu iki çalışmayı da aynı anda kullanabilmem mumkummudur.Yoksa sadece bagımsız mı çalışıtırabilirim.

Umarım anlatabilmişimdir.

Bu konuda örnek çalışmalarınızla bana ışık tutabilirmisiniz.

 

[eardeem]

teşekkürler

 

[Kemal Demir]

İyi hafta sonları,

Açmış oldugum konu hakkında bilgi sahibi olan yada benzer bir çalışması olan arkadaslar konu hakkında bilgi paylaşabilirmisiniz.

Teşekkurler.

 

[Ferhat Pazarçevirdi]

340.mdb adlı dosyanın "RAKKAS" adlı tablosu ile ilgilendiğimizi varsayalım.

"RAKKAS" adlı table'in yapısı şu şekilde olsun ...

Sutun1 : Veri tipi, Önemli Değil
Sutun2 : Veri tipi, Önemli Değil
Sutun3 : Veri tipi, Önemli Değil
Sutun4 : Veri tipi, Önemli Değil
Sutun5 : Veri Tipi : Metin (En az 6 karakteri alacak şekilde)
Sutun6 : Veri tipi, Önemli değil
......
......

Bu şekilde bir yapı ile; aşağıdaki Excele_Getir makrosunu çalıştırırsanız, aktif Çalışma kitabının görünen sayfasının ilk hücresinden itibaren, rastgele çekilen kayıtları görebilirsiniz.

Option Explicit
[COLOR=darkgreen]'Önce projenize, Microsoft Activex Data Object X.X referansını ekleyiniz.[/COLOR]
Sub Excele_Getir()
[COLOR=darkgreen] 'Siz bu parametreyi kendinize göre ayarlayınız.[/COLOR]
[COLOR=darkgreen] 'veya bir inputbox'dan da alabilirsiniz.[/COLOR]
    MDB_Dosyadan_Rastgele_Veri_Cek (100) [COLOR=darkolivegreen]'100 sayısı çekilecek kayıt sayısını belirler.[/COLOR]
End Sub

Yukarıdaki kod, aşağıdaki özel prosedürü çalıştırır. Siz bu kısmı kendinize adapte ediniz.

Private Sub MDB_Dosyadan_Rastgele_Veri_Cek(lCekilecek_Kayit_Sayisi As Long)
    Dim cn As ADODB.Connection
    Dim rs As ADODB.Recordset
    Dim sql As String
    Dim iStr As Integer
    Dim lKayitNo As Long
    Dim j%, x%
[COLOR=darkgreen] 'Çekilecek kayıt sayısının kontrolü[/COLOR]
    If lCekilecek_Kayit_Sayisi = 0 Then
        MsgBox "Rastgele çekilecek kayıt sayısı belirlenmedi", vbCritical, "Uyarı"
        Exit Sub
    End If
 
[COLOR=darkgreen] 'Veritabanına yeni bir bağlantı yaratılıyor[/COLOR]
    Set cn = New ADODB.Connection
    cn.ConnectionString = "Provider=Microsoft.Jet.OLEDB.4.0;" & _
                          "Data Source=\\WordPro\Cyber\Nos\Kg\PRg\340.mdb;" & _
                          "User Id=admin;" & _
                          "Password=;"
    cn.Open
 
[COLOR=darkgreen] 'Excel sayfasına yazma için başlangıç satırı[/COLOR]
    iStr = 1
 
[COLOR=darkgreen] 'Sorgu cümleciği yapılandırılyor[/COLOR]
    sql = "SELECT * FROM RAKKAS WHERE Sutun5 IS NULL OR Sutun5<>" & "'Alındı'"
 
[COLOR=darkgreen] 'Yeni bir RecordSet (Kayit listesi) nesnesi oluşturuluyor[/COLOR]
    Set rs = New ADODB.Recordset
 
[COLOR=darkgreen] 'Recordset sorguya göre dolduruluyor[/COLOR]
    rs.Open sql, coN, adOpenKeyset, adLockOptimistic
 
[COLOR=darkgreen] 'Eğer Recordsetteki kayıt sayısı 0 ise[/COLOR]
    If rs.RecordCount = 0 Then
        MsgBox "Tüm kayıtlar daha önce alındı", vbCritical, "Uyarı"
        GoTo cikis
    End If
 
[COLOR=darkgreen] 'Eğer Recordsetteki kayıt sayısı, çekilecek kayıt sayısından büyük veya eşitse[/COLOR]
    If rs.RecordCount >= lCekilecek_Kayit_Sayisi Then
 
        For j = 1 To lCekilecek_Kayit_Sayisi
 
[COLOR=darkgreen]         'Sorguyu yenile[/COLOR]
            rs.Requery
 
[COLOR=darkgreen]         'Recorsetteki kayıtsayısın göre Rassal bir sayı üret[/COLOR]
            Randomize: lKayitNo = CLng(Rnd() * rs.RecordCount)
            If lKayitNo = 0 Then lKayitNo = lKayitNo + 1
 
[COLOR=darkgreen]         'Recordset cursor'ını, rassal sayıya göre belirlenen index'e yerleştir[/COLOR]
            rs.Move (lKayitNo - 1)
 
[COLOR=darkgreen]         'Cursor'ın üzerinde bulunduğu kaydı, sayfaya aktar[/COLOR]
            For x = 0 To rs.Fields.Count - 1
                Cells(iStr, x + 1) = rs.Fields(x).Value
            Next
 
[COLOR=darkgreen]         'Excel sayfasına yazdırılan kaydı, VT'de Alındı olarak işaretle[/COLOR]
            rs.Update "SUTUN5", "Alındı"
 
[COLOR=darkgreen]         'Sonraki kaydı sayfaya yazmak için yeni bir satır oluştur[/COLOR]
            iStr = iStr + 1
 
        Next j
 
[COLOR=darkgreen] 'Eğer Recordsetteki kayıt sayısı, çekilecek kayıt sayısından azsa[/COLOR]
    Else
[COLOR=darkgreen]     'Recordset'tekitüm kayıtları getir[/COLOR]
        Do Until rs.EOF
[COLOR=darkgreen]         'Sayfaya yazma[/COLOR]
            For x = 0 To rs.Fields.Count - 1
                Cells(iStr, x + 1) = rs.Fields(x).Value
            Next
[COLOR=darkgreen]         'Yeni satır oluşturma[/COLOR]
            iStr = iStr + 1
 
[COLOR=darkgreen]         'Alınan kaydı işaretleme[/COLOR]
            rs.Update "SUTUN5", "Alındı"
 
[COLOR=darkgreen]         'bir sonraki kayda geçme[/COLOR]
            rs.MoveNext
        Loop
 
    End If
cikis:
 
    cn.Close:   rs.Close
    Set cn = Nothing
    Set rs = Nothing
End Sub

 

[Kemal Demir]

Ferhat hocam iyi geceler,

Yarın sabah kodları deneyeceğim.Şimdiden teşekkurler.

 

[Kemal Demir]

Ferhat Bey,

'Recordset sorguya göre dolduruluyor
    rs.Open sql, [b]coN[/b], adOpenKeyset, adLockOptimistic

Yukarıdaki kodda hata alıyorum.

HATA:Veriable Not Defined

Acaba coN diye bir değişkenin yukarıda tanımlanmamasımıdır.Yada değilse Nasıl düzeltebiliriz.

Teşekkurler

 

[Ferhat Pazarçevirdi]

Evet dediğiniz gibidir. Ben size uyarlarken, coN adını değiştirmeyi unutmuşum. Doğrusu şu şekilde :

rs.Open sql, cn, adOpenKeyset, adLockOptimistic

 

[Kemal Demir]

Ferhat Bey,

Aşagıdaki hatayı almaktayım;

Run-Time error '-214217904 ( 80040e10 )';

No value given for one more required parameters

Bu konuda da yardımcı olabilirmisiniz.

Teşekkurler.

 

[Ferhat Pazarçevirdi]

Sn.Rakkas

Bu hatayla daha önce hiç karşılaşmadım ama hatanın hangi satırda oluştuğunu belirtirseniz, sorununuzun daha açık olacağına eminim.

İki nedenden kaynaklanabileceğini düşünüyorum. Ya connection'da (bağlantı'da) ya da record set (kayıt kümesi) oluşturmada bu hata ile karşılaşabilirsiniz.

 

[Kemal Demir]

Ferhat hocam iyi geceler,

Evet dediğiniz gibi Record ( Id ) verilmediğinden olsa gerek Id verince sorun çözüldü.

Tekrar tekrar teşekkurler.