bugünkü tarihten sonraki ilk salı gününü bulma

[ferhatgurbuz]

16 Aralık 2011 Cuma


Kolay gelsin arkadaşlar. C9 hücresinde Bugün() formülü ile yukarıdaki formatta tarih alıyorum. C9 dan sonraki hücreler bu tarihten 15 gün sonrasına göre sıralanıyor.
Yapmak istediğim C35 hücresine C9 hücresindeki tarihten sonraki ilk salı gününün tarihini versin.

Örnek bugün günlerden 16 Aralık Cuma ise C35 hücresine 20 Aralık salıyı vermesini istiyorum.

 

[Ömer]

Merhaba,

Linkleri inceleyiniz.

TARİH VE SAAT FONKSİYONLARININ DETAYLI ANALİZİ

Tarih & Zaman & Saat Fonksiyonları Uygulamaları

.

 

[mnrs_]

C35'e aşağıdaki formülü yazmayı dener misiniz?

=C9+(7-HAFTANINGÜNÜ(C9;13))

 

[ferhatgurbuz]

Dosyayı tekrar güncelledim.

birkaç formül buldum ama C9 daki Bugün() formülündeki veri değiştikçe formül tutmadı. ilgilenirseniz sevinirim kolay gelsin.

 

[Ömer]

Dosya eklemişsiniz fakat içerisinde açıklama yok. Dosyanızda olması gerekenleri manuel yazarak detaylı açıklama yaptıktan sonra tekrar eklermisiniz.

 

[Korhan Ayhan]

Merhaba,

Aşağıdaki formülü denermisiniz.

=EĞER(D1="";"";D1+ARA(HAFTANINGÜNÜ(D1;2);{1;2;3;4;5;6;7};{1;7;6;5;4;3;2}))

 

[ferhatgurbuz]

Teşekkür ederim. Sağolun. Bir sorum daha olacak excel sayfasında D36 hücresinde olan bir veriyi userfor üzerinde Textbox8 üzerine almak istiyorum. Nasıl bir yöntem izlemem lazım.

 

[ferhatgurbuz]

Kusura bakmayın yukaridaki formül geçen hafta için olmuştu ama maalesef bugün hata veriyor.
Örnek vercek olursak Bugün 02.01.2012 olduğu için bugünden sonraki llk salı 03.01.2012 formül bu tarihi vermesi gerekiyor ama formül ayın 10.01.2012 yi gösteriyor. Yani ilk salıyı atlıyor ikinci salıyı veriyor.

 

[mancubus]

=A1+MOD(10-WEEKDAY(A1);7)
=A1+MOD(10-HAFTANINGÜNÜ(A1);7)

A1: baz tarihin olduğu hücre...


not: formül alıntıdır.

 

[mancubus]

yukarıdaki formül A1'deki tarih salı ise aynı günü verir.

bir hafta sonraki salı istenirse şöyle bir formül buldum:

=IF(WEEKDAY(A1)>2;A1+8-WEEKDAY(A1)+2;A1-WEEKDAY(A1)+3)
=IF(HAFTANINGÜNÜ(A1)>2;A1+8-HAFTANINGÜNÜ(A1)+2;A1-HAFTANINGÜNÜ(A1)+3)

 

[Korhan Ayhan]

Merhaba,

#6 nolu mesajımdaki formülü güncelledim. Ayrıca örnek dosya ekledim. İncelermisiniz.

 

[Necdet]

Merhaba,

Bir formülde benden olsun :

=BUGÜN()+[COLOR=red]2[/COLOR]-HAFTANINGÜNÜ(BUGÜN();2)+([COLOR=red]2[/COLOR]<HAFTANINGÜNÜ(A1;2))*7

Kırmızı ile yazılan istenilen haftanın gün sayısıdır.

1 - > Pazartesi
2 - > Salı......

 

[ferhatgurbuz]

Arkadaşlar hepinize ayrı ayrı teşekkkür ederim. Çok sağolun.Bugünkü tarihe göre sıkıntı yok gibi. Bakalım ileriki günlerde sıkıntı verecekmi inşallah vermez . Sizlere kolay gelsin hayırlı çalışmalar.

 

[yhelvaci]

Merhaba,

Konu eski fakat arayan başka arkadaşlar olursa yardımı olur diye ben de formül paylaşayım dedim.

Belirli bir günden sonraki herhangi bir günü, hafta kısıtı olmak şartı ile hesaplamak için kullanılır.

Örnek:

A1 hücresine yazdığımız bir tarihten 1 hafta sonraki Salı gününü bulmak.

=(A1+(2-(WEEKDAY(A1;2))+7))

Örneğe göre açıklama olarak:

A1= herhangi bir tarih
2= haftanın hangi gününü bulmak istiyorsak o günün günsayısı (burada Salı=2)
WEEKDAY(A1;2) = A1 hücresine yazdığımız günün haftanın kaçıncı günü olduğunu bulur
+7= kaç hafta sonrasının sonucunu arıyorsak o kadar gün sayısı eklenir (2 hafta sonrasının Salı gününü arıyor olsaydık +14 olacaktı)

 

[rabbace]

Merhabalar,

Herhangi bir yılın Eylül ayının 3. salı gününü bulan formülü nasıl yazabilirim?

Dinamik bir formül olmalı, Mayıs ayının 2. pazartesi günün de aynı formülle bulabilmem lazım. Mümkün müdür acaba?

 

[Ali]

F2 hücresi

=TARİH($A$2;D2;1+7*$B$2)-HAFTANINGÜNÜ(TARİH($A$2;D2;8-$C$2))

B2 hücresi o ayın kaçıncı Pazartesi, Salı ,Çarşambasına bakılacak ise o yazılır.

C2 hücresine H1:I7 aralığında ki göre Salıya bakılacak ise 3 , Cumartesine bakılacak ise 7 yazılır.

D2 kısmında Mayıs ayı içini arayacak isek , 5 ayı temsilen 5 yazılır.

 

[rabbace]

Ekli dosyayı görüntüle 251755

F2 hücresi

=TARİH($A$2;D2;1+7*$B$2)-HAFTANINGÜNÜ(TARİH($A$2;D2;8-$C$2))

B2 hücresi o ayın kaçıncı Pazartesi, Salı ,Çarşambasına bakılacak ise o yazılır.

C2 hücresine H1:I7 aralığında ki göre Salıya bakılacak ise 3 , Cumartesine bakılacak ise 7 yazılır.

D2 kısmında Mayıs ayı içini arayacak isek , 5 ayı temsilen 5 yazılır.

Çok teşekkürler Ali Bey, tam olarak aradığım buydu.