Aynı veri varsa uyarı verme mesajı göster..

[stirra_ej]

Arkadaşlar alttaki kodu alt alta veri kaydetmem için kullanıyorum, Kaydettiğim bir şeyin aynısı varsa, tekrar kaydetmeye çalışıyorsam bana uyarı mesajı versin ve kaydetmeden hata mesajından çıkayım.. yardımcı olabilirmisiniz lütfen..

Private Sub CommandButton2_Click()
If TextBox77.Text <> "" Then

Son_Dolu_Satir = Sheets("Firma").Range("b65536").End(xlUp).Row
Bos_Satir = Son_Dolu_Satir + 1
Sheets("Firma").Range("b" & Bos_Satir).Value = _
Application.WorksheetFunction.Max(Sheets("Firma").Range("A:A")) + 1
Sheets("Firma").Range("B" & Bos_Satir).Value = TextBox77.Text
TextBox77 = ""
MsgBox "Kayıt işlemi tamamlandı."

End If

Exit Sub

End Sub

Arkadaşlar alttaki kodu alt alta veri kaydetmem için kullanıyorum, Kaydettiğim bir şeyin aynısı varsa, tekrar kaydetmeye çalışıyorsam bana uyarı mesajı versin ve kaydetmeden hata mesajından çıkayım.. yardımcı olabilirmisiniz lütfen..

 

[mancubus]

sadece B sütununda (tek sütun) mükerrerlik kontrolü yapılıyor galiba.
A sütununa no, B sütununa veri
kodun tamamı buysa kullanılmayacak değişkenler tanımlamaya vs gerek yok

Private Sub CommandButton2_Click()

    Dim SonSat As Long

    If TextBox77.Text = "" Then Exit Sub
    
    With Sheets("Firma")
        If Application.CountIf(.Range("B:B"), TextBox77.Text) > 0 Then
            MsgBox "Bu veri daha önce girilmiş."
            TextBox77 = ""
            Exit Sub
        End If
        
        SonSat = .Range("B" & .Rows.Count).End(xlUp).Offset(1).Row
        .Range("A" & SonSat).Value = Application.Max(.Range("A:A")) + 1
        .Range("B" & SonSat).Value = TextBox77.Text
    End With
    
    TextBox77 = ""
    MsgBox "Kayıt işlemi tamamlandı."

End Sub