2 Eğer Fomülünü Birleştirme

[schlecht]

İyi akşamlar,

=EĞER(N2="Seçim ";((B2=L2)+(L2=" veri yok"))=1;"Seçim yok")

=EĞER(B2=L2;"EŞİT";EĞER(VE(B2>=L2);"FAZLA";EĞER(VE(B2<=L2);"EKSİK")))

1. formüle 2. formülü eklemem konusunda yardımlarınız rica ediyorum.

 

[Haluk]

Örnek dosya eklerseniz, olayın ne olduğunu anlayabiliriz belki ....

.

 

[schlecht]

Örnek dosya ekte, teşşekürler.

 

[Haluk]

Dosyanızdaki 1. grup olasılıklar için aşağıdaki formül, size istediğiniz sonucu verecektir.

Türkçe Excel versiyonu için, CHOOSE yerine ELEMAN kullanacaksınız.

=CHOOSE((N2="Seçim")*(B2=20)*((L2="veri yok")+(L2=20))*1 + (N2="Seçim")*(B2=15)*((L2=20))*2 + (N2="Seçim")*(B2=30)*((L2=20))*3 + (N2="Seçim yok")*(B2=20)*((L2=20))*4;"Eşit";"Eksik";"Fazla";"Seçim yok")

İkinci grupta istediğinizi tam anlamadım. O grup için de ayrı bir formül mü istiyorsunuz?

.

 

[schlecht]

Haluk Hocam değerler sabit değil, =20, =25, =30 değerlerini silsem çalışır mı?

N2 değeri "seçim" ise b2 değeri "herhangi bir sayı", L2 değeri "veri yok" sonuç "Eşit"
N2 değeri "seçim" ise b2 değeri L2 değeri eşit ise sonuç; "Eşit"
N2 değeri "seçim" ise b2 değeri L2 değerinden küçük ise sonuç; "eksik"
N2 değeri "seçim" ise b2 değeri L2 değerinden büyük ise sonuç "fazla"
N2 değeri "seçim yok" ise b2 değeri ve L2 değerine bakılmaksızın sonuç; "seçim yok"

 

[Haluk]

Bahsettiğiniz değerleri bir hücreye yazın, formülde de hücre adresini belirtin.

Yani; =20 yerine =D2 gibi ....

.

 

[schlecht]

Hocam denedim fakat 1. koşulu sağlayamadım.

1. Koşul: N2 değeri "seçim" ise b2 değeri "herhangi bir sayı", L2 değeri "veri yok" sonuç "Eşit"

=ELEMAN((N2="Seçim")*(B2=B2)*((L2="veri yok")+(L2=L2))*1 + (N2="Seçim")*(B2<L2)*2 + (N2="Seçim")*(B2>L2)*3 + (N2="Seçim yok")*(B2=B2)*((L2=L2))*4;"Eşit";"Eksik";"Fazla";"Seçim yok")

Sonuç "Seçim yok " çıkıyor.

 

[Ömer BARAN]

Merhaba.

Bu tür sorularda, kuralları EN GENEL olandan EN ÖZEL olana doğru sıralamalısınız.
Yanlış anlamadıysam aşağıdaki formül istenilen sonucu verir.

=EĞER(N2="SEÇİM YOK";"SEÇİM YOK";EĞER(VE(N2="SEÇİM";YADA(VE(ESAYIYSA(B2);L2="VERİ YOK");B2=L2));"EŞİT";EĞER(VE(N2="SEÇİM";YADA(VE(ESAYIYSA(B2);L2="VERİ YOK");B2>L2));"FAZLA";EĞER(VE(N2="SEÇİM";YADA(VE(ESAYIYSA(B2);L2="VERİ YOK");B2<L2));"EKSİK";""))))

 

[Haluk]

Örnek dosyanızdaki 1. grup sayısal örnek, 2. grup ise sizin ilave olarak genel açıklamanızmış. Dün gece anlayamamışım.....

Bu durumda, aşağıdaki formülü kullanabilirsiniz .....

İngilizce Excel için:

=CHOOSE((N2="Seçim")*ISNUMBER(B2)*((L2="veri yok")+ISNUMBER(L2)*(L2=B2))*1+(N2="Seçim")*ISNUMBER(L2)*(B2<L2)*2+(N2="Seçim")*ISNUMBER(L2)*(B2>L2)*3+(N2="Seçim yok")*4;"Eşit";"Eksik";"Fazla";"Seçim yok")

Türkçe Excel için:

=ELEMAN((N2="Seçim")*ESAYIYSA(B2)*((L2="veri yok")+ESAYIYSA(L2)*(L2=B2))*1+(N2="Seçim")*ESAYIYSA(L2)*(B2<L2)*2+(N2="Seçim")*ESAYIYSA(L2)*(B2>L2)*3+(N2="Seçim yok")*4;"Eşit";"Eksik";"Fazla";"Seçim yok")

.

 

[schlecht]

Ömer Bey teşekkür ederim cevabınız için. Haluk Bey ilginiz için teşekkürler evet 2. grupta örnek olarak gözüken açıklama kısmıyıdı. En son yazdığınız formülüde biraz değiştirip başka bir alanda kullandım.