TextBox içine yazdığım ismi Liste kutusunda seçsin

[Mdemir63]

Selamlar,

Arkadaşlar, Textbox içine isim girdiğimde Liste kutusundaki o ismi seçsin bunu nasıl şyapabilirim?

Saygılar

 

[Mdemir63]

Arkadaşlar hiç bu konu hakkında fikri olan yok mu?

Saygılar

 

[Ferhat Pazarçevirdi]

Merhabalar

Aşağıdakileri, ANASAYFA adlı sheet'in kod sayfasına kopyalayınız.

Private Sub TextBox1_Change()
Dim shA As Worksheet, shV As Worksheet
Dim i%
Set shA = Sheets("ANASAYFA")
Set shV = Sheets("VERİ")
For i = 2 To shV.Cells(65536, 1).End(xlUp).Row
    If StrConv(TextBox1, vbUpperCase) = StrConv(Left(shV.Cells(i, 2), Len(TextBox1)), vbUpperCase) Then
       shA.Cells(1, 1) = i - 1
       Exit For
    End If
Next i
Set shA = Nothing
Set shV = Nothing
End Sub

 

[Orion1]

Ekli dosyayı inceleyiniz.

Private Sub TextBox1_Change()
Dim j As Range
Range("A1").Value = ""
Set j = Sheets("VERİ").Range("B2:B65536").Find(TextBox1.Value, LookIn:=xlValues, lookat:=xlWhole)
If Not j Is Nothing Then
    Range("A1").Value = Sheets("VERİ").Cells(j.Row, "A").Value
End If
Set j = Nothing
End Sub

 

[Mdemir63]

Sn: fpc ve Orion2 hocalarım çok teşekkür ederim. Ellerinize sağlık iyi ki varsınız.

Saygılar sunarım.

 

[Mdemir63]

Sn: Hocalarım tekrar rahatsız ediyorum ama TextBox yerine Herhangibir Hücre kulanırsak kodlarda nereleri değiştirmem gerekir?

Saygılar

 

[Orion1]

Sn: Hocalarım tekrar rahatsız ediyorum ama TextBox yerine Herhangibir Hücre kulanırsak kodlarda nereleri değiştirmem gerekir?

Saygılar

Kodlarda TextBox1 yazan yarleri hücre adresi ile değiştiriniz.

 

[Mdemir63]

Selamlar,

Hocam dediğiniz şekilde yaptım ama çalışmadı.

Saygılar

 

[Ferhat Pazarçevirdi]

B2 hücresine ismi yazacağınız varsayımı ile, aşağıdakileri ANASAYFA adlı sheet'in kod sayfasına kopyalayınız.

Private Sub Worksheet_Change(ByVal Target As Range)
Dim shA As Worksheet, shV As Worksheet
Dim i%
If Not Intersect(Target, [B2]) Is Nothing Then
   Set shA = Sheets("ANASAYFA")
   Set shV = Sheets("VERİ")
   For i = 2 To shV.Cells(65536, 1).End(xlUp).Row
       If StrConv([B2], vbUpperCase) = StrConv(Left(shV.Cells(i, 2), Len([B2])), vbUpperCase) Then
          shA.Cells(1, 1) = i - 1
          Exit For
       End If
   Next i
   Set shA = Nothing
   Set shV = Nothing
End If
End Sub

 

[Mdemir63]

Hocam selamlar,

Anasayfamın kod penceresine son verdiğiniz kodları yapıştırdım ama çalışmadı

Saygılar

 

[Mdemir63]

Hocam ben yanlışlık yapmışım özür dilerim . kodlar çalıştı .çok teşekkürler.

Saygılar

 

[asem33]

hocalarım bu sayfayı güncelleyebilirmisiniz?