[ÇÖZÜLDÜ] Eğer boşsa

[mami68]

Sayın hocalarım ve site arkadaşlarım merhaba!
Dosya ekte içinde açıklama yapılmış nasıl bir formül uygulaması yapabiliriz.


İyi çalışmalar.

 

[Ömer]

Merhaba,

C2 hücresine,

=EĞER(VE(A2="";B2="");"";C1+A2-B2)

Yazarak alt hücrelere kopyalayınız..

 

[mami68]

Ellerine sağlık,Allah beyninize unutkanlık vermesin.Teşekkürler.

 

[Ömer]

Ellerine sağlık,Allah beyninize unutkanlık vermesin.Teşekkürler.

Rica ederim..

Eğer arada boş hücreler olacaksa C1 değeri toplamada hatalı sonuç verecektir, hata vermemesi için formülü aşağıdaki gibi kullanmanız daha sağlıklı olacaktır..

=E&#286;ER(VE(A2="";B2="");"";ARA(2;1/($C$1:C1<>"");$C$1:C1)+A2-B2)

 

[mami68]

Hocam, marifetleriniz hiçbir zaman bitmesin.Buda başka bir güzel oldu.Teşekkürler
Bo&#351; zaman&#305;n&#305;zda bu b&#246;l&#252;me bir a&#231;&#305;klama yaparsan&#305;z sevinirim "ARA(2;1/($C$1:C1<>"")" &#231;&#252;nk&#252; 2-yi bir yapt&#305;m, toplamda 1-ri 100 g&#246;rd&#252; merak ettim.

 

[Ömer]

Hocam, marifetleriniz hiçbir zaman bitmesin.Buda başka bir güzel oldu.Teşekkürler
Boş zamanınızda bu bölüme bir açıklama yaparsanız sevinirim "ARA(2;1/($C$1:C1<>"")" çünkü 2-yi bir yaptım, toplamda 1-ri 100 gördü merak ettim.

Daha önce Sayın yurttas' ın forumda bu konuyla ilgili yaptığı açıklamadan alıntıdır..

=LOOKUP(2,1/(1-ISBLANK(A1:A65535)),A1:A65535)

Veya

=LOOKUP(2;1/(A1:A65529<>"");A1:A65529)

Formülünün açıklanması:

1. Bu formüllerde LOOKUP fonksiyonunun vektör olarak söz dizimi formatı kullanılmaktadır.

Vektör biçiminin sözdizimi:

=LOOKUP(lookup_value;lookup_vector;result_vector)
=ARA(aranan_değer;aranan_vektör;sonuç_vektör)

Aranan_değer ARA fonksiyonunun ilk vektörde aradığı değerdir. Aranan_değer bir sayı, metin, mantıksal bir değer ya da bir değere başvuruda bulunan bir ad ya da başvuru olabilir.

Aranan_vektör yalnızca bir satır ya da bir sütun içeren aralıktır. Aranan_vektördeki değerler metin, sayı ya da mantıksal değer olabilir.

Sonuç_vektör yalnızca bir satır ya da sütun içeren bir aralıktır. Aranan_vektörle aynı büyüklükte olması gerekir.

2. Burada 2 (1’den farklı herhangi bir değer girilebilir.) aranan_değer olarak formülün birinci parametresini oluşturur.

3. Formülde ilginç olan ise ikinci parametrede yer alan
1/(1-ISBLANK(A1:A65535)) aranan_vektördür.

bu dizi değerlenirken;
{1;1;1;1;1;1;1;#DIV/0!;1;1;#DIV/0!;#DIV/0!;…;#DIV/0!} şeklinde olur. Burada ISBLANK fonksiyonu boş hücre için True- Doğru -1, dolu hücre için False-Yanlış – 0’a dönüşür. Bunları 1’den çıkardığımızda dizi 0 (boş) or 1 (dolu) değerlerini alır. Bu diziyi de 1’e bödüğümüzde dizi #DIV/0 (boş) veya 1 (dolu) değerlerini alır.

1/(A1:A65529<>"") aranan_vektöründe ise; bu dizi değerlenirken;
{1;1;1;1;1;1;1;#DIV/0!;1;1;#DIV/0!;#DIV/0!;…;#DIV/0!} şeklinde olur.

4. LOOKUP aranan_değer 2’yi dizide ararken bulamayacak ve buna yakın en son değer olan 1’i alacaktır. Bu da son dolu hücrenini değeri olacaktır.


.

 

[mami68]

Sayın espiyonajl



Teşekkürler.İyi çalışmalar.

 

[Ömer]

Rica ederim.

&#304;yi &#231;al&#305;&#351;malar..