Yazı Karakterleri

[aydogankemal]

Merhabalar,
Excel sayfasında bir sütunda alt alta tüm yazı karakterlerinin biçimlendirildiği bir dosya var mı, ya da bunu yapmak için bir makro var mı?
Örnek verecek olursak:
A1 satırında Deneme Ltd Şti yazısı var ve arial karakterinde,
A2 de ave devam eden tüm alt satırlarda aynı cümlenin farklı karakterlerde görünmesini istiyorum,
(Bunu niçin kullanacağıma gelince broşürlerde kullanılacak yazı stiline karar vermek için yapılacak bir toplantıya hazırlık)

 

[Necdet]

Font Listesi

Merhaba,

Aşğıdaki kodları kullanabilirsiniz.
http://j-walk.com/ss/excel/tips/tip79.htm den alınmadır.

'http://j-walk.com/ss/excel/tips/tip79.htm
Sub ShowInstalledFonts()
 
    Set FontList = Application.CommandBars("Formatting").FindControl(ID:=1728)
 
'   If Font control is missing, create a temp CommandBar
    If FontList Is Nothing Then
        Set TempBar = Application.CommandBars.Add
        Set FontList = TempBar.Controls.Add(ID:=1728)
    End If
 
'   Put the fonts into column A
    Range("A:A").ClearContents
    For i = 0 To FontList.ListCount - 1
        Cells(i + 1, 1) = FontList.List(i + 1)
        Cells(i + 1, 2) = Cells(i + 1, 1)
        Cells(i + 1, 2).Font.Name = FontList.List(i + 1)
    Next i
 
    Cells.EntireColumn.AutoFit
 
'   Delete temp CommandBar if it exists
    On Error Resume Next
    TempBar.Delete
 
End Sub

 

[aydogankemal]

Teşekkür ederim, istediğim aynen buydu

 

[levo26]

Merhaba,

Alternatif olarak aşağıdaki kodu kullanabilirsiniz. A1 hücresine yazdıktan sonra makroyu çalıştırınız.

Sub hucrelerde_Listele()
Set liste = CommandBars("Formatting").FindControl(ID:=1728)
For i = 0 To liste.ListCount - 1
Cells(i + 1, 1) = Range("A1")
Cells(i + 1, 2) = liste.List(i + 1)
Cells(i + 1, 1).Font.Name = liste.List(i + 1)
Next i
End Sub