Eğer formülü

[magnesia]

Arkadaşlar selam.
C2 hücresindeki değer;

12-20 arası ise "YETERSİZ"
21-30 arası ise "GELİŞMEYE İHTİYACI VAR"
31-40 arası ise "STANDART"
41-50 arası ise "VERİMLİ"
51-60 arası ise "MÜKEMMEL"

nasıl yazdırabilirim... (Formül H sütununa olacak)
Şimdiden teşekkürler

 

[turist]

H2 hücresine:

=EĞER(VE(C2>=12;C2<=20);"YETERSİZ";EĞER(VE(C2>=21;C2<=30);"GELİŞMEYE İHTİYACI VAR";EĞER(VE(C2>=31;C2<=40);"STVEART";EĞER(VE(C2>=41;C2<=50);"VERİMLİ";EĞER(C2>=51;"MÜKEMMEL")))))

yazın, kopyalayıp aşağıya gerektiği satıra kadar yapıştırın.

 

[Haluk]

=CHOOSE((C1>12)*(C1<=20)*1+(C1>20)*(C1<=30)*2+(C1>30)*(C1<=40)*3+(C1>40)*(C1<=50)*4+(C1>50)*(C1<=60)*5+((C1<12)+(C1>60))*6;"YETERSİZ";"GELİŞMEYE İHTİYACI VAR";"STANDART";"VERİMLİ";"MÜKEMMEL";"TANIMSIZ")

Türkçe Excel için CHOOSE yerine ELEMAN kullanın.

.

 

[turist]

Alternatif olarak;
Aynı sayfada, boş bir alana Örneğin AA, AB ve AC sütunlarında;
AA2 ye 12 AB2 ye 20 AC2 ye YETERSİZ
AA3 ye 21 AB3 ye 30 AC2 ye GELİŞMEYE İHTİYACI VAR
AA4 ye 31 AB4 ye 40 AC2 ye STANDART
AA5 ye 41 AB5 ye 50 AC2 ye VERİMLİ
AA6 ye 51 AB6 ye 60 AC2 ye MÜKEMMEL

Yazın.

H2 hücresine:
=ARA(C2;$AA$2:$AB$6;$AC$2:$AC$6)
formülünü yazın, kopyalayıp aşağıya doru yapıştırın.

 

[magnesia]

Arkadaşlar hepinize çok teşekkür ederim. Hepsi de işimi görüyor.
İlginize, bilginize ve emeğinize sağlık.

 

[turist]

Sağolun.

 

[Haluk]

Yukarıda 4 No'lu mesajda turist nickli arkadaşın önerdiği yöntemin, farklı bir versiyonu da kullanılabilir ....

=LOOKUP(C1;{0\12\21\31\41\51\61;"TANIMSIZ"\"YETERSİZ"\"GELİŞMEYE İHTİYACI VAR"\"STANDART"\"VERİMLİ"\"MÜKEMMEL"\"TANIMSIZ"})

Türkçe Excel için LOOKUP yerine ARA kullanın.

.

 

[magnesia]

Yukarıda 4 No'lu mesajda turist nickli arkadaşın önerdiği yöntemin, farklı bir versiyonu da kullanılabilir ....

=LOOKUP(C1;{0\12\21\31\41\51\61;"TANIMSIZ"\"YETERSİZ"\"GELİŞMEYE İHTİYACI VAR"\"STANDART"\"VERİMLİ"\"MÜKEMMEL"\"TANIMSIZ"})

Türkçe Excel için LOOKUP yerine ARA kullanın.

.

Haluk Bey ilginize ve emeğinize teşekkür ederim.