Benzersiz kayıt ve sayfalardan toplam almak

[unur]

Arkadaşlar,Bu konuda yardımcı olursanız çok büyük bir yükten kurtarmış olacaksınız.

1-Sayfalardan (ocak,şubat,mart....) kişilerin tc kimlik numaralarına göre benzersiz kayıtları almak istiyorum
2- Bu sayfalardaki personelin keseneklerini (özet sayfasında) ilgili hücrelere toplamak istiyorum.

Dosyayı ektedir.

 

[Ömer]

Merhaba,

Bu şekilde deneyin.

Sub Ozet()
 
    Dim s(), a1, deg, k As Integer
    Dim i As Long, d As Object, j As Byte, sat As Long
 
    Application.ScreenUpdating = False
    Sheets("özet").Select
 
    Rows("2:" & Rows.Count).ClearContents
 
    Set d = CreateObject("Scripting.Dictionary")
 
    For k = 1 To Worksheets.Count
        With Sheets(k)
            If .Name <> "özet" Then
                For i = 2 To .Cells(Rows.Count, "A").End(xlUp).Row
                    deg = .Cells(i, "A")
                    If Not d.exists(deg) Then
                        ReDim s(1 To 21)
                        For j = 1 To 21
                            s(j) = .Cells(i, j)
                        Next j
                        d.Add deg, s
                    Else
                        s = d.Item(deg)
                        For j = 15 To 21
                            s(j) = s(j) + .Cells(i, j)
                        Next j
                        d.Item(deg) = s
                    End If
                Next i
            End If
        End With
    Next k
 
    a1 = d.items: sat = 2
 
    For i = 0 To d.Count - 1
        s = a1(i)
        For j = 1 To 21
            Cells(i + sat, j) = s(j)
        Next j
    Next i
 
    Cells.EntireColumn.AutoFit
    Set d = Nothing
 
End Sub

Not: Detaylı deneme yapmadım.

 

[unur]

Ömer Bey çok teşekkürler emeklerinize sağlık.
Zamanınız olursa kodların hangilerinin mükerrer kayıtlar için hangilerinin toplam almaya yaradığını yazma şansınız olursa sevinirim.Çünkü aynı kodları buna benzer başka belgerede uygulamam gerekiyor onun için bu konuda bilgim olursa kolay uygulama yapabilirim.

 

[unur]

Hangilerinin mükerrer kayıtlar için hangilerinin toplam almaya yaradığını yazma şansınız olursa sevinirim.Çünkü aynı kodları buna benzer başka belgerede uygulamam gerekiyor onun için bu konuda bilgim olursa kolay uygulama yapabilirim.

Kodların açıklamasını yapacak arkadaşlara şimdiden Teşekkürler.