Sayfa 1'deki verileri belirli kritere gore Sayfa2'ye aktarma

[weirdom]

Arkadaslar Merhaba,
Ekte verdigim ornek tabloya, Sayfa 1 de herbir satira 1 isleme ait verileri giriyorum.
bu girmis oldugum verileri belirli bir kritere gore sayfa 2 ye aktarmak istiyorum.
ornegin sayfa 1 de c sutununda "ky" olan satirlari sayfa 2 ye ayni tabloya sirali bir bicimde atsin istiyorum.

Yardimlarinizi bekliyorum...
Simdiden tesekkurler.
Not: Makro giremiyorum, eger li formuller vb. kabulumdur=))

 

[İhsan Tank]

Arkadaslar Merhaba,
Ekte verdigim ornek tabloya, Sayfa 1 de herbir satira 1 isleme ait verileri giriyorum.
bu girmis oldugum verileri belirli bir kritere gore sayfa 2 ye aktarmak istiyorum.
ornegin sayfa 1 de c sutununda "ky" olan satirlari sayfa 2 ye ayni tabloya sirali bir bicimde atsin istiyorum.

Yardimlarinizi bekliyorum...
Simdiden tesekkurler.
Not: Makro giremiyorum, eger li formuller vb. kabulumdur=))

Merhaba
Sheet2 sayfasının H1 hücresine hangi kriter ise onu girin.
A2 hücresine

Türkçe
=EĞER(SATIRSAY(A$2:A2)>EĞERSAY(Sheet1!$C$2:$C$1000;$H$1);"";İNDİS(
Sheet1!A$2:A$1000;KÜÇÜK(EĞER(Sheet1!$C$2:$C$1000=$H$1;SATIR(Sheet1!$C$2:$C$1000)
-SATIR(Sheet1!$C$2)+1);SATIRSAY(A$2:A2))))
İngilizce
=IF(ROWS(A$2:A2)>COUNTIF(Sheet1!$C$2:$C$1000;$H$1);"";INDEX(
Sheet1!A$2:A$1000;SMALL(IF(Sheet1!$C$2:$C$1000=$H$1;ROW(Sheet1!$C$2:$C$1000)
-ROW(Sheet1!$C$2)+1);ROWS(A$2:A2))))

BU formülü yazın ve dizi ~ array'a çevirin.

Dizi Formülü Formül Hücreye Girildikten Sonra Enter Tuşuna Basmadan Ctrl+Shift+Enter Tuş Kombinasyonu İle Aktif Olmaktadır. Formülün Başında Ve Sonunda { } Bu İşaretler Çıkar Elle Eklediğiniz Takdirde Formül Hata Verir.

Formülde 1000 satır baz alınmıştır.

1000 satır'ı değiştirmek için ctrl+h yapın aranan değere $1000 yeni değere $10000 yazın ve tümünü değiştir deyin.
$10000 olan yeri kendinize göre ayarlayınız.

 

[weirdom]

cok tesekkurler.... calisti

 

[İhsan Tank]

cok tesekkurler.... calisti

Rica ederim
:keyif:

 

[weirdom]

Hocam tekrar teşekkürler,

Formül süper yalnız tek birşey sorucam=) mantığını açıklaman mümkün mü=) ben olabildiğince anlamaya çalıştım ama bir de sen anlatırsan süper olur=)
Allah razı olsun...

 

[İhsan Tank]

Hocam tekrar teşekkürler,

Formül süper yalnız tek birşey sorucam=) mantığını açıklaman mümkün mü=) ben olabildiğince anlamaya çalıştım ama bir de sen anlatırsan süper olur=)
Allah razı olsun...

Merhaba

=EĞER(SATIRSAY(A$2:A2)>EĞERSAY(Sheet1!$C$2:$C$1000;$H$1);"";

Bu formül satırsay ~ Rows ise satır sayısını buluyoruz eğersay ~ countif ile bulduğumuz sayıdan satır fazla ise boş bırakmasını istiyoruz.

İNDİS(Sheet1!A$2:A$1000;

İndis ~ Index ile hangi sütunu yazdırmak istiyorsak onu yazıyoruz

KÜÇÜK(EĞER(Sheet1!$C$2:$C$1000=$H$1;SATIR(Sheet1!$C$2:$C$1000)
-SATIR(Sheet1!$C$2)+1);SATIRSAY(A$2:A2))))

Eğer ~ If Burada ise önce hangi sütunda karşılaştırma hangi karaktere göre arama yapacağını belirliyoruz sonra satır kontrolünü yaptırıyoruz bulduğu satıra numara vermesini sağlıyoruz. Küçük ~Small formülü ile Satırsay ~ Rows ile küçükten büyüğe doğru sonuç çıkarmasını sağlıyoruz.