Combobox içerisine sadece sayı girişi olunca veri aktarmıyor

[RamazanCager]

Merhaba Arkadaşlar.
Web siteniz sayesinde kendimce bir excel dosyası hazırladım. Ancak bir sorunu aşamadım. Combobox içerisine PLAKA listesi aktarılmış ve plaka dinamik olarak seçilince yan sütünlardaki bazı verileri textboxlara atıyor. Comboboxta sadece rakamlardan oluşan bazı plakalar seçilince bilgiler textboxlara aktarılmıyor. Bu konuda yardımcı olursanız sevinirim.
Kayıt ekleme menüsü Sayfa sol üst köşesinde 3 çizgi yada Ctrl+Enter tuşlarıyla geliyor.

Dosya linki

İndir Yakıt Takip xlsm

Dosyayı indir Yakıt Takip xlsm

dosya.co

 

[Korhan Ayhan]

Merhaba,

Bu kodları deneyebilirsiniz.

' UserForm açılırken verileri yükle
Private Sub UserForm_Initialize()
    Dim ws As Worksheet
    Dim lastRow As Long
    
    Set ws = Worksheets("Data")
    
    ' Combobox özelliklerini ayarla
    With Me.cbx_plaka
        .ColumnCount = 4
        .BoundColumn = 1
        .ColumnWidths = "80;0;0;0"  ' Sadece A sütunu görünsün
        
        ' Data sayfasındaki son dolu satırı bul
        lastRow = ws.Cells(ws.Rows.Count, "D").End(xlUp).Row
        
        ' A:D sütunlarındaki tüm verileri yükle
        If lastRow >= 2 Then
            .List = ws.Range("A2:D" & lastRow).Value
        End If
        
        .ListRows = Application.WorksheetFunction.Min(10, .ListCount)
    End With
    
    ' Diğer başlangıç ayarları
    If ws.Range("G2") = "" Then
        UserForm1.tb_tarih.Value = Format(Date, "dd.mm.yyyy")
        UserForm1.tb_teslimeden.Text = ws.Range("E2")
    Else
        UserForm1.tb_tarih.Text = ws.Range("G2")
        UserForm1.tb_teslimeden.Text = ws.Range("E2")
    End If
End Sub

' Combobox'ta seçim değiştiğinde
Private Sub cbx_plaka_Change()
    ' Seçim yapıldıysa
    If Me.cbx_plaka.ListIndex >= 0 Then
        ' Gizli sütunlardaki verileri textbox'lara yaz
        Me.tb_cinsi.Text = Me.cbx_plaka.Column(1)  ' B sütunu
        Me.tb_birim.Text = Me.cbx_plaka.Column(2)  ' C sütunu
        Me.tb_mulkiyet.Text = Me.cbx_plaka.Column(3)  ' D sütunu
    End If
End Sub

 

[RamazanCager]

Korhan bey elinize sağlık. Combobox içerisine sadece sayısal değerler girince textboxlara aktarmama sorunu çözülmüş . Ancak önceki halinde combobox filtreleme yapıyordu şimdi yapmıyor bu kodlarda yok sanırım.

 

[Korhan Ayhan]

Tam olarak neyi filtreliyordu?

 

[RamazanCager]

Tam olarak neyi filtreliyordu?

Comboboxa Plaka baş harflerini yazdıkça eşdeğer olanları açılan listede gösteriyordu.

 

[Korhan Ayhan]

Böyle deneyiniz.

' Combobox'ta seçim değiştiğinde
Private Sub cbx_plaka_Change()
    Dim i As Long
    Dim ws As Worksheet
    Dim lastRow As Long
    
    If Not Comb_Arrow Then
        Set ws = Worksheets("Data")
        With Me.cbx_plaka
            ' Data sayfasındaki son dolu satırı bul
            lastRow = ws.Cells(ws.Rows.Count, "D").End(xlUp).Row
            
            ' A:D sütunlarındaki tüm verileri yükle
            If lastRow >= 2 Then
                .List = ws.Range("A2:D" & lastRow).Value
            End If
            .ListRows = Application.WorksheetFunction.Min(10, .ListCount)
            .DropDown
            If Len(.Text) Then
                For i = .ListCount - 1 To 0 Step -1
                    If InStr(1, .List(i), .Text, vbTextCompare) = 0 Then .RemoveItem i
                Next
            .DropDown
            Me.Repaint
            End If
         End With
     End If
    
    ' Seçim yapıldıysa
    If Me.cbx_plaka.ListIndex >= 0 Then
        ' Gizli sütunlardaki verileri textbox'lara yaz
        Me.tb_cinsi.Text = Me.cbx_plaka.Column(1)  ' B sütunu
        Me.tb_birim.Text = Me.cbx_plaka.Column(2)  ' C sütunu
        Me.tb_mulkiyet.Text = Me.cbx_plaka.Column(3)  ' D sütunu
    End If
End Sub

 

[RamazanCager]

Teşekkür ederim.