Eğer değer seçili hücreye eşitse

[preLude3]

If tar.Value = Sheets("ANASAYFA").Range("C131").Value

Kodlarımın içinde böyle bir kısım var. İstediğim şey, bu C131 hücresini o an seçili olan hücre olarak değiştirmek. Yani değer C131'e değil de o an tıklanmış olan hücreye eşitse demek istiyorum...

 

[preLude3]

bir sorum daha olacak;

If tar.Value = Sheets("ANASAYFA").Range("C131").Value Then
        Sheets("ANASAYFA").Range("A" & sat2 & ":P" & sat2).Value = Sheets("saatli").Range("B" & tar.Row & ":Q" & tar.Row).Value

Kodum bu şekilde. "saatli" sayfasından verileri "ANASAYFA" sayfasına çağırıyorum. Ama biçimlendirmesi sıfırlanıyor. Biçimlendirmesinin de olduğu gibi gelmesini nasıl sağlayabilirim?

 

[Korhan Ayhan]

Selamlar,

Konuyla ilgili olarak örnek dosya eklermisiniz.

 

[preLude3]

Buyrun. Baya detaylı bir örnek oldu umarım anlatabilmişimdir.
Gerçi başlıktan biraz saptım, en başta tıkladığım hücreye eşit değerleri çağıracaktım şmdi 2 solundaki oldu ama başlıktaki gibi olsa da olur sorun değil...

 

[preLude3]

arkadaşlar bana en azından şunun cevabını verseniz:

Örneğin C10 hücresine bir makro atadım. Bu hücreye tıklayınca makro çalışıyor. makronun içinde tıklamış olduğum hücrenin satır numarasını kullanmak istiyorum. nasıl olacak?

 

[preLude3]

sorumun cevabını kendim buldum ihtiyacı olanlara:

i = ActiveCell.Row

 

[Korhan Ayhan]

Selamlar,

Sorunuzun cevabını kendinizin bulması sizin için faydalı olmuş. Alternatif olarak sayfanızda kullandığınız tüm kodları silip yerine sadece aşağıdaki kodu kullanabilirsiniz.

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    Dim BUL As Range, ADRES As String, SATIR As Long
 
    If Intersect(Target, [D:E]) Is Nothing Then Exit Sub
    Application.ScreenUpdating = False
 
    If Target.Column = 4 And Target.Row < 132 Then
        Range("B134:R65536").Clear
        Sheets("saatli").Range("B1:Q1").Copy Range("B134")
        SATIR = 135
 
        Set BUL = Sheets("SAATLİ").Range("A:A").Find(Cells(Target.Row, "A"), LookIn:=xlValues)
        If Not BUL Is Nothing Then
        ADRES = BUL.Address
        Do
        Range("B" & SATIR & ":Q" & SATIR).Value = Sheets("SAATLİ").Range("B" & BUL.Row & ":Q" & BUL.Row).Value
        Sheets("SAATLİ").Range("B" & BUL.Row & ":Q" & BUL.Row).Copy
        Cells(SATIR, "B").PasteSpecial Paste:=xlPasteFormats
        Application.CutCopyMode = False
        SATIR = SATIR + 1
        Set BUL = Sheets("SAATLİ").Range("A:A").FindNext(BUL)
        Loop While Not BUL Is Nothing And BUL.Address <> ADRES
        End If
 
    ElseIf Target.Column = 5 And Target.Row < 132 Then
        Range("B134:R65536").Clear
        Sheets("TARİHLİ").Range("B1:R1").Copy Range("B134")
        SATIR = 135
 
        Set BUL = Sheets("TARİHLİ").Range("A:A").Find(Cells(Target.Row, "A"), LookIn:=xlValues)
        If Not BUL Is Nothing Then
        ADRES = BUL.Address
        Do
        Range("B" & SATIR & ":R" & SATIR).Value = Sheets("TARİHLİ").Range("B" & BUL.Row & ":R" & BUL.Row).Value
        Sheets("TARİHLİ").Range("B" & BUL.Row & ":R" & BUL.Row).Copy
        Cells(SATIR, "B").PasteSpecial Paste:=xlPasteFormats
        Application.CutCopyMode = False
        SATIR = SATIR + 1
        Set BUL = Sheets("TARİHLİ").Range("A:A").FindNext(BUL)
        Loop While Not BUL Is Nothing And BUL.Address <> ADRES
        End If
    End If
 
    Range("B134").Activate
    Application.ScreenUpdating = True
End Sub