Düşeyaralı Eğer Formülü

[Rheago]

Merhaba arkadaşlar. Excel bilgimi bu forumda araştırma yaparak geliştirmekteyim. Ve konu başlığında belirtildiği gibi düşeyara kullanarak eğer formülü kullanmak istiyorum. Aslında daha önce kullanmıştım ama yapmak istediğim şeyi tam olarak yapamadım. Örnek verecek olursak;


A TABLOSU

Ürün - Çıkış Deposu - Sevk Edilecek Depo
Güneş 1,Kanyon Mağazası - Vadi
Güneş 1,Emaar - Suadiye
Güneş 1,Tunalı - Nişantaşı
Güneş 2,Armada - Zorlu
Güneş 2,Bodrum -Turgut Reis
Güneş 2,Kanyon - Zorlu

Şimdi yukarıdaki listede Ürün sütunu A,Çıkış Sütunu B,Giriş Sütunu C olsun, Ürün ile beraberde satırlar 1,2,3,4 diye devam etsin.
Şimdi benim istediğim şey yukarıdaki Güneş 1 in gitmesi gereken mağazaya gidip gitmediğini öğrenmek istiyorum. Yani Güneş 1 bir Kanyondan vadiye, bir emaardan suadiyeye, birde tunalıdan nişantaşına gitmesi gerek. Benim istediğim şey gidip gitmediğini öğrenmek.

Alttakiler de gerçekleşen sevkiyatlar.

B TABLOSU

Ürün - Çıkış Deposu - Sevk Edilecek Depo
Güneş 1,Kanyon Mağazası - Vadi
Güneş 1,Tunalı - Nişantaşı
Güneş 2,Armada - Zorlu
Güneş 2,Kanyon - Zorlu

Ben ilk tablodaki giriş deposunun yanına aşağıdaki formülü yazdığımda, düşeyara yaparken her zaman sevkiyat tablosundaki ilk satırı baz alıyor. Örnek verecek olursak A Tablosundaki Vadiye sevk edilmesi gereken ürünü, B tablosunda ilk sırada bulduğu için "Doğru" olarak göstermekte. Fakat düşeyara, Nişantaşına sevk edilmesi gereken Güneş 1'i yine B tablosundaki ilk satırda aradığı için alt satırlarda aramıyor. Yani Güneş 1 i bulduğu ilk satırda varsa ve mağazalar eşleşmiyorsa direk yanlış veriyor. Ben istiyorum ki ilk satırda bulamıyorsa alttaki satırlarda da arasın.

=EĞER(DÜŞEYARA(A2;'B TABLOSU'!A:B;2;0)='A TABLOSU'!B2;"SEVK EDİLDİ";"EDİLMEDİ")
Kısacası hem A Tablosundaki Güneşlerin deki Çıkış deposu ve sevk edilecek deposu B Tablosunda varsa yada yoksa Var Yok yazmasını istiyorum.

https://dosya.co/1bi7r6gozo8u/Kitap1.xlsx.html

 

[çıtır]

A tablosu D2 hücresine kopyalayınız.Aşağı doğru çoğaltınız.

=EĞER(ÇOKEĞERSAY('B TABLOSU'!$A$2:$A$200;$A2;'B TABLOSU'!$B$2:$B$200;$B2;'B TABLOSU'!$C$2:$C$200;$C2)>0;"SEVK EDİLDİ";"EDİLMEDİ")

 

[Rheago]

Çok teşekkür ederim. Son bir şey daha rica edeceğim sizden. E sütununa sevk edilenlerin B Tablosundaki referans numaralarını nasıl ekleyebilirim.

 

[çıtır]

Rica ederim.Aşağıdaki formülü.E2 Hücresine kopyalayınız.Aşağı doğru çoğaltınız.

=EĞERHATA(İNDİS('B TABLOSU'!$D$1:$D$200;EĞER($D2="SEVK EDİLDİ";TOPLAMA(15;6;(SATIR($A$2:$A$200)/((('B TABLOSU'!$A$2:$A$200=$A2)*('B TABLOSU'!$B$2:$B$200=$B2)*('B TABLOSU'!$C$2:$C$200=$C2))));SATIR($A$1));""));"")

 

[Rheago]

Tekrardan teşekkürler. Asıl tabloya kendim yapmaya çalışacağım.