EĞersay Yardim

[noxious]

Hazırladığım bir çalışmada personelin izinli olduğu günlerin toplamını almam lazım
daha önceleri =EĞERSAY($C3:$AG3;"izinli") formülü ile C3, D3, E3, ........AG3 hücresine kadar boşluk atlamadan izinli olduğu günlerde o güne denk gelen hücrelere izinli yazdığımda her izinli yazılı hücre için izin sayısı kadar toplam yazıyordu ama yeni yaptığımız çalışmada durum biraz değişti ve hücreler 1 arttı yani

C3, E3, G3, I3 ......... BM3 e kadar uzanıyor (aralarda birer boşluk var D3, F3, H3 ..... hücrelerinin atlanması lazım) yeni formüller denedim ama beceremedim. Bu konuda yardımlarınızı bekliyorum. Şimdiden teşekkürler

 

[Orion1]

dikkate almayacağınız hücreleri yazmadan bir kaç bölümde yapabilirsiniz.
Eğersay(aralık;ölçüt)+Eğersay(aralık;Ölçüt)+Eğersay(aralık;ölçüt)

 

[noxious]

Hocam karşıma çok uzun bir yol çıktı

=EĞERSAY(E3;"İzinli")+EĞERSAY(G3;"İzinli")+EĞERSAY(I3;"İzinli")+EĞERSAY(K3;"İzinli")+EĞERSAY(M3;"İzinli")+EĞERSAY(O3;"İzinli")+EĞERSAY(Q3;"İzinli")+...........................................EĞERSAY(BM3;"İzinli") gibi

toplam gün sayısını 31 gün olarak baz alırsak çok uzun bir formül oluyor. ayrıca izinli olmadığı günler hücresine sayısal değerler giriliyor. Ekte bir örnek sundum eski çalışmamızda sorun yoktu (hücre atlamadığımız için) izinli+sayı+izinli+sayı...........=toplam sayıyı veriyordu ama şimdi hücre atlatarak yaptığımız için hata oluşuyor. Yardım edebilirmisiniz. Teşekkürler

 

[noxious]

Son bir şey eklemeyi unuttum izinli kelimesi ekli dosyada görüldüğü gibi sadece "Kendi" başlığı altında olacak, "Takviye" bölümünde sadece sayısal değerler olacak sorun "Kendi" başlığının alt satırlarında oluyor

 

[AS3434]

BO3 hücresine

=TOPLA.ÇARPIM(($E$2:$BN$2="Kendi")*(E3:BN3="izinli"))

yazın.

 

[noxious]

Hocam formülü BU3 hücresine yazdım İzinli toplam sorunu kalktı
ancak
BO3 hücresine "Kendi" başlığı altında sayısal olarak dolu bulunan hücrelerin içindeki sayısal değerlerin toplamının gelmesi lazım ancak örneğin E3=10, G3=12, I3=İzinli, M3=İzinli, O3=7, Q3=9 ...... olduğunda 2 hücrede izinli yazılı olduğunda BO3 hücresine 2 sonucu doğru olarak geliyor ama BO3 hücresininde sayıların toplamı olan 38 olması lazımken BO3 Hücresinde "Değerde hata var" diyor.

 

[AS3434]

Yanlış anlamadıysam, BO3 hücresinde, o satırda ki sayısal değerleri toplamak istiyorsunuz.

Şu formülü deneyin.

=ETOPLA(E3:BN3;">0")

Yada "Kendi" kontrolu yapılarak "Kendi" olanları toplamak için.

=ETOPLA($E$2:$BN$2;"Kendi";E3:BN3)

 

[noxious]

Tamamdır Hocam sorun çözüldü Allah razı olsun

bu formülleri öğrenmem lazım

 

[noxious]

Hocam konu ile ilgili son bir sorum daha olacak

=TOPLA.ÇARPIM(($E$2:$BN$2="Kendi")*(E3:BN3="izinli"))

formülüne göre "Kendi" hücrelerini baz alarak

=EĞERSAY($E3:$BN3;">0")

haline nasıl getirebiliriz

 

[AS3434]

"Takviye" sütununda "İzinli" olmadığını varsayarak şöyle yaparsınız.

=EĞERSAY($E3:$BN3;"İzinli")

 

[noxious]

Hocam bu şekilde yapınca İzinli olanları sayıyor

Bana "Takviye" başlıklarının altını es geçerek sadece "Kendi" başlığı altında sayısal değer varsa her sayısal değer olan hücreyi sayarak hücre sayısını vermesi lazım

=EĞERSAY($E3:$BN3;">0") formülünde olduğu gibi ama sadece "Kendi" başlığı altındaki sayısal veri olan hücreleri sayacak

 

[AS3434]

E3:BN3 aralığında numerik olmayan değerler olduğu için, Topla.çarpım ile dediğiniz işlemi yapamazsınız.

=TOPLA.ÇARPIM(($E$2:$BN$2="Kendi")*(esayıysa(E3:BN3))) gibi bir formül kurulabilir ama o da sayısal değerlerin adedini verir. toplamını vermez.

İşleminizi aşağıdaki fonksiyon ile yapabilirsiniz.

=ETOPLA($E$2:$BN$2;"Kendi";E3:BN3)

 

[noxious]

Hocam Saygılar

=TOPLA.ÇARPIM(($E$2:$BN$2="Kendi")*(esayıysa(E3:BN3))) formülü istediğim formüldü bana sayısal değerlerin adedi lazımdı. Bu formül ile bir hücrede sayısal değerlerin adedini alırken

=ETOPLA($E$2:$BN$2;"Kendi";E3:BN3) bu formül ilede başka bir hücrede sayısal değerlerin toplamını aldım.

Gecenin bu saatinde ilgi ve alakanız için çok teşekkürler.
Siz ve sizin gibi uzmanlar biz acemilerden yardımlarınızı esirgemediğiniz için Allah sizlerden razı olsun.
Başka bir konuda başka bir sorunla başınızı ağrıtmak üzere hoşçakalın

 

[noxious]

Kurcaladıkça başka şeyleride merak ediyor insan

=TOPLA.ÇARPIM(($E$2:$BN$2="Kendi")*(E3:BN3="izinli")) formülünde
E2 hücresi ile BN2 hücresi arasında adı geçen "Kendi" hücrelerinin altında yazılı bulunan izinli sayısını buluyoruz peki bunu çeşitlendirme imkanımız varmı mesela "izinli" nin yanında "raporlu" ve "dış görev" kelimelerinide eklesek ve "Kendi" yazılı hücrelerin altında geçen "izinli+raporlu+dış görev" kelimelerinin sayısını aynı hücrede toplasa bu şekilde bir formül üretilebilirmi

 

[AS3434]

Kurcaladıkça başka şeyleride merak ediyor insan

=TOPLA.ÇARPIM(($E$2:$BN$2="Kendi")*(E3:BN3="izinli")) formülünde
E2 hücresi ile BN2 hücresi arasında adı geçen "Kendi" hücrelerinin altında yazılı bulunan izinli sayısını buluyoruz peki bunu çeşitlendirme imkanımız varmı mesela "izinli" nin yanında "raporlu" ve "dış görev" kelimelerinide eklesek ve "Kendi" yazılı hücrelerin altında geçen "izinli+raporlu+dış görev" kelimelerinin sayısını aynı hücrede toplasa bu şekilde bir formül üretilebilirmi

İkiside olur.

=TOPLA.ÇARPIM(($E$2:$M$2="Kendi")*((E3:M3="izinli")+(E3:M3="Raporlu")+(E3:M3="Dış Görev")))

=TOPLA.ÇARPIM(--($E$2:$M$2="Kendi");--((E3:M3="izinli")+(E3:M3="Raporlu")+(E3:M3="Dış Görev")))

 

[noxious]

Hocam Teşekkürler

Formüllerin işleyişini yavaş yavaş anlamaya başladım