Buton yardımıyla ilgili sayfaya veri aktarımı

[dus_sokagi]

Merhaba Arkadaşlar,

Ekteki dosyada örneklendirmeye çalıştığım gibi, bir buton yardımıyla verileri ilgili çalışma sayfasına aktarmak başka bir buton ile de ilgili veriyi silmek istiyorum,

Excel'im çok iyi değil örnekler bulmaya çalıştım ancak çalışma bana acil lazım olduğundan yardım rica ediyorum. Yardımcı olabilecek arkadaşlara teşekkür ederim.

 

[Ömer]

Merhaba,

Veri eklemek için:

Sub VeriEkle()
 
    Dim son As Long, i As Long
 
    Sheets("Sayfa1").Select
 
    With Sheets("" & Range("A3") & "")
        For i = Range("C3") To Range("D3")
            son = .Cells(Rows.Count, "D").End(xlUp).Row + 1
            .Cells(son, "A") = Range("E3")
            .Cells(son, "B") = Range("A3")
            .Cells(son, "C") = Range("B3")
            .Cells(son, "D") = i
            .Cells(son, "E") = Range("F3")
        Next i
    End With
 
End Sub

Veri silmek için:

Sub VeriSil()
 
    Dim c As Range
 
    Sheets("Sayfa1").Select
 
    With Sheets("" & Range("A8") & "")
        Set c = .Range("D:D").Find(Range("B8"), , xlValues, xlWhole)
        If Not c Is Nothing Then
            .Range("A" & c.Row & ":E" & c.Row).ClearContents
            .Cells(c.Row, "F") = Range("C8")
        End If
    End With
 
End Sub

.

 

[dus_sokagi]

Teşekkür ederim Ömer Bey elinize emeğinize sağlık.

 

[dus_sokagi]

Verileri tek sayfaya eklemek istiyorum ekleme kısmını yaptım ancak veri silme kısmında veriyi sadece "SERİ NO" ya göre değil aynı zamanda "ADI" na göre de yapmak istiyorum, SERİ NO ve ADI aynı olan veriyi silsin.

bunun için aşağıdaki değişikliği yaptım ancak hata veriyor nasıl bir değişiklik yapmam gerekir

Set c = .Range("D: D").Find(Range("B8"), , xlValues, xlWhole))

Set c = .Range("B:B").Find(Range("A8") And .Range("D: D").Find(Range("B8"), , xlValues, xlWhole))

 

[Ömer]

Bu şekilde deneyin.

Sub VeriSil()
 
    Dim i As Long
 
    Application.ScreenUpdating = False
    Sheets("Sayfa1").Select
 
    With Sheets("" & Range("A8") & "")
        For i = 2 To .Cells(Rows.Count, "D").End(xlUp).Row
            If .Cells(i, "D") = Range("B8") And _
                .Cells(i, "B") = Range("A8") Then
                .Range("A" & i & ":E" & i).ClearContents
                .Cells(i, "F") = Range("C8")
            End If
        Next i
    End With
 
End Sub

.