bugün'e eşit olan hücreleri msgboxda görmek

[ismetali]

arkadaşlar istediğim b2 f300 aralığındaki hücrelerin j1 hücresine eşitliği durumunda mesaj yazdırabilmek mesajdada ilgili hücrenin satır ve sütun değerlerini kullanabilmek, örnek daha açıklayıcı, şimdiden teşekkürler

 

[Orion1]

Dosyanız ekte.

Sub mesaj()
Dim i As Long, msj As String, k As Byte, sahis As String, msg2 As String
Dim var As Boolean
With Sheets("gün")
    For i = 2 To .Cells(65536, "A").End(xlUp).Row
        var = False
        sahis = "": msg2 = ""
        For k = 2 To 6
            If .Cells(i, k).Value = .Range("J1").Value Then
                sahis = "Şahıs : " & .Cells(i, "A").Value & " "
                msg2 = msg2 & vbTab & .Cells(1, k).Value
                var = True
            End If
        Next k
        msg2 = sahis & " " & msg2
        If var = True Then msj = msj & vbLf & msg2
    Next i
End With
MsgBox msj
End Sub

 

[leumruk]

Selamlar,

Sub Auto_Open()
[j1] = Format(Now, "dd.mm.yyyy")
For Each x In Range("b2:f" & [a65536].End(3).Row)
If Format(Date, "dd.mm.yyyy") = Format(x, "dd.mm.yyyy") Then
a = a & vbLf & "Bugün " & x & " " & Cells(x.Row, "a") & " nolu şahıs için uyarı: " & Cells(1, x.Column)
End If
Next
MsgBox a
End Sub

 

[ismetali]

teşekkürler

arkadaşlar çok teşeşekkür ederim
sormak istesiğim bişey var sayın leumruk
For Each x In Range("b2:f" & [a65536].End(3).Row)
satırını açıklayabilirmisiniz bu işi öğrenmeye çalışıyorum da

 

[leumruk]

Range("b2:f" & [a65536].End(3).Row) bu satır b2 ile f aralığındaki verileri ifade ediyor. F'ye sayı vermedim, gereksiz döngü oluşturmaması için. Bunun yerine a sütunundaki son dolu satır numarasını f sütununa atadım. Sizin örneğinize göre a sütununun son dolu satırı 43. Böyle olunca b2:f43 arası döngüye alınmış oluyor.
For Each x In Range bu kısımdaki x hücre değişkenidir. Bu herhangi bir karakter ya da metin olabilir. Döngü başladığında b2:f43 aralığındaki tüm hücreler tek tek kontrol ediliyor. Eğer bugünün tarihine eşitse bunları mesaja ekliyor.