Açılış sayfası ile boş satırları gizlenmesi

[teyadih]

Merhaba arkadaşlar. Ekli dosya için açılış sayfası yapıp, boş satırları gizleyecek ve işi biten bilgileri temizleyecek makroya ihtiyacım var. Makro tecrübem sıfır derecesinde olduğundan rica etsem makroyu örnek dosyaya uygulayabilir misiniz? Teşekkür ederim.

 

[Korhan Ayhan]

Merhaba,

Önereceğim kendiniz uygulayın. Böylece makro terimlerine adım atmış olursunuz.

Dosyanızı açın ve ALT+F11 tuşlarına basarak kod editörünü (VBA) açın.

Aşağıdaki kodu açılan pencerenin sol tarafında bulunan resimdeki bölüme uygulayın.

Option Explicit

Private Sub Workbook_Open()
    Sheets("Giriş").Select
End Sub

Aşağıdaki kodu ise resimdeki sayfanızın kod bölümüne uygulayınız.

Option Explicit

Private Sub Worksheet_Activate()
    Dim Veri As Range, Alan As Range
    
    Application.ScreenUpdating = False
    
    Cells.EntireRow.Hidden = False
    
    For Each Veri In Range("A12:A" & Cells(Rows.Count, 1).End(3).Row)
        If Veri.Value = "" Then
            If Alan Is Nothing Then
                Set Alan = Veri
            Else
                Set Alan = Union(Alan, Veri)
            End If
        End If
    Next

    If Not Alan Is Nothing Then Alan.Rows.Hidden = True

    Application.ScreenUpdating = True
End Sub

Aşağıdaki kodu içe boş bir modül ekleyip uygulayınız. (Görselde ki gibi)
Sonra bahsettiğiniz sarı renkli alana EKLE menüsünden bir şekil ekleyin ve şekil üzerinde sağ tıklayıp makro ata diyerek modüldeki kodu seçerek işlemi tamamlayın. Zor değil biraz dikkatli yaparsanız gayet kolay olduğunu görebilirsiniz.

Option Explicit

Sub Hucreleri_Temizle()
    Dim Onay As Byte
    
    Onay = MsgBox("J-K-L sütunlarında ki bilgiler silinsin mi?", vbCritical + vbYesNo + vbDefaultButton2)
    
    If Onay = vbNo Then Exit Sub
    
    Range("J12:L" & Rows.Count).ClearContents

    MsgBox "Hücre içerikleri temizlenmiştir.", vbInformation
End Sub

 

[teyadih]

Teşekkür ederim korhan bey uygulayıp dönüş yapacağım

 

[teyadih]

Makro tamam Korhan Bey teşekkür ederim. Elinize sağlık.

 

[Korhan Ayhan]

Ben sadece kapıyı açtım. Gerisini siz hallettiniz.

 

[teyadih]

Teşekkür ederim