Soru EXCEL DERECE ÇEVİRME

[hls06drm]

slm; excel a sütününda verilen dereceleri aşağıda belirtilen şekilde nasıl yapabilirim yardımlarınız için şimdiden teşekkür ederim.

Metin Biçimi Verisi	Sayı Biçimi Olacak
Verilen Derece	istenilen Derece
0.40.59	40,59​
50.33	50,33​
1.20.30	80,30​

1.22.75=82,75
58.20=58,20

1=dakika
22=saniye
75=salise

 

[volki_112]

slm; excel a sütününda verilen dereceleri aşağıda belirtilen şekilde nasıl yapabilirim yardımlarınız için şimdiden teşekkür ederim.

Metin Biçimi Verisi	Sayı Biçimi Olacak
Verilen Derece	istenilen Derece
0.40.59	40,59​
50.33	50,33​
1.20.30	80,30​

1.22.75=82,75
58.20=58,20

1=dakika
22=saniye
75=salise

Verilen derecelerin A sütununda olduğunu varsayarak yazıyorum

=EĞER(A3="";"";EĞER(UZUNLUK(A3)>5;SOLDAN(A3;MBUL(".";A3)-1);0)*60+SAYIYAÇEVİR(SOLDAN(SAĞDAN(A3;5);2))+SAYIYAÇEVİR(SAĞDAN(A3;2))/100)

 

[hls06drm]

Verilen derecelerin A sütununda olduğunu varsayarak yazıyorum

=EĞER(A3="";"";EĞER(UZUNLUK(A3)>5;SOLDAN(A3;MBUL(".";A3)-1);0)*60+SAYIYAÇEVİR(SOLDAN(SAĞDAN(A3;5);2))+SAYIYAÇEVİR(SAĞDAN(A3;2))/100)

ilginiz için teşekkür ederim

 

[Korhan Ayhan]

Bunlarda alternatif olsun...

Önerilerim verileri noktalardan split (parçalayarak) işlem yapar..

Ofis 2024 ve sonrası için;

=EĞER(A3="";"";EĞERHATA(TOPLA.ÇARPIM(METİNBÖL(A3;;".";1)*{60;1;0,01});TOPLA.ÇARPIM(METİNBÖL(A3;;".";1)*{1;0,01})))

Ofis 2016 ve sonrası için;

=EĞER(A3="";"";EĞERHATA(TOPLA.ÇARPIM(XMLFİLTRELE("<t><s>"&YERİNEKOY(A3;".";"</s><s>")&"</s></t>";"//s");{60;1;0,01});TOPLA.ÇARPIM(XMLFİLTRELE("<t><s>"&YERİNEKOY(A3;".";"</s><s>")&"</s></t>";"//s");{1;0,01})))

Daha eski sürümler için;

=EĞER(A3="";"";EĞERHATA(SOLDAN(A3;BUL(".";A3)-1)*60+PARÇAAL(A3;BUL(".";A3)+1;BUL(".";A3;BUL(".";A3)+1)-BUL(".";A3)-1)*1+SAĞDAN(A3;UZUNLUK(A3)-BUL("~";YERİNEKOY(A3;".";"~";2)))*0,01;SOLDAN(A3;BUL(".";A3)-1)*1+SAĞDAN(A3;UZUNLUK(A3)-BUL(".";A3))*0,01))