ÇOK EĞER KULLANIMI

[SSAFFAK]

Sevgili hocalarım merhabalar; Benim iki ayrı listede kullanmak üzere yaklaşık 30 listem var. Şöyle bir sorunum var. 1. listedeki hücreye yazılmış kısaltmaların 2. listedeki o kısaltmanın karşılığını yazdırmak istiyorum. Fakat çok eğer kullanıyorum. Bunun daha kısa yolu varmıdır? örnek formülüm

=EĞER(YADA(LİSTE!F60="A+";LİSTE!F60="A++";LİSTE!F60="B+";LİSTE!F60="B++");"FAZLA MESAİ";EĞER(LİSTE!F60="Sİ";"SENELİK İZİN";EĞER(LİSTE!F60="DG";"DOĞUM GÜNÜ";EĞER(LİSTE!F60="SGK";"RAPORLU";EĞER(LİSTE!F60="Eİ";"EVLİLİK İZNİ";EĞER(LİSTE!F60="Üİ";"ÜCRETSİZ İZİN";EĞER(LİSTE!F60="Şİ";"ŞUA İZNİ";EĞER(LİSTE!F60="Dİ";"DOĞUM İZNİ";EĞER(LİSTE!F60="EG";"EĞİTİM";EĞER(LİSTE!F60="Öİ";"ÖLÜM İZNİ";""))))))))))

 

[Ömer]

Merhaba
Farklı bir sayfa yada aralıkta ilk sütuna şartları ikinci sütuna şartların karlılıklarını yazıp düşeyara fonksiyonunu kullanmanızı tavsiye ederim.

 

[SSAFFAK]

Ömer Hocam düşeyara formülünü kullandım ama olmadı. Biraz karışık bir durum ama şöyle; "Mesai fişi" sayfasındaki açıklama "ı12"bölümüne Liste F60 taki veriye göre "Liste AN60-AO60 listesindeki kısaltmaların karşılığına denk gelen açıklamayı yazdırmaya çalışıyorum.

 

[Ömer]

=DÜŞEYARA(LİSTE!F60;LİSTE!$A$65:$C$71;2;0)

LİSTE!$A$65:$C$71

bu aralıkta şartlar ve karışlıklarının olması gerekirdi. Bu aralık boş.

 

[SSAFFAK]

=EĞER(YADA(LİSTE!F66="A+";LİSTE!F66="A++";LİSTE!F66="B+";LİSTE!F66="B++");"FAZLA MESAİ";DÜŞEYARA(LİSTE!F66;LİSTE!$AO$60:$AP$68;2;0))

Hocam verdiğiniz formülü bu şekilde uyarladım doğru çalışıyor fakat bunların dışındaki veriler olduğunda hücreye #YOK yazıyor
Bunların dışındakiler için hücreyi boş bıraktırmaya çalışıyorum ama yapamadım bir türlü.
Biliyorum başınızı ağrıttım. Kusuruma bakmayın hocam..

 

[Ömer]

Deneyiniz.

=EĞERHATA(EĞER(YADA(LİSTE!F66="A+";LİSTE!F66="A++";LİSTE!F66="B+";LİSTE!F66="B++");"FAZLA MESAİ";DÜŞEYARA(LİSTE!F66;LİSTE!$AO$60:$AP$68;2;0));"")

Not:Telefondan yazdığım için kopyalama hatalı olabilir.

 

[SSAFFAK]

Ömer hocam çok teşekkür ederim. Allah razı olsun. Elinize kolunuza sağlık..

 

[SSAFFAK]

Hocam bir düşeyara formülünde iki adet farklı liste kullanılabilirmi ? Örneğin aşağıdaki listede a+ve b+ ları AQ60:AR63 Listesinde düşünürsek 2 farklı listeyi tek düşeyara formülü ile nasıl yazabilirim.

=EĞERHATA(EĞER(YADA(LİSTE!F66="A+";LİSTE!F66="A++";LİSTE!F66="B+";LİSTE!F66="B++");"FAZLA MESAİ";DÜŞEYARA(LİSTE!F66;LİSTE!$AO$60:$AP$68;2;0));"")

 

[Ömer]

Yapabilirsiniz tabi. Fakat tüm listeyi aynı aralığı yazmak bana göre daha pratik olur.

Tablo dizisine de şart yazılabilir fakat sizin formülde daha karışık durur.

=EĞERHATA(EĞER(YADA(LİSTE!F66="A+";LİSTE!F66="A++";LİSTE!F66="B+";LİSTE!F66="B++");DÜŞEYARA(LİSTE!F66;AQ60:AR63;2;0);DÜŞEYARA(LİSTE!F66;LİSTE!$AO$60:$AP$68;2;0));"")

 

[SSAFFAK]

Ömer hocam merhabalar; Ben farklı bir yolla çözdüm. yukarıdaki verileri ayrı bir liste yaptım ve düşeyara ile karşılıklarını getirttim. Çok kısa bir formül oldu.
=IFERROR(VLOOKUP(LİSTE!F60;SAATLER;2;0);"")

Elinize emeğinize sağlık..

 

[SSAFFAK]

Sadece F60 taki verilerin sonundaki boşlukları olma ihtimaline karşılık KIRP formülünü uyarlayamadım.

 

[Korhan Ayhan]

Deneyiniz.

=IFERROR(VLOOKUP(TRIM(LİSTE!F60);SAATLER;2;0);"")

 

[SSAFFAK]

Süpersiniz. Hakkınız ödenmez çok teşekkür ederim. Çok Sağolun..