Düşeyara-Topla.Çarpım-Eğer?? Hangisi ve nasıl olacak bulamadım :s

[faksu]

Konuyu doğru yere mi açtım bilmiyorum ama "arama" bölümünden forumda benzer birşey bulamadım malesef:s
Açıklamayı ekteki dosyada yapmaya çalıştım. Yardımcı olursanız sevinirim

 

[promega109]

Kardeş soruna cavap olur heralde

 

[faksu]

Malesef düşeyara formülü tek koşul için geçerli oluyor. Benm istedigim ise hem a hem de b sütunundakiler eşit oldugunda karşısındaki değeri versin. bu şekilde oldugunda şöyle bir sorun çıkıyor ortaya; diyelimki ahmet'ten birden fazla var ama a sütunundaki karşılıklaır farklı. işte o zaman yanlış sonuçlar veriyor :s

 

[Ali]

TOPLA.ÇARPIM ilede yapılır ama İNDİS daha sağlıklıdır.



Alternatif1

Sayfa1'deki C7 hücresine

=İNDİS(Sayfa2!$C$1:$C$20;KAÇINCI(1;EĞER(Sayfa2!$A$1:$A$20=A7;EĞER(Sayfa2!$B$1:$B$20=B7;1));0))

yazıp direk ENTER tuşuna basmadan CTRL+SHIFT+ENTER tuşlarına birlikte basınız.Sonra aşağı doğru çekiniz.

Alternatif2

Sayfa1'deki C7 hücresine

 =TOPLA.ÇARPIM((Sayfa2!$A$1:$A$20=A7)*(Sayfa2!$B$1:$B$20=B7);Sayfa2!$C$1:$C$20)

yazıp aşağı doğru çekiniz.

 

[faksu]

Hızlı cevap için teşekkür ederim ama hazırlamıs oldugum taslakta calısıyor formul fakat asıl dosyada calıstıramadım sanırım biraz calısmam gerek. bir şeyi de anlamadım. kaçıncı formülünde neden 1 yazdık?
-Asıl dosyada da çalıştırabildm sonunda teşekkür ederim tekrar

 

[unur]

Arkadaşlar;
Arkadaşımızın dosyasında Ali beyin indis dizi formülünü kullanarak işlem yaptım ancak eklediğim dosyadan da anlaşılacağı üzere bazı bilgileri olmayan personelin karşılığında yok hatası çıkıyor.

Bu dizi formülde hataları gözardı etme imkanı varmıdır.
Teşekkürler.

 

[YUSUF44]

C14'teki formül:

{=EĞER(EHATALIYSA(İNDİS(Sayfa2!$C$1:$C$19;KAÇINCI(1;EĞER(Sayfa2!$A$1:$A$19=A14;EĞER(Sayfa2!$B$1:$B$19=B14;1));0)));"";İNDİS(Sayfa2!$C$1:$C$19;KAÇINCI(1;EĞER(Sayfa2!$A$1:$A$19=A14;EĞER(Sayfa2!$B$1:$B$19=B14;1));0)))}

 

[unur]

Yusuf bey;
Verdiğiniz formülü dizi formül olarak yapamadım, normal formül olarak yazdığım zaman yok hatasını gözardı ediyor ancak diğer hücrelerede uyguladığımız zaman sonuç vermek yerine boş bırakıyor sonucu veya ben yapamadım.
Yardımcı olacak arkadaşlara teşekkürler.

 

[YUSUF44]

Gönderdiğiniz dosyada bende problem olmadı:

Şöyle deneyin bakalım:

=EĞER(EHATALIYSA(İNDİS(Sayfa2!$C$1:$C$19;KAÇINCI(1;EĞER(Sayfa2!$A$1:$A$19=A14;EĞER(Sayfa2!$B$1:$B$19=B14;1));0)));"";İNDİS(Sayfa2!$C$1:$C$19;KAÇINCI(1;EĞER(Sayfa2!$A$1:$A$19=A14;EĞER(Sayfa2!$B$1:$B$19=B14;1));0)))

CTRL+SHIFT+ENTER tabi.

 

[unur]

Çok Teşekkürler şimdi bir proplem olmadı sağolun.

 

[Mahir64]

Merhaba,

Hacimli dosyalarda bu formül hesaplama süresi uzun olabilir.
İki koşullu indis formülü de düşünülebilir.
DİZİ formülüne çevirmeden deneyiniz. Eğer(ehatalıysa eklenebilir.

=İNDİS(Sayfa2!$C$1:$C$10;TOPLA.ÇARPIM((KAÇINCI(A7&"@"&B7;Sayfa2!$A$1:$A$10&"@"&Sayfa2!$B$1:$B$10;0))))

 

[unur]

Merhaba,

Hacimli dosyalarda bu formül hesaplama süresi uzun olabilir.

=İNDİS(Sayfa2!$C$1:$C$10;TOPLA.ÇARPIM((KAÇINCI(A7&"@"&B7;Sayfa2!$A$1:$A$10&"@"&Sayfa2!$B$1:$B$10;0))))

Çok Teşekkürler Mahir hocam;
1-Hacimli dosyalarda hesaplama süresi uzun olabilir dediğiniz formül yusuf beyin önerdiği dizi formül mü yoksa sizin önerdiğiniz normal formül mü? kullanım açısından dizi formüllle normal formül arasındaki fark nedir?
2- Mahir hocam formülde kullandığınız kuyruklu a "@" neyi ifade ediyor, hatta formülün mantığını açıklama şansınız olursa bilgi haznemize bir bilgi daha atmış oluruz.
Çok Teşekkürler.