Açılışta uyarı mesajı

[shuriken7478]

Açılışta sayfaya gelindiğinde sayfadaki K sütunundaki araçların muayene durumuna bakıp muayenesinin bitimine 5 gün ve daha az gün kalan araçları mesaj halinde bildiren bir makro varmı?

 

[Korhan Ayhan]

Merhaba,

Linkteki konular faydalı olabilir...

Sorgu için arama sonuçları: Doğum günü

www.excel.web.tr

 

[muhasebeciyiz]

Private Sub Workbook_Open()
    Call MuayeneDurumuTamListe
End Sub

Sub MuayeneDurumuTamListe()
    Dim ws As Worksheet
    Dim i As Long
    Dim sonSatir As Long
    Dim muayeneTarihi As Date
    Dim farkGun As Long
    Dim mesaj As String
    Dim bugun As Date
    
    Set ws = ThisWorkbook.Sheets("Sayfa1")
    bugun = Date
    mesaj = ""
    
    sonSatir = ws.Cells(ws.Rows.Count, "K").End(xlUp).Row
    
    For i = 2 To sonSatir
        If IsDate(ws.Cells(i, "K").Value) Then
            muayeneTarihi = CDate(ws.Cells(i, "K").Value)
            farkGun = muayeneTarihi - bugun
            
            Select Case farkGun
                Case Is < 0
                    mesaj = mesaj & "Satır " & i & ": Muayene tarihi " & Abs(farkGun) & " gün önce geçmiş! (" & _
                        Format(muayeneTarihi, "dd.mm.yyyy") & ")" & vbCrLf
                Case 0
                    mesaj = mesaj & "Satır " & i & ": Muayene süresi bugün doluyor! (" & _
                        Format(muayeneTarihi, "dd.mm.yyyy") & ")" & vbCrLf
                Case Else
                    mesaj = mesaj & "Satır " & i & ": Muayeneye " & farkGun & " gün kaldı. (" & _
                        Format(muayeneTarihi, "dd.mm.yyyy") & ")" & vbCrLf
            End Select
        End If
    Next i

    If mesaj <> "" Then
        MsgBox "Araç Muayene Durumları:" & vbCrLf & vbCrLf & mesaj, vbInformation, "Durum Raporu"
        End If
End Sub

Tarihler K sutununda olacak
Sayfa1 olarak geçen sayfa adı farklı ise değiştirin

Deneyiniz ve geri dönüş yapınız