ETOPLA Formülüne tarih ve işçilik kriteri eklemek

[DOLAR]

Merhaba,

Ekteki dosyada Personel ismine göre ETOPLA formülü ile toplama yapıyor.
Bu formüle A:A sütunundaki tarih kriteri ve N:N Sütunundaki işçilik değerini ekleyip sadece ay bazında toplama yapmasını istiyorum.

Umarım kısa ve net olarak anlatabilmişimdir.

 

[omerfarukzorlu]

Asagidaki formulu D3 hucresine yapistirip asagi ve saga dogru surukleyince otomatik olarak butun Aylari hesaplayacak. Sadece D1den itibaren 1. satira ilgili aydan herhangi bir tarih girmeniz yeterli. D2den itibaren 2. satirda da aramak istediginiz "AA EKIPMAN" var. onu degistirirsenin baska bir veriyi arar.
Ornek olarak yaptigim degisikliklerle beraber dosyayi da yoilluyorum.
=SUMIFS('05-06 Kesilen Fatura'!$L:$L,
'05-06 Kesilen Fatura'!$E:$E, $B3,
'05-06 Kesilen Fatura'!$N:$N, $D$2,
'05-06 Kesilen Fatura'!$A:$A, ">="&DATE(YEAR(D$1),MONTH(D$1),1),
'05-06 Kesilen Fatura'!$A:$A, "<="&EOMONTH(D$1,0))

 

[DOLAR]

Emeğiniz ve İlginiz için teşekkür ederim.

 

[DOLAR]

Asagidaki formulu D3 hucresine yapistirip asagi ve saga dogru surukleyince otomatik olarak butun Aylari hesaplayacak. Sadece D1den itibaren 1. satira ilgili aydan herhangi bir tarih girmeniz yeterli. D2den itibaren 2. satirda da aramak istediginiz "AA EKIPMAN" var. onu degistirirsenin baska bir veriyi arar.
Ornek olarak yaptigim degisikliklerle beraber dosyayi da yoilluyorum.
=SUMIFS('05-06 Kesilen Fatura'!$L:$L,
'05-06 Kesilen Fatura'!$E:$E, $B3,
'05-06 Kesilen Fatura'!$N:$N, $D$2,
'05-06 Kesilen Fatura'!$A:$A, ">="&DATE(YEAR(D$1),MONTH(D$1),1),
'05-06 Kesilen Fatura'!$A:$A, "<="&EOMONTH(D$1,0))

Hocam Merhaba,

=ÇOKETOPLA('Satış Faturaları Tümü'!$L:$L;
'Satış Faturaları Tümü'!$E:$E; $A4;
'Satış Faturaları Tümü'!$P:$P; $B$2;
'Satış Faturaları Tümü'!$A:$A; ">="&TARİH(YIL(B$1);AY(B$1);1);
'Satış Faturaları Tümü'!$A:$A; "<="&SERİAY(B$1;0))

Verdiğiniz formül ile dosyamı biraz daha geliştirdikten sonra yıl sonu yaklaştığından sağlamalı kontroller yapıyordum.
Bir personelde farklı toplamlar görünce biraz daha inceledim.

ÖrneK ekli dosyada Personel 2 nin Ocak Şubat Mart toplamları yanlış fakat Nisan toplamı doğru.
Mart toplamına baktığımda 31 Mart tarihli veriyi toplamıyor. Ocak aynı şekilde 31 Ocak verisini toplamıyor.
Şubat ı ise neden toplamadığını bulamadım. Doğru sonuç alabilmek için nerede düzeltme yapmalıyım.

************************************************************************************************************************************************************

Ayrıca Satışlar 2023 sayfası A6 hücresindeki Diğer Personel kısmına tüm toplamı alıp Personel 1-2-3 olanı çıkarıyorum. Bunu Personel 1-2-3 hariç diğer personeli topla gibi farklı bir formül ile yapabilir miyim.

 

[DOLAR]

@omerfarukzorlu hocam dışında yardımcı olabilecek başka bir üye var mı?
Hocam forumu her gün ziyaret etmiyor olabilir.

 

[Korhan Ayhan]

Deneyiniz.

B3 ve sağa sürükleyiniz;

=ÇOKETOPLA('Satış Faturaları Tümü'!$L:$L;
'Satış Faturaları Tümü'!$E:$E;$A3;
'Satış Faturaları Tümü'!$P:$P;B$2;
'Satış Faturaları Tümü'!$A:$A;">="&B$1;
'Satış Faturaları Tümü'!$A:$A;"<="&SERİAY(B$1;0)+ZAMAN(23;59;59))

B6 ve sağa sürükleyiniz;

=ÇOKETOPLA('Satış Faturaları Tümü'!$L:$L;
'Satış Faturaları Tümü'!$E:$E;"<>"&$A$3;
'Satış Faturaları Tümü'!$E:$E;"<>"&$A$4;
'Satış Faturaları Tümü'!$E:$E;"<>"&$A$5;
'Satış Faturaları Tümü'!$P:$P;B$2;
'Satış Faturaları Tümü'!$A:$A;">="&B$1;
'Satış Faturaları Tümü'!$A:$A;"<="&SERİAY(B$1;0)+ZAMAN(23;59;59))

B8 ve sağa sürükleyiniz;

=ÇOKETOPLA('Satış Faturaları Tümü'!$L:$L;
'Satış Faturaları Tümü'!$T:$T;$A8;
'Satış Faturaları Tümü'!$P:$P;B$2;
'Satış Faturaları Tümü'!$A:$A;">="&B$1;
'Satış Faturaları Tümü'!$A:$A;"<="&SERİAY(B$1;0)+ZAMAN(23;59;59))

B11 ve sağa sürükleyiniz;

=ÇOKETOPLA('Satış Faturaları Tümü'!$L:$L;
'Satış Faturaları Tümü'!$A:$A;">="&B$1;
'Satış Faturaları Tümü'!$A:$A;"<="&SERİAY(B$1;0)+ZAMAN(23;59;59))-B7

 

[DOLAR]

Korhan Hocam,

Kusursuz çalışıyor.

Teşekkür Ederim. Emeğinize Sağlık...