bir hücre içinde belli metin arama...

[keo84]

Sayın site üyeleri,
şimdiden yardımlarınız için teşekkür ederim sorum şu;
ekli dosyada 20 adet ürün var ben her bir ürünü sonuna "lüx ve eko" metinlerini ekleyip aşağıdaki şekilde çoklamak istiyorum.
X (esas ürün adı)
X LÜX
X EKO
örneğin:
DOMATES
DOMATES LÜX
DOMATES EKO
Listede bazı ürünler belirtilen şekilde çoklanmış ama bazıları çoklanmamış gözüküyor.
yapmak istediğim şu ; excel ilk satırdan itibaren hücreleri tarasın metin sonunda lüx veya eko ibarelerine rastlamadıklarını (yani X leri) bir alt satıra diğer sütun bilgileri ile birlikte sırayla sonuna LÜX ve EKO ekleyerek çoğaltsın.
(satır sayısı yaklaşık 1000 adet olduğundan bunu manuel yapmam bir hayli zamanımı alacaktır.)
saygılar..

 

[Korhan Ayhan]

Aşağıdaki kodu deneyiniz.

Sub VERILERI_DUZENLE()
    Dim X As Long
    
    For X = Cells(Rows.Count, 1).End(3).Row To 2 Step -1
        If InStr(1, Cells(X, 1), "LÜX", vbTextCompare) = 0 And InStr(1, Cells(X, 1), "EKO", vbTextCompare) = 0 Then
            If WorksheetFunction.CountIf(Range("A:A"), Cells(X, 1) & " LÜX") = 0 Then
                Rows(X + 1).Insert
                Range("A" & X & ":K" & X).Copy Range("A" & X + 1)
                Cells(X + 1, 1) = Cells(X + 1, 1) & " LÜX"
            End If
            If WorksheetFunction.CountIf(Range("A:A"), Cells(X, 1) & " EKO") = 0 Then
                Rows(X + 2).Insert
                Range("A" & X & ":K" & X).Copy Range("A" & X + 2)
                Cells(X + 2, 1) = Cells(X + 2, 1) & " EKO"
            End If
        End If
    Next

    MsgBox "İşleminiz tamamlanmıştır.", vbInformation
End Sub

 

[keo84]

Sayın Korhan Ayhan,
çok teşekkür ederim tam istediğim gibi.
iyi günler diliyorum.

 

[keo84]

Korhan bey,
bir sorum daha olacaktı bu listeyi oluşturduktan sonra içinde LÜX ve EKO geçmeyen satırları silmem gerekiyor. (yani normal olanları listeden çıkarmalıyım). Bunun için nasıl bir yol izlemeliyim?
teşekkür ederim.

 

[Korhan Ayhan]

Merhaba,

Filtre menüsünü kullanarak rahatlıkla yapabilirsiniz.

LÜX ve EKO içermeyen verileri süzerek kalan satırları silerek istemediğiniz satırlardan kurtulabilirsiniz.

 

[keo84]

filtrelemenin bu özelliğini hiç kullanmamıştım bunu da öğrenmiş oldum. Liste tam istediğim gibi şu an. Yardımlarınız için çok teşekkür ederim.
iyi günler.