Dikey olarak üsteki dolu hücre ile birleştirme

[qwertyemre]

örnekte gösterdiğim gibi A1 sutunundan aşağıya doğru boş satırları üsteki dolu hücreyle birleştirip tek bir hücre yapmak istiyorum. Nasıl yapabilirim?
Yardımcı olan olursa sevinirim.
Saygılar

 

[Ferhat Pazarçevirdi]

Merhabalar

Aşağıdaki kodları deneyiniz. Son satır'ın nereye kadar birleştirileceği belli olmadığı için dokunulmadı.

Sub Birlestir()
Dim hcr As Range
Dim satir As Long
Set hcr = Cells(2, 1)
Do While hcr.Address <> Cells(65536, 1).Address
   satir = hcr.End(xlDown).Row
   If satir <> 65536 Then
       With Range(hcr, hcr.Offset(satir - hcr.Row - 1, 0))
           .MergeCells = True
           .HorizontalAlignment = xlCenter
           .VerticalAlignment = xlCenter
       End With
   End If
   Set hcr = hcr.End(xlDown)
Loop
Set hcr = Nothing
End Sub

 

[Necdet]

Merhaba,
Sayın fpc yanıtlamış ama her yiğidin bir yoğurt yemesi varmış

A hücresinde son satırın birleştirilmesinin B hücresine bağlı olduğunu varsayarsak

Sub Merge_Yap()
SonSat = [B65536].End(3).Row
For i = 2 To [A65536].End(3).Row
    j = Cells(i, "A").End(xlDown).Row
    If j > SonSat Then
        j = SonSat
    Else
        j = j - 1
    End If
    
    With Range(Cells(i, "A"), Cells(j, "A"))
        .HorizontalAlignment = xlCenter
        .VerticalAlignment = xlCenter
        .MergeCells = True
    End With
    i = j
Next i
End Sub

 

[qwertyemre]

İkisi de çok işime yaradı
Çok teşekkür ederim

 

[atilayildirim]

selamlar,

benim de qwertyemre' nin sorununa benzeyen bir sorunum var. tek fark: bendeki boş hücrelerde de formül bulunması. buna bağlı olarak sadece sütunun en üstündeki hücre değerini alıp tüm sütunu birleştiriyor. bu konuda yarımcı olursanız çok sevinirim. şimdiden teşekkürler.