Kısaltmalar

S

Selcuk1903

Katılım
7 Ekim 2019
Mesajlar
135
Excel Vers. ve Dili
Tr 2019
Selâmün aleyküm arkadaşlar benim sorum şu ünvan kısaltmalarını tam şekli ile yazdırmak istiyorum örneğin a hücresinde dr. Av. Gibi kısaltmalar yazıyor ise b hücresine doktor avukat yazdırmak istiyorum otomatik olarak nasıl yapabilirim
 
Kısaltmlarınızın yer aldığı bir listeniz varsa olacaktır.
İçinde kısaltmalarınız olduğu listenin düzeni de önemli.
Hep kısaltmalar hücrenin başında mı bulunuyor, ortasında da olabilir mi?
Verilerinizi (gerçek kişiler olmayan) ve kısaltmalarınızı içeren örnek bir dosya hazırlayıp foruma eklerseniz çabucak yardım gelecektir.
 
Merhaba,
Kaç farklı unvan var?
Sayı fazla ise veri tabanı oluşturun ve düşeyara, indis gibi araba başvuru formüllerini kullanın. 2-3 ise eğer formülünü kullanın.
 
Ömer beyin mesajını atlamayın ona göre örnek verininiz.
 
Selcuk1903' Alıntı:
5 tane kısaltma var mesela dr. Av. Gibi
Genişletmek için tıkla ...
Kısaltmalar hep nokta ile bitiyor ve kısaltmalar cümle başında varsaydım
Dr.=Doktor
Av.=Avukat
K3.=Kısaltma3 (Siz kendinize göre K3 K4 k5 kısaltmalarının kısa ve uzun hallerini formüle işleyebilirsiniz

A2 de kısaltma kullanılmış veri var.
=ELEMAN(KAÇINCI(SOLDAN(A2;3);{"Av.";"Dr.";"K3.";"K4.";"K5."};0);"Avukat";"Doktor";"Kısaltma3";"Kısaltma4";"Kısaltma5")

Kısaltma olmayan ya da hatalı kısaltmalar varsa formülü aşağıdaki gibi kullanabilirsin
=EĞERHATA(ELEMAN(KAÇINCI(SOLDAN(A5;3);{"Av.";"Dr.";"K3.";"K4.";"K5."};0);"Avukat";"Doktor";"Kısaltma3";"Kısaltma4";"Kısaltma5");"")
 
ÖmerFaruk' Alıntı:
Kısaltmalar hep nokta ile bitiyor ve kısaltmalar cümle başında varsaydım
Dr.=Doktor
Av.=Avukat
K3.=Kısaltma3 (Siz kendinize göre K3 K4 k5 kısaltmalarının kısa ve uzun hallerini formüle işleyebilirsiniz

A2 de kısaltma kullanılmış veri var.
=ELEMAN(KAÇINCI(SOLDAN(A2;3);{"Av.";"Dr.";"K3.";"K4.";"K5."};0);"Avukat";"Doktor";"Kısaltma3";"Kısaltma4";"Kısaltma5")

Kısaltma olmayan ya da hatalı kısaltmalar varsa formülü aşağıdaki gibi kullanabilirsin
=EĞERHATA(ELEMAN(KAÇINCI(SOLDAN(A5;3);{"Av.";"Dr.";"K3.";"K4.";"K5."};0);"Avukat";"Doktor";"Kısaltma3";"Kısaltma4";"Kısaltma5");"")
Genişletmek için tıkla ...
Çok teşekkür ederim
 
METNİ SÜTUNLARA DÖNÜŞTÜR DIŞINDA SELÇUK SAĞUN
İSMİNİ FORMÜL İLE NASIL AYIRABİLİRİM
VE 4 İSİMLİ
İSA TARIK CAN YILDIZ
İSMİNİ NASIL AYIRABİLİRİM FORMÜL İLE
YARDIM EDEBİLİR MİSİNİZ
 
A15 de uzun isimler.

B15 ilk parça
=EĞER(UZUNLUK(KIRP($A15))-UZUNLUK(YERİNEKOY(KIRP($A15);" ";""))>=1;PARÇAAL(KIRP($A15);1;MBUL(" ";KIRP($A15))-1);"")

C15
=EĞER(UZUNLUK(KIRP($A15))-UZUNLUK(YERİNEKOY(KIRP($A15);" ";""))>=1;PARÇAAL(KIRP(YERİNEKOY($A15;$B15;""));1;EĞERHATA(MBUL(" ";KIRP(YERİNEKOY($A15;$B15;"")))-1;UZUNLUK(KIRP(YERİNEKOY($A15;$B15;"")))));"")

D15
=EĞER(UZUNLUK(KIRP($A15))-UZUNLUK(YERİNEKOY(KIRP($A15);" ";""))>=2;PARÇAAL(KIRP(YERİNEKOY(YERİNEKOY($A15;$B15;"");$C15;""));1;EĞERHATA(MBUL(" ";KIRP(YERİNEKOY(YERİNEKOY($A15;$B15;"");$C15;"")))-1;UZUNLUK(KIRP(YERİNEKOY(YERİNEKOY($A15;$B15;"");$C15;"")))));"")

E15
=EĞER(UZUNLUK(KIRP($A15))-UZUNLUK(YERİNEKOY(KIRP($A15);" ";""))>=3;PARÇAAL(KIRP(YERİNEKOY(YERİNEKOY(YERİNEKOY($A15;$B15;"");$C15;"");$D$15;""));1;EĞERHATA(MBUL(" ";KIRP(YERİNEKOY(YERİNEKOY(YERİNEKOY($A15;$B15;"");$C15;"");$D$15;"")))-1;UZUNLUK(KIRP(YERİNEKOY(YERİNEKOY(YERİNEKOY($A15;$B15;"");$C15;"");$D$15;"")))));"")
 
Alternatif;

Kısaltmalar için;

Verinizin A1 hücresinde olduğunu varsaydım...

C++: 
=EĞERHATA(DÜŞEYARA(A1;{"av."\"Avukat";"dr."\"Doktor";"öğr."\"Öğretmen";"müh."\"Mühendis";"inş."\"İnşaatçı"};2;0);"Kısaltma bulunamadı.")


Birden fazla kelime içeren metni sütunlara ayırmak için;

A1 hücresindeki metin için B1 hücresine uygulayın. Sonrasında formülü sağa doğru sürükleyin.

C++: 
=KIRP(PARÇAAL(YERİNEKOY(" "&PARÇAAL($A1;1;UZUNLUK($A1));" ";YİNELE(" ";255));SÜTUN(A$1)*255;255))
 
Merhaba @ÖmerFaruk,

Ben bu durumlarda genelde excelin hücrelerini kullanıyorum.

Boş bir alana iki sütundan oluşan tabloyu yazdım. (Görsel-1)

229425


Sonrasında boş bir hücreye =B4:C8 yazarak formüle ediyorum.

229426


Sonra hücre içine F2 ile girip F9 tuşu ile değerliyorum.

229427


Son olarak oluşan diziyi DÜŞEYARA fonksiyonu içine modifiye ediyorum. Durum bundan ibarettir.
 
Teşekkürler.
Tarif ettiğiniz yöntemle çalıştı.
Ben elle girince ya da sizin formülü direkt kopyalayınca çalışmamasının sebebi { } parantezlerinden mi kaynaklanmaktadır?
 
Köşeli parantezleri elle yazarsanızda çalışması gerekir. Eğer yazmazsanız dizi oluşmayacapı için zaten hata verecektir.
 
=EĞERHATA(DÜŞEYARA(A1;{"av.";"Avukat"\"dr.";"Doktor"};2;0);"Kısaltma bulunamadı.")

Dediğiniz yöntemi kullandım çalıştı. Farkettim ki garip bir şeklde sizin formülden farklı olarak ; ve \ yerdeğişmiş olarak oluştu.
Manuel olarak da bu şekilde girince yine çalıştı.

Bu fark nerden kaynaklanıyor bulamadım?
365 ve önceki sürümlerin farkı mıdır?
 
ÖmerFaruk' Alıntı:
=EĞERHATA(DÜŞEYARA(A1;{"av.";"Avukat"\"dr.";"Doktor"};2;0);"Kısaltma bulunamadı.")

Dediğiniz yöntemi kullandım çalıştı. Farkettim ki garip bir şeklde sizin formülden farklı olarak ; ve \ yerdeğişmiş olarak oluştu.
Manuel olarak da bu şekilde girince yine çalıştı.

Bu fark nerden kaynaklanıyor bulamadım?
365 ve önceki sürümlerin farkı mıdır?
Genişletmek için tıkla ...
Aynen öyle Sn Ömer Faruk. Aynı şeyi yazacaktım.
 
Bir de formülün sonundaki 2;0 yerine 2;1 olarak değiştirince “Avukat” sonucunu verdi. 2;0 olunca “Kısaltma bulunamadı” uyarısı çıkıyor.
 
izcik' Alıntı:
Bir de formülün sonundaki 2;0 yerine 2;1 olarak değiştirince “Avukat” sonucunu verdi. 2;0 olunca “Kısaltma bulunamadı” uyarısı çıkıyor.
Genişletmek için tıkla ...
Artan sırada olmayan verilerde bu kısmı SIFIR olarak kullanmak zorundasınız.
 
Cevap yazmak için giriş yap yada kayıt ol.
Geri
Üst