• DİKKAT

    DOSYA İndirmek/Yüklemek için ÜCRETLİ ALTIN ÜYELİK Gereklidir!
    Altın Üyelik Hakkında Bilgi

Aynı Hücreye Girilen Adı Soyadı Bilgisini Başka Hücrelere Ayırma

K

KMLZDMR

Katılım
9 Nisan 2015
Mesajlar
494
Excel Vers. ve Dili
2003 TÜRKÇE EXCEL
Sayın arkadaşlar,

A2 Hücresinde bulunan Ayşe BALTAY (DURMAZ) ismi aşağıdaki formüller uygulandığında; B2 hücresine: Ayşe BALTAY gelmektedir.
C2 hücresinde: (DURMAZ) ismi gelmektedir.

B2 hücresine; =SOLDAN(A2;BUL("*";YERİNEKOY(A2;" ";"*";UZUNLUK(A2)-UZUNLUK(YERİNEKOY(A2;" ";"")))))

C2 hücresine; =SAĞDAN(A2;UZUNLUK(A2)-BUL("*";YERİNEKOY(A2;" ";"*";UZUNLUK(A2)-UZUNLUK(YERİNEKOY(A2;" ";"")))))


Bilgi:Bu isimdeki "BALTAY" bayanın babasından soyadıdır. Parantez içindeki ise "(DURMAZ)" evlilikten eşinin soy ismidir.

Şimdi,
Birinci talebimiz; parantez içinin solundaki kelimeyi de C2 formülünün içinde olmak yani C2 hücresinin yeni formülü sonucunda bize "BALTAY (DURMAZ)" şeklinde gelsin. Tabidirki B2 hücresinde de "Ayşe" gelmeli.

İkinci talebimiz; Ayşe'nin ismi de çift isim olursa Ayşe Banu BALTAY (DURMAZ) olursa diğer formül ise B2 hücresinde "Ayşe Banu" ; C2 hücresinde ise "BALTAY (DURMAZ)" gelmeli.

Lütfen, Birinci ve İkinci talebe ilişkin formülleri ayrı ayrı yazalım ki öğrenmemiz de kolay olsun.

Saygılarımla. İyi akşamlar.
 
Merhaba.

-- Adı için;
Kod: 
=EĞER(A2="";"";KIRP(SOLDAN(YERİNEKOY(A2;" ";"@";UZUNLUK(A2)-UZUNLUK(YERİNEKOY(A2;" ";""))-EĞER(YERİNEKOY(A2;"(";"")=A2;0;1));BUL("@";YERİNEKOY(A2;" ";"@";UZUNLUK(A2)-UZUNLUK(YERİNEKOY(A2;" ";""))-EĞER(YERİNEKOY(A2;"(";"")=A2;0;1));1)-1)))
-- Soyadı için;
Kod: 
=EĞER(A2="";"";KIRP(PARÇAAL(YERİNEKOY(A2;" ";"@";UZUNLUK(A2)-UZUNLUK(YERİNEKOY(A2;" ";""))-EĞER(YERİNEKOY(A2;"(";"")=A2;0;1));BUL("@";YERİNEKOY(A2;" ";"@";UZUNLUK(A2)-UZUNLUK(YERİNEKOY(A2;" ";""))-EĞER(YERİNEKOY(A2;"(";"")=A2;0;1));1)+1;255)))
 
Üsdat Aklınıza sağlık.
Formül her durumda da işlem görmektedir.
Teşekkür ederim.
İyiki varsınız.
 
Merhaba,

Alternatif olarak,

İsim için

Kod: 
=PARÇAAL(A1;1;EĞERHATA(BUL("#";YERİNEKOY(A1;" ";"#";TOPLA.ÇARPIM(--(PARÇAAL(A1;SATIR(DOLAYLI("1:"&UZUNLUK(A1)));1)=" "))-1))-1;BUL(" ";A1)-1))

Soyad'ı için

Kod: 
=PARÇAAL(A1;EĞERHATA(BUL("#";YERİNEKOY(A1;" ";"#";TOPLA.ÇARPIM(--(PARÇAAL(A1;SATIR(DOLAYLI("1:"&UZUNLUK(A1)));1)=" "))-1))+1;BUL(" ";A1)+1);99)
 
Ad Soyad bilgilerinin A sütununda olduğunu düşünürsek, alternatif..

Ad için;
Kod: 
[FONT="Trebuchet MS"][SIZE="2"]=EĞER(UZUNLUK(A1)-UZUNLUK(YERİNEKOY(A1;" ";""))=3;SOLDAN(A1;BUL("*";YERİNEKOY(A1;" ";"*";2)));SOLDAN(A1;BUL(" ";A1)-1))[/SIZE][/FONT]

Soyad için;
Kod: 
[FONT="Trebuchet MS"][SIZE="2"]=KIRP(YERİNEKOY(A1;B1;""))[/SIZE][/FONT]
 
Sayın KUVARİ, Sayın Murat Osma teşekkür ederim.
Sayın KUVARİ,; excel 2003 de sizin formülleri EĞER(EHATALIYSA(...
olarak nasıl yapabiliriz.
 
Merhaba Sayın ÖZDEMİR bence artık EĞERHATA işlevinin yapısını öğrenmelisiniz.

EĞERHATA ve EHATALIYSA işlevlerinin yapısı:
=EĞERHATA(...hata kontrolü yapılacacak formül...;....hata varsa yapılacak işlem....) -> burada ayrıca EĞER işlevi kullanılmıyor.
=EĞER(EHATALIYSA(...hata verebilecek işlem formülü...);...hata varsa yapılacak işlem...;...hata verebilecek işlem formülü....) ->(burada EĞER işlevi de var)

Sayın KUVARİ fark etmedi sanırım. Ben açıklamaya çalışayım.

İsim kısmını tespit eden ana formül olan =PARÇAAL(A2;1;…...) formülünde,
örnekteki "Ayşe Banu BALTAY (DURMAZ)" metni için alınacak karakter sayısı 9.

Bu sayıyı tespit eden formül parçası;
-- çift soyadı varsa
BUL("#";YERİNEKOY(A1;" ";"#";TOPLA.ÇARPIM(--(PARÇAAL(A1;SATIR(DOLAYLI("1:"&UZUNLUK(A1)));1)=" "))-1))-1
-- çift soyadı yoksa ykarıdaki BUL formül parçası #DEĞER hatası verecektir ve EĞERHATA işlevi kullanılarak yukarıdaki
formül parçası hatalıysa aşağıdaki bul formül parçası kullanılıyor
(hücredeki AD SOYADI örneğin Ayşe BANU BALTAY olarak değiştirirseniz bu hata durumu gerçekleşir)
BUL(" ";A1)-1
.
 
Sağolun sayın Ömer Baran üstadım. şimdi bu konuya çalışmaktayım.
 
Sayın Ömer Baran üstadım.
eğerhata ve eğer/ehatalıysa( formüller için çalışmaktayım. Yapamadım.

Benzer bir örnek olan formülde parçaları anlayabildim.
Kod: 
=EĞER(EHATALIYSA(DOLAYLI(ADRES(4;TOPLA.ÇARPIM((C4:G29=J5)*(SÜTUN(C4:G29)));4)));"Plaka Yok";(DOLAYLI(ADRES(4;TOPLA.ÇARPIM((C4:G29=J5)*(SÜTUN(C4:G29)));4))))

ANCAK:
1) Aşağıdaki eğerhata( fomül örneğindeki formülde; eğerhata(>>>hata kontrolü yapılacak formül (...;....hata varsa yapılacak işlem....") ayırımı tespit edemedim.

Kod: 
=PARÇAAL(A1;1;EĞERHATA(BUL("#";YERİNEKOY(A1;" ";"#";TOPLA.ÇARPIM(--(PARÇAAL(A1;SATIR(DOLAYLI("1:"&UZUNLUK(A1)));1)=" "))-1))-1;BUL(" ";A1)-1))


2) Aşağıdaki eğer(EHATALIYSA( uygulamasında sonuç alamadım. nerede hata yapmaktayım.?
ve bu formülü aşağıdaki alan ayırımları hangi formüllerdir.. (nerede başlayıp, nerede bitiyor anlamadım.)
=EĞER(EHATALIYSA(...hata verebilecek işlem formülü?...);...hata varsa yapılacak işlem?...;...hata verebilecek işlem formülü....)

=eğer(EHATALIYSA(BUL("#";YERİNEKOY(A1;" ";"#";TOPLA.ÇARPIM(--(PARÇAAL(A1;SATIR(DOLAYLI("1:"&UZUNLUK(A1)));1)=" "))-1))-1);BUL(" ";A1)-1)));"buraya ne yazmalıyım ki?";BUL("#";YERİNEKOY(A1;" ";"#";TOPLA.ÇARPIM(--(PARÇAAL(A1;SATIR(DOLAYLI("1:"&UZUNLUK(A1)));1)=" "))-1))-1);BUL(" ";A1)-1)))


TEŞEKKÜR EDERİM.
 
Tekrar merhaba.
-- Formülü hücreye uyguladığınızda formül çubuğunda, kullanılan İŞLEV ADIndan sonraki PARANTEZ işaretinin soluna fareyle sağ tıklayıp, OK tuşuyla bir sağa geçerseniz o işlevin nereye kadar devam ettiğini anlayabilirsiniz (kapanan parantez yanıp söner).
-- Formülü hücreye uyguladığınızda fromül çubuğunda EHATALIYSA kelimesine fareyle bir kez tıklayıp, formül çubuğunun solundaki fx simgesine fareyle tıkladığınızda excel formül yardımcısı ekrana gelir ve HATA KONTROLÜ YAPILAN FORMÜLÜ orada da görebilirsiniz.
Kod: 
[FONT="Arial Narrow"]=EĞER(EHATALIYSA(
BUL("#";YERİNEKOY(A1;" ";"#";TOPLA.ÇARPIM(--(PARÇAAL(A1;SATIR(DOLAYLI("1:"&UZUNLUK(A1)));1)=" "))-1))-1);[COLOR="blue"]bu formül parçası HATA sonucu mu veriyor?[/COLOR]
BUL(" ";A1)-1;[COLOR="blue"]cevap EVET ise yani yukarıdaki formül sonucu HATA ise buradaki hesaplama yapılacak.[/COLOR]
BUL("#";YERİNEKOY(A1;" ";"#";TOPLA.ÇARPIM(--(PARÇAAL(A1;SATIR(DOLAYLI("1:"&UZUNLUK(A1)));1)=" "))-1))-1[COLOR="Blue"]cevap HAYIR ise yani sonuç HATA DEĞİLSE buradaki hesaplama yapılacak[/FONT][/COLOR]
)

Tabi şunu unutmayın, HATA'dan kasıt formül hatası değil, formül sonucunun #DEĞER, #SAYI/0!, #YOK gibi hata sonuçlarından birini vermesidir.
 
b2 hücresinde isim ve soy isim yazıyorsa bunu c2 hücresine adı d2 hüsresine soyadını yazabilirmiyiz.bazıkişilerin isimleri 2 tanedir c2 hücresine gelmektedir.formül ingilizce olabilir mi
 
Cevap yazmak için giriş yap yada kayıt ol.
Geri
Üst