birleştir fonksiyonunda hücre biçimlerini almak

[birayfil]

ekte örneğini verdiğim birleştir fonksiyonunda hücre biçimlerini alabilirmiyiz, yada belirli hücrelere yazılan birleştir ama b1 deki f1 deki değerleri şöyle olsun diye,

şimdiden teşekkürler

 

[Korhan Ayhan]

Merhaba,

Bu işlemi fonksiyonlarla yapamazsınız. Ancak makro ile yapılabilir. Aşağıdaki kodu denermisiniz.

Option Explicit
 
Sub BİÇİMİYLE_BİRLEŞTİR()
    Dim Aralık As Range, Sonuç As Range, Hücre As Range
    Dim Veri As String, İlk As Integer, Son As Integer, Uzunluk As Integer
    
    On Error GoTo Hata
    Set Aralık = Application.InputBox("Lütfen birleştirmek istediğiniz hücreleri seçiniz.", Type:=8)
    If Aralık Is Nothing Then Exit Sub
    
    Set Sonuç = Application.InputBox("Lütfen sonucu görmek istediğiniz hücreyi seçiniz.", Type:=8)
    If Sonuç Is Nothing Then Exit Sub
    
    Application.ScreenUpdating = False
    
    For Each Hücre In Aralık
        If Veri = "" Then
            Veri = Hücre.Text
        Else
            Veri = Veri & " " & Hücre.Text
        End If
    Next
    
    Sonuç.Formula = Veri
 
    For Each Hücre In Aralık
        If İlk = Empty And Son = Empty Then
            İlk = 1
            Son = Len(Hücre.Text)
            Uzunluk = Len(Hücre.Text) + 1
        Else
            İlk = Uzunluk + 1
            Son = Len(Hücre.Text)
            Uzunluk = Uzunluk + Len(Hücre.Text) + 1
        End If
        
        With Sonuç.Characters(Start:=İlk, Length:=Son).Font
            .Bold = Hücre.Font.Bold
            .Name = Hücre.Font.Name
            .FontStyle = Hücre.Font.FontStyle
            .Size = Hücre.Font.Size
            .Strikethrough = Hücre.Font.Strikethrough
            .Superscript = Hücre.Font.Superscript
            .Subscript = Hücre.Font.Subscript
            .OutlineFont = Hücre.Font.OutlineFont
            .Shadow = Hücre.Font.Shadow
            .Underline = Hücre.Font.Underline
            .ColorIndex = Hücre.Font.ColorIndex
        End With
    Next
    
    Application.ScreenUpdating = True
    
    MsgBox "İşleminiz tamamlanmıştır.", vbInformation
    Exit Sub
    
Hata:
    MsgBox "Lütfen hücre seçimi yapınız !", vbCritical
    Exit Sub
End Sub

 

[birayfil]

sayın Korhan Ayhan
elinize sağlık çok güzel olmuş,

ama karışık bir işlemin bir özelliği olacağından kendisi otomatik alması lazım.
=BİÇİMİYLE_BİRLEŞTİR(b1;c1;d1;e1;f1) şeklinde olması gerek,

eğer olmuyorsa yapacak bir şey yok,
teşekkür ederim yardımlarınız için

 

[Korhan Ayhan]

Merhaba,

Biçimlendirme işlemini fonksiyonlarla dinamik olarak yapmanız mümkün değil. Ancak benim önerdiğim şekilde makro ile yapabilirsiniz.

 

[sertar]

Merhaba,

Biçimlendirme işlemini fonksiyonlarla dinamik olarak yapmanız mümkün değil. Ancak benim önerdiğim şekilde makro ile yapabilirsiniz.

Merhaba , yazdığınız macro benim işimi görüyor ama aynı dosya değilde , farklı bir excel dosyada hücreyi nasıl seçebiliriz?

Şimdiden teşekkürler