aynı sayfaya verileri toplatmak

[ezgi73]

Sayın üstadlarım ekte yer alan sadece iş bankasının verileri var ; yaklaşık 100 sayfa ve farklı isimlerde
isteğim şudur her sayfanın T ve AC aralığındaki dolu verileri burda alt alta sıralamak ve sayfa isimlerini satır başlarına yazdırmak teşekürlerimi sunarım saygılarımla

sayfa linki:https://dosya.co/3njh4sryg83m/Kopyası_İŞ_BANKASI_KREDİLER.xlsx.html

 

[Ziynettin]

Sub kod()
Dim a(), b()
satir = Rows.Count
ReDim b(1 To satir, 1 To 12)
    For j = 1 To Worksheets.Count
        Set s1 = Sheets(j)
        If s1.Name <> "GENEL TABLO" Then
            son = s1.Range("T" & Rows.Count).End(3).Row - 1
            If son > 6 Then
                a = s1.Range("T7:AC" & son).Value
                For i = 1 To UBound(a)
                    If a(i, 1) <> "" Then
                        If a(i, UBound(a, 2)) > 0 Then
                            say = say + 1
                            b(say, 1) = s1.Name
                            For y = 1 To UBound(a, 2)
                                b(say, y + 1) = a(i, y)
                            Next y
                        End If
                    End If
                Next i
            End If
        End If
    Next j
    With Sheets("GENEL TABLO")
        .Range("B4:L" & satir) = Empty
        If say > 0 Then
            .[B4].Resize(say, 12) = b
        End If
    End With
MsgBox "İşlem tamam.", vbInformation
End Sub

 

[ezgi73]

Çok teşekür ederim sayın @Ziynettin hocam muhteşemsiniz