Bir hücreyi belli sayıda tekrarlatma

[burcin_end_muh]

Merhabalar,

A sütununda isimler var B sütununda ise bu isimlerin kaç kere tekrar etmesi gerektiği yazıyor.

adana 3
ankara 2
istanbul 4 gibi.

Formüller alt alta 3 tane adana 2 tane ankara 4 tane istanbul yazdırmak istiyorum

Değerli vaktiniz için şimdiden teşekkürler

 

[Ömer BARAN]

Merhaba.

Belgenizde 1'inci satırın başlık satırı olduğu ve verilerin 2'nci satırdan itibaren listelendiği varsayılmıştır.

-- C2 hücresine =A2 formülünü uygulayın,
-- C3 hücresine aşağıdaki formülü uygulayın ve dizi formülüne dönüştürün,
Formülü dizi formülüne dönüştürme:
formülü hücreye yapıştırın, F2 tuşu ile hücre içerisine girin, CTRL ve SHIFT tuşları basılı iken ENTER tuşuna basın,
işlemi doğru yapmışsanız formül kendiliğinden {....} gibi köşeli parantez içine alınır.

-- C3 hücresini aşağı doğru, boş sonuç elde edinceye kadar kopyalayın.
.

=[COLOR="red"]EĞER[/COLOR]([COLOR="red"]SATIR()[/COLOR]-1>[COLOR="red"]TOPLA[/COLOR]($B:$B);"";[COLOR="red"]EĞER[/COLOR]([COLOR="red"]EĞERSAY[/COLOR]($C$1:C2;C2)<[COLOR="red"]KAYDIR[/COLOR]($B$1;[COLOR="red"]KAÇINCI[/COLOR](C2;$A:$A;0)-1;0);C2;[COLOR="red"]KAYDIR[/COLOR]($A$1;[COLOR="Red"]KAÇINCI[/COLOR](C2;$A:$A;0);0)))

 

[burcin_end_muh]

çok teşekkür ederim Ömer bey. Kaydır yerine indis de kullanılabilirdi sanırım. ben formülü ilk satıra kurmaya çalıştığımdan ve formülü aşağıya çektikçe saydırmayı akıl edemediğimden kuramamıştım for döngüsünü çok çok teşekkür ederim tekrar.

 

[zulkarneyn37]

Merhabalar,

A sütununda isimler var B sütununda ise bu isimlerin kaç kere tekrar etmesi gerektiği yazıyor.

adana 3
ankara 2
istanbul 4 gibi.

Formüller alt alta 3 tane adana 2 tane ankara 4 tane istanbul yazdırmak istiyorum

Değerli vaktiniz için şimdiden teşekkürler

Evet konuyu hortlatıyorum. Tam aradığım soru. Var mı yeni önderi arkadaşlar.

 

[zulkarneyn37]

Yukarıdaki formülü denedim ama çalıştıramadım.

 

[52779]

@zulkarneyn37
İsimler ve Adetler : A1 : B10 aralığında
Aralarda BOŞ adetler mevcut. BOŞ adetlerin oldukları isimler listelenmez.

Adana	3		Adana		Adana	Adana
Mersin	2		Adana		Adana	Adana		D kolonu	Excel 2021
İstanbul	4		Adana		Adana	Adana			Tek hücreye
Ankara			Mersin		Mersin	Mersin			Formül
İzmir	3		Mersin		Mersin	Mersin			Sonuçlar
Antalya	2		İstanbul		İstanbul	İstanbul			Komple
Gaziantep			İstanbul		İstanbul	İstanbul			Dökülmeli
Muğla			İstanbul		İstanbul	İstanbul
Denizli	4		İstanbul		İstanbul	İstanbul		F Kolonu	> Excel2003
İstanbul	3		İzmir		İzmir	İzmir			Normal
			İzmir		İzmir	İzmir			Formül
			İzmir		İzmir	İzmir
			Antalya		Antalya	Antalya		G Kolonu	> Excel2003
			Antalya		Antalya	Antalya			DİZİ Formül
			Denizli		Denizli	Denizli
			Denizli		Denizli	Denizli
			Denizli		Denizli	Denizli		Adet Kolonu	Adet >0
			Denizli		Denizli	Denizli			BOŞ bırakılabilir
			İstanbul		İstanbul	İstanbul			BOŞ olanlar
			İstanbul		İstanbul	İstanbul			listelenmez
			İstanbul		İstanbul	İstanbul

3 adet formülle çözüm önerisi mevcut
1. çözüm (D1 hücresinde) : Profilinizde Excel2021 kullanıcısı olduğunuz yazmakta olduğundan, Excel 2021 ile Tek hücrede formül ile komple dökülmeli sonuçlar

=LET(z;A1:B10;a;İNDİS(z;;1);b;İNDİS(z;;2);c;DÇARP(--(SATIR(z)>DEVRİK_DÖNÜŞÜM(SATIR(z)));EĞER(ESAYIYSA(b);EĞER(b>0;b;0);0));s;SIRALI(TOPLA(b);;0);ARA(s;c;a))

2.Çözüm (F1 hücresinde) : Excel2027 ve sonrası için Klasik Normal Formül ile çözüm. F1 hücresine yazılır ve aşağıya doğru kopyalanır.

=EĞER(SATIRSAY(A$1:A1)<=TOPLA($B$1:$B$10);İNDİS($A$1:$A$10;EĞERHATA(1+KAÇINCI(SATIRSAY(A$1:A1)-1;ALTTOPLAM(9;KAYDIR($B$1:$B$10;;;SATIR($B$1:$B$10)-SATIR($B$1)+1;)));1));"")

3.Çözüm (G1 hücresinde) : Excel2027 ve sonrası için Klasik DİZİ Formül ile çözüm. G1 hücresine yazılır ve aşağıya doğru kopyalanır.

=EĞER(SATIRSAY(A$1:A1)<=TOPLA($B$1:$B$10);İNDİS($A$1:$A$10;KAÇINCI(SATIRSAY(A$1:A1)-1;DÇARP(--(SATIR($B$1:$B$10)>DEVRİK_DÖNÜŞÜM(SATIR($B$1:$B$10)));EĞER(ESAYIYSA($B$1:$B$10);EĞER($B$1:$B$10>0;$B$1:$B$10;0);0))));"")

Örnek dosya ektedir. İncelersiniz..

ANONYMOUS - Filemail

Click here to view and download these shared files from Filemail.com

www.filemail.com

 

[Korhan Ayhan]

Bende bir yardımcı sütun kullanarak alternatif bir çözüm önermek isterim.

C1 hücresine uygulayıp alta doğru sürükleyiniz...

=B1+EĞERHATA(DOLAYLI("C"&SATIR()-1);)

E1 hücresine uygulayıp alta doğru sürükleyiniz...

=EĞER(SATIR()>TOPLA($B:$B);"";İNDİS($A$1:$A$1000;TOPLAMA(15;6;SATIR($C$1:$C$1000)/($C$1:$C$1000>=SATIRSAY(C$1:C1));1)))