Belli aralıklarla sıralama döngüsü

[buggsbunny]

resimde belli aralıklarla devam eden aynı satır sayısına sahip satırlarım var. Bunları kendi içinde büykten küçüğe sıralamak istiyorum. bunu makroda döngü kullanarak nasıl yaparım?

 

[Necdet]

ikinci grup ile birinci grup arasında 2 satır boşluk, son grupta ise 3 satır boşluk var.
Standart gitmiyor sanırım.

 

[Necdet]

Neyse ben yine değişken boşluk olduğunu varsayarak kodları yazayım.
A sütununun ilk hücresinde örnekte olduğu gibi başlığın olmadığı varsayılmıştır.

Sub Deneme()

Dim i As Long
Dim j As Long

j = Cells(Rows.Count, "A").End(3).Row
i = 1

Application.ScreenUpdating = False

Do Until Cells(i, "A") <> ""
    i = i + 1
Loop

Do
    Range("A" & i & ":B" & i + 3).Sort Key1:=[B1], order1:=2
    i = i + 4
    i = Range("A" & i).End(xlDown).Row
Loop While i < j

Application.ScreenUpdating = True

MsgBox "İşlem Bitmiştir ...."

End Sub

 

[Korhan Ayhan]

Alternatif..

Option Explicit

Sub Sort_Blocks_Z_A()
    Dim Rng As Range
    
    Application.ScreenUpdating = False
    
    For Each Rng In Range("A:B").SpecialCells(xlCellTypeConstants)
        If Rng.Column = 1 Then
            Rng.CurrentRegion.Sort Rng.Columns(2), xlDescending
        End If
    Next

    Application.ScreenUpdating = True

    MsgBox "İşleminiz tamamlanmıştır.", vbInformation
End Sub

 

[buggsbunny]

Teşekkürler işimi gördü