çoklu kritere göre düşeyara

[gezgin-49]

Sayın üstadlarım ekteki dosyada Veri sayfası ile sonuç sayfasındaki A,C,D,I hücreleri birbirine eşit ise Veri Sayfası G hücresini Sonuç sayfasında G hücresine yazmasını istiyorum. saygılarımla

 

[yanginci34]

Merhabalar bu konuyu bende merak ettim yardımcı olan arkadaşlara şimdiden teşekkürler.

 

[yanginci34]

Konu günceldir ve benim de böyle bir şeye ihtiyacım var.

 

[gezgin-49]

aslında ben kısa yolunu buldum şöyle ki düşeyara yapacağım hangi hücreler varsa önce onları birleştidikten sonra arama yapacağım yerdeki verileri de aynı şekilde birleştirdikten sonra norma düşeyara formülü ile yapılabiliyor

 

[askm]

Aşağıdaki formül dizi formul olarak deneyin. (Dizi formul demek formulü yazdıktan sonra CTRL+Shift + Enter tuşuna basmak. Sonrasında formulu alt köşeden çekip alta doğru sürükleyin.)

{=EĞERHATA(İNDİS(VERİ!G:G;KAÇINCI(A2&C2&D2&I2;VERİ!A:A&VERİ!C:C&VERİ!D&VERİ!I:I;0));"")}

 

[Ömer BARAN]

Merhaba.

1) Yardımcı sütun kullanarak;
-- VERİ sayfası Z2 hücresine (yardımcı sütun) aşağıdaki formülü uygulayın ve aşağı doğru liste boyunca kopyalayın.
.

=A2&C2&D2&I2

-- SONUÇ sayfası G2 hücresine aşağıdaki formülü uygulayın ve liste boyunca kopyalayın.
.

=EĞER(EĞERSAY(VERİ!$Z:$Z;A2&C2&D2&I2)=0;"";KAYDIR(VERİ!$G$1;KAÇINCI(A2&C2&D2&I2;VERİ!$Z:$Z;0)-1;0))

2) TOPLA.ÇARPIM işlevini kullanarak;
-- SONUÇ sayfası G2 hücresine aşağıdaki formülü uygulayın ve aşağı doğru kopyalayın.
.

=EĞER(TOPLA.ÇARPIM((VERİ!$A$1:$A$5457=A2)*(VERİ!$C$1:$C$5457=C2)*(VERİ!$D$1:$D$5457=D2)*(VERİ!$I$1:$I$5457=I2)*(SATIR(VERİ!$A$1:$A$5457)))=0;"";KAYDIR(VERİ!$G$1;TOPLA.ÇARPIM((VERİ!$A$1:$A$5457=A2)*(VERİ!$C$1:$C$5457=C2)*(VERİ!$D$1:$D$5457=D2)*(VERİ!$I$1:$I$5457=I2)*(SATIR(VERİ!$A$1:$A$5457)))-1;0))

3) DİZİ FORMÜLÜ kullanarak;
-- SONUÇ sayfası G2 hücresine aşağıdaki dizi formülünü uygulayın ve aşağı doğru liste boyunca kopyalayın.
.

=EĞERHATA(KAYDIR(VERİ!$G$1;KAÇINCI(A2&C2&D2&I2;VERİ!$A$1:$A$5457&VERİ!$C$1:$C$5457&VERİ!$D$1:$D$5457&VERİ!$I$1:$I$5457;0)-1;0);"")
[COLOR="blue"]Formül dizi formülü olup hücreye [B][COLOR="Red"]CTRL+SHIFT+ENTER[/COLOR][/B] ile uygulanmalıdır.
İşlem doğru yapılmışsa formül [B]kendiliğinden  [COLOR="red"]{....}[/COLOR][/B]  şeklinde köşeli parantez içine alınır.[/COLOR]

 

[yanginci34]

Sayın askm ben nerede hata yapıyorum acaba denedim ve sonuç bu incelerseniz sevinirim.
Ekli dosyayı görüntüle çoklu KRİTER DENEME.xls

 

[askm]

Girdiğiniz şekilde doğru. Yalnız formullerin işleyebilmesi için SONUÇ ve Veri sayfasında yazımlar aynı olması gerekir. Birinde büyük harf diğerinde küçük harf işlem yapmaz.

 

[Ömer BARAN]

Tekrar merhaba.

Sanırım önceki cevabımı fark etmediniz.
Eğer verdiğim yöntemlerle istediğiniz sonucu alamıyorsanız;
hatalı olarak gördüğünüz sonucun yerine olması gereken sonucun ne olduğunu (net hücre adresi belirterek) ve
bunu nasıl bulduğunuzu açıklayınız.

Yanılmıyorsam Sayın askm'nin verdiği formülle de aynı sonucu alırsınız.
.

 

[yanginci34]

Sayın askm ve Sayın Ömer bey, öncelikle ilginizden ötürü çok teşekkür ederim. örnek olarak, sonuç sayfası g41 e gelmesi gereken MEHMET CAN gelmiyor c sütununda bu verinin 2014/788 yazıyor veri sayfasında filtre uygulandığı zaman 2 adet aynı veri sadece I sütunundaki numaraların farklı olduğunu gördüm nacizane fikrim bundan kaynaklanıyor olabilir. Tekrar teşekkür ederim.

 

[Ömer BARAN]

-- SONUÇ sayfası A41'deki değer "sulh hukuk mahkemesi"
-- VERİ sayfası A253 ve A552 hücrelerindeki değer ise (filtre sonucunda kaldığını belirttiğiniz satırlar) "ASLİYE HUKUK MAHKEMESİ"

A sütununa da filtre uygularsanız sonuç BOŞ olur ve dolayısıyla da SONUÇ sayfası 41'inci satırda BOŞ sonuç almanız NORMAL.
.

 

[yanginci34]

Sayın Ömer Bey, sonradan onu bende fark ettim elinize sağlık kolay gelsin.